Copy bitmap to the clipboard succeed but doesn't work

[abcjeff]

Try to copy the bitmap of a image file to clipboard then paste into MS Paint, but Paint doesn't recognize the data and show an error. In fact Paint even freeze for a while.

$rst is not 0, meaning _ClipBoard_SetDataEx succeed, but the image is not in the clipboard viewer and can't be paste into other program. 

Here is the code:

#include <Constants.au3>

#include <GDIPlus.au3>

#include <GUIConstantsEx.au3>

#include <WindowsConstants.au3>

#include <WinAPIHObj.au3>

#include <File.au3>

#include <Clipboard.au3>

 

_GDIPlus_Startup()

_ClipBoard_Open(0)

Global $hBmp = _GDIPlus_BitmapCreateFromFile("C:\Users\olnw\Desktop\123.jpg")

$hImage = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)

$rst = _ClipBoard_SetDataEx($hImage, $CF_BITMAP)

MsgBox(0,$rst,$rst)

;_GDIPlus_BitmapDispose($hImage)

;_WinAPI_DeleteObject($hBmp)

;_GDIPlus_Shutdown()

;_ClipBoard_Close()

 

Paint error message:

 

[ioa747]

edit:
and if you want to use ms-pant, in main script (SmartNote) is a function
Func _PicToClip($Path) ; use ms-paint to copy image to clipboard

Edited April 17, 2023 by ioa747

[ioa747]

to forum

[abcjeff]

17 minutes ago, ioa747 said:

 

Thank you. 

_WinAPI_CopyImage did the trick.

[KaFu]

#include <GDIPlus.au3>
#include <Clipboard.au3>

_GDIPlus_Startup()
_ClipBoard_Open(0)

Local $hBmp = _GDIPlus_BitmapCreateFromFile(@ScriptDir & "\test.png")
Local $hImage = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)

Local $res = _ClipBoard_SetDataEx(_WinAPI_CopyImage($hImage), $CF_BITMAP)

_WinAPI_DeleteObject($hImage)
_GDIPlus_BitmapDispose($hBmp)

_ClipBoard_Close()
_GDIPlus_Shutdown()

 

[ioa747]

@KaFu  it gives me the below error

Local $res = _ClipBoard_SetDataEx(_WinAPI_CopyImage($hImage), $CF_BITMAP) : error: _ClipBoard_SetDataEx() called with Const or expression on ByRef-param(s).

[KaFu]

 

Caused by the "ByRef" of $hMemory in _ClipBoard_SetDataEx(), design decision and should not change the functionality. Not sure why it throws an error for you, and not for me 🙄. Maybe because I run the latest Beta of Au3Check.exe?

#include <GDIPlus.au3>
#include <Clipboard.au3>

_GDIPlus_Startup()
_ClipBoard_Open(0)

Global $hBmp = _GDIPlus_BitmapCreateFromFile(@ScriptDir & "\test.png")
Global $hImage = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)

Global $hImage_Copy = _WinAPI_CopyImage($hImage)
Global $res = _ClipBoard_SetDataEx($hImage_Copy, $CF_BITMAP)

_WinAPI_DeleteObject($hImage)
_GDIPlus_BitmapDispose($hBmp)

_ClipBoard_Close()
_GDIPlus_Shutdown()

 

 

[ioa747]

OK with this

[Nine]

NOT a good idea to put _WinAPI_CopyImage as a parameter or simply said : not with a delete object.  Eventually this will create a large memory leak.  Like the Beatles said : Dear Prudence

[KaFu]

Object is handed to system clipboard and must not be deleted by script.

 

Edit: Run this and check with task-manager

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GDIPlus.au3>
#include <Clipboard.au3>

For $i = 1 To 1000

    Sleep(1000)

    _GDIPlus_Startup()
    _ClipBoard_Open(0)

    Global $hBmp = _GDIPlus_BitmapCreateFromFile(@ScriptDir & "\test.png")
    Global $hImage = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)

    Global $hImage_Copy = _WinAPI_CopyImage($hImage)

    ConsoleWrite(@AutoItPID & @tab & $i & @tab & $hImage_Copy & @crlf)

    Global $res = _ClipBoard_SetDataEx($hImage_Copy, $CF_BITMAP)

    _WinAPI_DeleteObject($hImage)
    _GDIPlus_BitmapDispose($hBmp)

    _ClipBoard_Close()
    _GDIPlus_Shutdown()

Next

 

Edited April 18, 2023 by KaFu

[Nine]

Good catch @KaFu.  Per help file on _ClipBoard_SetDataEx.

Quote

If this function succeeds, the system owns the object identified by the $hMemory parameter. The application may not write to or free the data once ownership has been transferred to the system