Binary to hex

[crackdonalds]

Hi,

So I was using this piece of code posted by Jos in 2007.

$BinIn = "11111110"
  BinaryToHex($BinIn)
 Func BinaryToHex($BinIn)
$Bits = StringSplit($BinIn,"")
$dec = 0
For $x = $Bits[0] To 1 Step -1
    $dec +=  (2^($Bits[0]-$x)) * $Bits[$x]
Next
$hex = Hex($dec)
ConsoleWrite("bin:" & $BinIn & "  Dec:" & $dec & "   Hex:" & $Hex & @CRLF)
ConsoleWrite("bin:" & $BinIn & "  Dec:" & $dec & " " &  Hex(254) & @CRLF)
EndFunc

The first consolewrite returns: bin:11111110  Dec:254   Hex:406FC00000000000
The second consolewrite returns: bin:11111110  Dec:254 000000FE

Obviously FE is the correct answer. Anyone know why the first console write got it wrong even though the decimal (254) used in the hex-conversion is correct?

Looks like a bug?

[Jos]

Change the type of $dec to int and then it works:

$BinIn = "11111110"
BinaryToHex($BinIn)
Func BinaryToHex($BinIn)
    $Bits = StringSplit($BinIn, "")
    $dec = 0
    For $x = $Bits[0] To 1 Step -1
        $dec += (2 ^ ($Bits[0] - $x)) * $Bits[$x]
    Next
    $hex = Hex(int($dec))
    ConsoleWrite("bin:" & $BinIn & "  Dec:" & $dec & "   Hex:" & $hex & @CRLF)
    ConsoleWrite("bin:" & $BinIn & "  Dec:" & $dec & " " & Hex(254) & @CRLF)
EndFunc   ;==>BinaryToHex

 

[crackdonalds]

$hex = Hex(int($dec))

that fixed it indeed. thx

[jchd]

Another way:

$BinIn = "11111110"
ConsoleWrite(Hex(_StringToUint($BinIn, 2), 2) & @LF)

Func _StringToUint($s, $base)
    Return DllCall("msvcrt.dll", "uint64:cdecl", "_wcstoui64", "wstr", $s, "ptr*", 0, "int", $base)[0]
EndFunc   ;==>_StringToUint

Func _UintToString($i, $base)
    Return DllCall("msvcrt.dll", "wstr:cdecl", "_ui64tow", "uint64", $i, "wstr", "", "int", $base)[0]
EndFunc   ;==>_UintToString

You can specify any base in 2...36 and you get the reverse conversion for the same price.

[Jos]

It seems AutoiT3's behavior changed for Hex() as that piece seemed to work back in 2007: 

 

[crackdonalds]

  On 11/23/2021 at 12:17 PM, Jos said:

It seems AutoiT3's behavior changed for Hex() as that piece seemed to work back in 2007: 

 

Expand  

Yea that's what I was thinking. I had found more examples and they all didn't work (anymore).

[jchd]

Do you mean my above sample code doesn't work for you?

[crackdonalds]

  On 11/23/2021 at 2:26 PM, jchd said:

Do you mean my above sample code doesn't work for you?

Expand  

I didn't try your solution because the suggestion made by Jos already worked for me.
Thanks for you contribution. Maybe they can implement your solution as UDF.