Set image from resource as ListView background

[TimRude]

I have a 250x250 png image that gets set as the centered background to a _GUICtrlListView when there is nothing to display in the listview.

Currently, it gets displayed like this:

If $iImages > 0 Then
    Local $sBGImageFile = "" ; no background image needed
Else
    Local $sBGImageFile = @ScriptDir & "\NoPics.png"
EndIf
_GUICtrlListView_SetBkImage($hListView, $sBGImageFile, 0, 50, 50)

Since I don't want an external file, I've added this image file to the resources (as number 301) using:

#AutoIt3Wrapper_Res_File_Add=P:\PictureShow\NoPics.png, PNG, 301

And Resource Hacker shows that the image file was successfully added.

How do I now assign this image from the resource to my listview background?

(FWIW, I also have the same image as a BMP file if using a PNG file complicates things.)

[Melba23]

TimRude,

Take a look at guinness' ResourcesEx UDF - that should let you extract the image and use it.

M23

[Nine]

If you don't want to use a quite large UDF for just a few lines of code, here a simple way to perform what you want :

#AutoIt3Wrapper_Res_File_Add=Pixel.bmp, rt_bitmap, Image, 301

#include <GUIConstants.au3>
#include <GuiListView.au3>
#include <Constants.au3>

If Not @Compiled Then Exit MsgBox($MB_SYSTEMMODAL, "Error", "This script needs to be compiled")

Local $hGUI = GUICreate("test", 500, 500)
Local $hListView = _GUICtrlListView_Create($hGUI, '', 30, 30, 300, 200)
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_FULLROWSELECT)
GUISetState()

Local $hInstance = _WinAPI_GetModuleHandle(NULL)
Local $hBitmap = _WinAPI_LoadImage($hInstance, "Image", $IMAGE_BITMAP , 0, 0, 0)

_GUICtrlListView_SetBkHBITMAP($hListView, $hBitmap, 0, 0, 0, True)

While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

ps. use BMP as it will ease your life

[TimRude]

@Melba23 Thanks for the pointer. If I was doing a lot of this I'd probably use the UDF. But this is the only instance of this I need for this script. I'll keep the UDF in mind for future reference.

@Nine I like the simpler method. I changed to the BMP version of the image as you suggested, since there was no transparency required. Works nicely. Thanks!