Limit List lines...

[fraizor]

Hello

how can i limit the amount of lines a list can hold ?

i am using a list in my project to show logs.

the list eventually will show thousands of lines, i want to limit the amount of lines to avoid any crash or slow performance , as we only need to see the last 50 or so logs 

i tried this but no luck

 

$listLog = GUICtrlCreateList("", 0, 400, @DesktopWidth/2 -460,200,0x1000)
GUICtrlSetLimit($listLog, 3)
GUISetState(@SW_SHOW)

 

[Melba23]

fraizor,

Read the number of items in the list with _GUICtrlListBox_GetCount and, if it is over the required maximum, use _GUICtrlListBox_DeleteString to delete the early lines.

M23

[water]

GUICtrlSetLimit only limits the horizontal scrolling.
You have to use GUICtrlSetData to fill the list. Simply stop adding new entries when your limit has been reached.

[Nine]

Here an example how to use ControlCommand to interact with a ListBox :

#include <GUIConstants.au3>
#include <Constants.au3>

Example()

Func Example()
  Local $hGUI = GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

  Local $idButton_Add = GUICtrlCreateButton("Add", 64, 32, 75, 25)
  Local $idButton_Clear = GUICtrlCreateButton("Clear", 64, 72, 75, 25)
  Local $idMylist = GUICtrlCreateList("Buttons that have been clicked by number", 176, 32, 150, 120, BitOR($WS_BORDER, $WS_VSCROLL, $WS_HSCROLL))
  GUICtrlSetLimit(-1, 300) ; to limit horizontal scrolling
  GUICtrlSetData(-1, "The following buttons have been clicked")
  Local $idButton_Close = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

  GUISetState(@SW_SHOW)

  Local $iNum = 0, $iCount
  While 1
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE, $idButton_Close
        ExitLoop
      Case $idButton_Add
        $iCount = ControlCommand($hGUI, "", $idMylist, "GetCount")
        If $iCount > 10 Then ControlCommand($hGUI, "", $idMylist, "DelString", 0)
        $iNum += 1
        GUICtrlSetData($idMylist, "You clicked button No " & $iNum & "|")
        ControlCommand($hGUI, "", $idMylist, "SetCurrentSelection", $iCount > 10 ? 10 : $iCount)
      Case $idButton_Clear
        GUICtrlSetData($idMylist, "")
    EndSwitch
  WEnd
EndFunc   ;==>Example

 

[fraizor]

24 minutes ago, Nine said:

Here an example how to use ControlCommand to interact with a ListBox :

#include <GUIConstants.au3>
#include <Constants.au3>

Example()

Func Example()
  Local $hGUI = GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

  Local $idButton_Add = GUICtrlCreateButton("Add", 64, 32, 75, 25)
  Local $idButton_Clear = GUICtrlCreateButton("Clear", 64, 72, 75, 25)
  Local $idMylist = GUICtrlCreateList("Buttons that have been clicked by number", 176, 32, 150, 120, BitOR($WS_BORDER, $WS_VSCROLL, $WS_HSCROLL))
  GUICtrlSetLimit(-1, 300) ; to limit horizontal scrolling
  GUICtrlSetData(-1, "The following buttons have been clicked")
  Local $idButton_Close = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

  GUISetState(@SW_SHOW)

  Local $iNum = 0, $iCount
  While 1
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE, $idButton_Close
        ExitLoop
      Case $idButton_Add
        $iCount = ControlCommand($hGUI, "", $idMylist, "GetCount")
        If $iCount > 10 Then ControlCommand($hGUI, "", $idMylist, "DelString", 0)
        $iNum += 1
        GUICtrlSetData($idMylist, "You clicked button No " & $iNum & "|")
        ControlCommand($hGUI, "", $idMylist, "SetCurrentSelection", $iCount > 10 ? 10 : $iCount)
      Case $idButton_Clear
        GUICtrlSetData($idMylist, "")
    EndSwitch
  WEnd
EndFunc   ;==>Example

 

thank you for the example , i am getting this error ...

[water]

Replace "GetCount" wiht "GetLineCount".

[fraizor]

great , thank you guys, one more thing .. how can i always automatically scroll to the end of the list ? 

[water]

Does the script work for you? Means: Press the "Add" button until you see > 10 lines.
Here the script does not delete lines.

[water]

Seems that "GetLineCount" does not work for a ListBox.
I modified the script and it now works for me:

expandcollapse popup

#include <GUIConstants.au3>
#include <Constants.au3>
#include <GuiListBox.au3>

Example()

