Passing a parameter (Variable used without being declared)

[NassauSky]

Hi all,

Can anyone help me and possibly explain why I'm getting the error message:

Variable used without being declared.:

on the following code

AutoItSetOption ( "MustDeclareVars", 1)
myFunction()


Func myFunction($getCustomName=True)
    If $getCustomName Then
        MsgBox(0,"Custom Name",$getCustomName)
    Else
        MsgBox(0,"Custom Name","None Given")
    EndIf
EndFunc

 

Edited May 19, 2022 by NassauSky
Typo

[TheXman]

2 minutes ago, NassauSky said:

MsbBox(0,"Custom Name","None Given")

MsbBox maybe?

[NassauSky]

Sorry that was just my typo. It was correct in my actual code. It specifically errors on :

 

If $getCustomName Then
If ^ ERROR

 

Edited May 19, 2022 by NassauSky

[TheXman]

When I corrected MsbBox and reran the script, I didn't get any errors.  The error I saw was on the MsbBox line.

Edited May 19, 2022 by TheXman

[Melba23]

NassauSky,

Works fine for me too.

M23

[NassauSky]

Strange I'm going to have to see what else is going on.

Thanks @TheXman & @Melba23 

[NassauSky]

Sorry OK I realized it must be my implementation:

This example shows the error

 

AutoItSetOption ( "MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global  $hGUI = GUICreate("myHelper", 600, @DesktopHeight-80, @DesktopWidth-600, 0) ;w,h,x,y
Global $hExportList = GUICtrlCreateButton("Export List",200,25,80,25)   ;x,y,w,h
   GUICtrlSetOnEvent(-1, "myFunction")
GUISetState()
While 1
   Sleep(10)
WEnd

Func myFunction($getCustomName=True); Handle both a button press in EventMode and a call to the function
    If $getCustomName Then
        MsgBox(0,"Custom Name","Called through button press")
    Else
        MsgBox(0,"Custom Name","Called through function call myFunction(False)")
    EndIf
EndFunc

 

[Melba23]

NassauSky,

Here is how I might go about coding a solution:

AutoItSetOption ( "MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

HotKeySet("{ESC}", "_Exit")

Global $getCustomName = "Button"

Global  $hGUI = GUICreate("myHelper")
Global $hExportList = GUICtrlCreateButton("Export List",200,25,80,25)   ;x,y,w,h
   GUICtrlSetOnEvent(-1, "myFunction")
GUISetState()

 myFunction_Direct("Direct")

While 1
   Sleep(10)
WEnd

Func myFunction_Direct($Param = True)
    $getCustomName = $Param
    myFunction()
    $getCustomName = "Button"
EndFunc

Func myFunction(); Handle both a button press in EventMode and a call to the function
    If $getCustomName = "Button" Then
        MsgBox(0,"Custom Name","Called through button press")
    Else
        MsgBox(0,"Custom Name","Called through function call with param: " & $getCustomName)
    EndIf
EndFunc

Func _Exit()
    Exit
EndFunc

M23

[NassauSky]

Thanks @Melba23.  I try to use my Global Variables sparingly. That's what I'll wind up doing.  It's just funny that the function does get called from the button event trigger and functions correctly if I don't make any references to the missing passed parameter.

 

[Subz]

Only occurs when using GuiOnEventMode and MustDeclareVars, you could use

AutoItSetOption ( "MustDeclareVars", 1)

Global  $hGUI = GUICreate("myHelper", 600, @DesktopHeight-80, @DesktopWidth-600, 0) ;w,h,x,y
Global $hExportList = GUICtrlCreateButton("Export List",200,25,80,25)   ;x,y,w,h
GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hExportList
            myFunction()
    EndSwitch
WEnd

Func myFunction($getCustomName = True); Handle both a button press in EventMode and a call to the function
    If $getCustomName Then
        MsgBox(0,"Custom Name","Called through button press")
    Else
        MsgBox(0,"Custom Name","Called through function call myFunction(False)")
    EndIf
EndFunc

 

Edited May 19, 2022 by Subz

[NassauSky]

Thanks @Subz

Yeah in this case I created the app a year ago and was tweaking it and must have used EventMode for a reason. Was faster to implement the global variable option.

 

Thanks again though I also like to hear other options like yours.

Edited May 19, 2022 by NassauSky