Why do I have to invert some of my logic statements to get them to work?

[rcmaehl]

Hi all,

I've had this question for a while. For some reason, on occasion, I will have to invert a logic statement for it to work. The most recent is the below:

Global $aEdges[6] = [5, _
    "C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe", _
    "C:\Program Files (x86)\Microsoft\Edge Beta\Application\msedge.exe", _
    "C:\Program Files (x86)\Microsoft\Edge Dev\Application\msedge.exe", _
    @LocalAppDataDir & "\Microsoft\Edge SXS\Application\msedge.exe"]

$aEdges[5] = "C:\ProgramData\ie_to_edge_stub.exe"

Local $aChannels[5] = [True, True, True, True, True]

Test($aChannels)

Func Test(ByRef $aChannels)

    For $iLoop = 1 To $aEdges[0] Step 1
        If $aChannels[$iLoop - 1] Then
            MsgBox(0, "Loop", $iLoop)
            If Not $iLoop = $aEdges[0] Then
                MsgBox(0, "Success", $iLoop)
            Else
                ;;;
            EndIf
        EndIf
    Next
EndFunc

This should produce 9 dialog boxes. Yet it does not. However, if I invert it, it works:

Global $aEdges[6] = [5, _
    "C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe", _
    "C:\Program Files (x86)\Microsoft\Edge Beta\Application\msedge.exe", _
    "C:\Program Files (x86)\Microsoft\Edge Dev\Application\msedge.exe", _
    @LocalAppDataDir & "\Microsoft\Edge SXS\Application\msedge.exe"]

$aEdges[5] = "C:\ProgramData\ie_to_edge_stub.exe"

Local $aChannels[5] = [True, True, True, True, True]

Test($aChannels)

Func Test(ByRef $aChannels)

    For $iLoop = 1 To $aEdges[0] Step 1
        If $aChannels[$iLoop - 1] Then
            MsgBox(0, "Loop", $iLoop)
            If $iLoop = $aEdges[0] Then
                ;;;
            Else
                MsgBox(0, "Success", $iLoop)
            EndIf
        EndIf
    Next
EndFunc

 

It's comparing Int to Int, is there some weird fuzzy loose typing logic happening I'm not aware of?

Edited November 23, 2022 by rcmaehl

[Danp2]

You should read the help file entry on Operators, specifically the portion on Precedence. I'm unsure why you would want to use Not in this fashion, but you would need to modify your line by wrapping the equals portion in parentheses, like this --

If Not ($iLoop = $aEdges[0]) Then
                MsgBox(0, "Success", $iLoop)
            Else
                ;;;
            EndIf

 

[rcmaehl]

10 minutes ago, Danp2 said:

You should read the help file entry on Operators, specifically the portion on Precedence. I'm unsure why you would want to use Not in this fashion, but you would need to modify your line by wrapping the equals portion in parentheses, like this --

If Not ($iLoop = $aEdges[0]) Then
                MsgBox(0, "Success", $iLoop)
            Else
                ;;;
            EndIf

 

It just feels like I shouldn't need to wrap the equals portion in parentheses for some reason, like it's unnatural compared to the rest of the language to me. I don't know where I got it from. Maybe AutoIt should add != 😅

Edited November 23, 2022 by rcmaehl

[jchd]

7 hours ago, rcmaehl said:

Maybe AutoIt should add !=

What about <> ???