Func Example()
  Local $hGUI = GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

  Local $idButton_Add = GUICtrlCreateButton("Add", 64, 32, 75, 25)
  Local $idButton_Clear = GUICtrlCreateButton("Clear", 64, 72, 75, 25)
  Local $idMylist = GUICtrlCreateList("Buttons that have been clicked by number", 176, 32, 150, 120, BitOR($WS_BORDER, $WS_VSCROLL, $WS_HSCROLL))
  GUICtrlSetLimit(-1, 300) ; to limit horizontal scrolling
  GUICtrlSetData(-1, "The following buttons have been clicked")
  Local $idButton_Close = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

  GUISetState(@SW_SHOW)

  Local $iNum = 0, $iCount
  While 1
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE, $idButton_Close
        ExitLoop
      Case $idButton_Add
        ; $iCount = ControlCommand($hGUI, "", $idMylist, "GetLineCount")
        $iCount = _GUICtrlListBox_GetCount($idMyList)
        ConsoleWrite("$iCount: " & $iCount & ", @error=" & @error & @CRLF)
        If $iCount >= 10 Then
            ; ControlCommand($hGUI, "", $idMylist, "DelString", 1)
            _GUICtrlListBox_DeleteString ($idMylist, 0)
            ConsoleWrite("ControlCommand: @error=" & @error & @CRLF)
        EndIf
        $iNum += 1
        GUICtrlSetData($idMylist, "You clicked button No " & $iNum & "|")
        ControlCommand($hGUI, "", $idMylist, "SetCurrentSelection", $iCount > 10 ? 10 : $iCount)
      Case $idButton_Clear
        GUICtrlSetData($idMylist, "")
    EndSwitch
  WEnd
EndFunc   ;==>Example

 

[fraizor]

2 minutes ago, water said:

Does the script work for you? Means: Press the "Add" button until you see > 10 lines.
Here the script does not delete lines.

yes it seems to work for me , all buttons are working , however my auto scroll question is in general. 

this is a sample code.. how can i make it always show the last line ? 

GUICreate("", 500, 600)
$listLog = GUICtrlCreateList("", 0, 400, @DesktopWidth/2 -460,200)

GUISetState(@SW_SHOW)
for $i = 0 to 90
    GUICtrlSetData($listLog,@SEC & "|")
    Sleep(500)
next

 

[water]

This works perfect here:

expandcollapse popup

#include <GUIConstants.au3>
#include <Constants.au3>
#include <GuiListBox.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("My GUI list") ; will create a dialog box that when displayed is centered
    Local $iMaxItems = 10

    Local $idButton_Add = GUICtrlCreateButton("Add", 64, 32, 75, 25)
    Local $idButton_Clear = GUICtrlCreateButton("Clear", 64, 72, 75, 25)
    Local $idMylist = GUICtrlCreateList("Buttons that have been clicked by number", 176, 32, 150, 120, BitOR($WS_BORDER, $WS_VSCROLL, $WS_HSCROLL))
    GUICtrlSetLimit(-1, 300) ; to limit horizontal scrolling
    GUICtrlSetData(-1, "The following buttons have been clicked")
    Local $idButton_Close = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

    GUISetState(@SW_SHOW)

    Local $iNum = 0, $iCount
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idButton_Close
                ExitLoop
            Case $idButton_Add
                $iCount = _GUICtrlListBox_GetCount($idMylist)
                If $iCount >= $iMaxItems Then
                    _GUICtrlListBox_DeleteString($idMylist, 0)
                    $iCount = $iCount - 1
                EndIf
                $iNum += 1
                GUICtrlSetData($idMylist, "You clicked button No " & $iNum & "|")
                _GUICtrlListBox_SetCurSel($idMylist, $iCount)
                $iCount = $iCount + 1
            Case $idButton_Clear
                GUICtrlSetData($idMylist, "")
        EndSwitch
    WEnd
EndFunc   ;==>Example

 

[Nine]

52 minutes ago, fraizor said:

thank you for the example , i am getting this error ...

Download latest version 3.3.16.0, cause it is working fine on this version.

[water]

My version runs and works with AutoIt 3.3.14.5

[Nine]

21 minutes ago, water said:

My version runs and works with AutoIt 3.3.14.5

Does my script works or do you get OP error too ?

[water]

As posted above: The parameter for ControlCommand was wrong. Has to be changed from "GetCount" to "GetLineCount".
In addition

$iCount = ControlCommand($hGUI, "", $idMylist, "GetLineCount")

always returned 0. According to the help file: "Returns # of lines in an Edit". So GetLineCount does not seem to work for a ListBox control (at least in 3.3.14.5.).

[Nine]

3 minutes ago, water said:

Has to be changed from "GetCount" to "GetLineCount".

I do not have 3.3.14.5 anymore but according to 3.3.16.0 documentation of ControlCommand :

 

Quote

"GetCount", ""

Returns number of entries in a ListBox or ComboBox

Where 

Quote

option

[optional]    Additional parameter required by some commands.

So with 3.3.16.0

$iCount = ControlCommand($hGUI, "", $idMylist, "GetCount")

The code is working perfectly and you do not have to specify the option parameter.  I guess it is time to update 

[water]

Keyword "GetCount" does not exist in AutoIt 3.3.14.5 and was added with 3.3.16.0 in March 2022.
I let a few months pass before I update to the latest version

[Nine]

44 minutes ago, water said:

I let a few months pass before I update to the latest version

Like the Beatles said "Dear Prudence" 

[water]