Array of combinations

[jerem488]

Hi all,

I have 2 lists of materials with a list of basic material and another list of secondary material.

And I want generate an array with the list of combinations. I looked _ArrayCombinations() function but it doesn't work properly...

Local $aArray[10] = ["H", "Li", "Na", "K", "Rb", "Cs", "Ti/B", "Zr/Si", "Hf/As", "Rf/Sb"]

Local $aArrayCombo = _ArrayCombinations($aArray, 7, ",")
_ArrayToString($aArrayCombo, ',')
_ArrayDisplay($aArrayCombo)

"H", "Li", "Na", "K", "Rb" and "Cs" are basics materials, so they must be in each combinations. And other "groups" only one of two.

For example:

"H", "Li", "Na", "K", "Rb", "Cs", "Ti", "Zr", "As", "Sb"

"H", "Li", "Na", "K", "Rb", "Cs", "B", "Zr", "As", "Rf"

 

[jchd]

Something like this ?

Local $sBase = "H,Li,Na,K,Rb,Cs,"
Local $aSalt = ["Ti", "B", "Zr", "Si", "Hf", "As", "Rf", "Sb"]

Local $aCombo = _ArrayCombinations($aSalt, 2, ",")
_ArrayDelete($aCombo, 0)
For $i = 0 To UBound($aCombo) - 1
    $aCombo[$i] = '"' & StringReplace($sBase & $aCombo[$i], ',', '", "') & '"'
Next
_ArrayDisplay($aCombo)

BTW do you really have a significant physical stock of Rutherfordium, or do you produce it on demand in your microwave oven?

[jerem488]

On the periodic table of elements, we have basic elements that cannot be coupled. But these elements can be combined with most other elements of the table. I have a table in Excel with characteristics for each element. And columns of calculations on each combination.

And in the code that you note, it doesn't include every subgroup.

The basic elements should always be in each list and then 1 element from each group.

In my example, the series that I note "Ti/B", "Zr/Si", "Hf/As", "Rf/Sb" means that in each list you can have only Ti OR B but not both. But one element of each group.

 

Edited May 10, 2022 by jerem488

[jchd]

Even if I strongly suspect this has nothing to do with chemistry and all to do with some game,

Local $sBase = "H,Li,Na,K,Rb,Cs"
Local $aSalt = [["Ti", "B"], ["Zr", "Si"], ["Hf", "As"], ["Rf", "Sb"]]
Local $aCombo[2 ^ UBound($aSalt)]

For $i = 0 To UBound($aCombo) - 1
    For $j = 0 To UBound($aSalt) - 1
        $aCombo[$i] &= "," & $aSalt[$j][BitAND(BitShift($i, $j), 1)]
    Next
    $aCombo[$i] = '"' & StringReplace($sBase & $aCombo[$i], ',', '", "') & '"'
Next

_ArrayDisplay($aCombo)

 

[jerem488]

Thanks a lot ! 

As soon as my program will be completely finished I will gladly put it in the examples of this site