Controlclick on hidden GUI not working

[KaFu]

Hiho Forum,

I found older postings where controlclick on hidden GUIs worked, now it does not seem to work anymore, a bug?

 

Local $hGUI = GUICreate("Example")
Local $c_Button = GUICtrlCreateButton("Test", 10, 10, 100)
; GUISetState(@SW_SHOW, $hGUI)

ControlClick($hGUI, "", $c_Button)

While 1
    Switch GUIGetMsg()
        Case $c_Button
            MsgBox(0, "", "Click")
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

 

Edit: the same with onevent mode

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)

Local $hGUI = GUICreate("Example")
Local $c_Button = GUICtrlCreateButton("Test", 10, 10, 100)
GUICtrlSetOnEvent(-1, "ButtonPressed")
; GUISetState(@SW_SHOW, $hGUI)

ControlClick($hGUI, "", $c_Button)

Sleep(1000)

Func ButtonPressed()
    MsgBox(0, "", "Click")
EndFunc

 

Edited November 4, 2022 by KaFu

[pixelsearch]

Hi KaFu
Just tested your code on 2 older AutoIt releases (oldest one being v3.2.10.0 dated 2007) with same result as yours (controlclick on hidden GUI didn't work)

What seems to work is adding a couple of lines, then ControlClick will be done while the GUI is hidden :

Local $hGUI = GUICreate("Example")
Local $c_Button = GUICtrlCreateButton("Test", 10, 10, 100)

GUISetState(@SW_SHOW, $hGUI)     ; or @SW_SHOWNA  @SW_SHOWNOACTIVATE
WinSetState($hGUI, '', @SW_HIDE) ; not GUISetState(@SW_HIDE, $hGUI)

ControlFocus($hGUI, "", $c_Button)
ControlClick($hGUI, "", $c_Button)

While 1
    Switch GUIGetMsg()
        Case $c_Button
            MsgBox(0, "Button", "Click")
            ExitLoop
        Case -3 ; $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Same with OnEvent mode :

Opt("GUIOnEventMode", 1)

Local $hGUI = GUICreate("Example")
Local $c_Button = GUICtrlCreateButton("Test", 10, 10, 100)
GUICtrlSetOnEvent(-1, "ButtonPressed")

GUISetState(@SW_SHOW, $hGUI)     ; or @SW_SHOWNA  @SW_SHOWNOACTIVATE
WinSetState($hGUI, '', @SW_HIDE) ; not GUISetState(@SW_HIDE, $hGUI)

ControlFocus($hGUI, "", $c_Button)
ControlClick($hGUI, "", $c_Button)

Sleep(1000)

Func ButtonPressed()
    MsgBox(0, "Button", "Click")
EndFunc

 

Edited November 4, 2022 by pixelsearch
replaced _WinAPI_SetFocus() with ControlFocus()

[KaFu]

I guess the default WNDPROC is only hooked once @SW_SHOW is called. Might be a good feature to hook this with GUISetState(@SW_HIDE, $hGUI)  too?

[pixelsearch]

Overlord, where are you ? 

[argumentum]

5 hours ago, KaFu said:

default WNDPROC is only hooked once @SW_SHOW is called

...well, if WinSetState is called ( with @SW_HIDE ). As far as I remembered the call was always needed. But my mileage memory may vary   

[pixelsearch]

Just modified the 2 scripts above. No need of _WinAPI_SetFocus() when ControlFocus() does the job.
Then no need of #include <WinAPISysWin.au3>  or  an eventual $h_Button . Shorter code, same result.