Minimize an active window - (Moved)

[rix]

I'm a newbie. i need a script to minimize an active windows Can you teach/help me? Thanks in advance...

[Melba23]

Moved to the appropriate forum, as the Developer General Discussion forum very clearly states:

Quote

General development and scripting discussions.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Moderation Team

[Melba23]

rix,

Welcome to the AutoIt forums. I would suggest looking at WinSetState in the Help file.

M23

[Comatose]

This is actually a bit complicated. Minimizing the window is the easy part. Being on the correct window will take a bit of coding.
WinList will show the open windows. Then you'll have to compare to see if the window you're looking for is open.
If so make it the active window then minimize it. OR ... if you know the windows exact name you could just try to make it active.
If that works then you can minimize it. If not the window couldn't be found. There is a tool called: AutoIt v3 Window Information.
You can use that to find the exact window text you can use (It's basically the name of the window and/or any text you added).

Raw commands would be: WinActivate ( "title" [, "text"] ) and WinSetState ( "title", "text", @SW_MINIMIZE)

Without anymore context in your question this is just a generic answer for you.

[SkysLastChance]

Here is an example with notepad. 

OpenNotepad ()

Func OpenNotepad ()
    Local $iNotePad = Run("notepad.exe", "", @SW_MAXIMIZE)
    WinWait("[CLASS:Notepad]", "", 5)
    Sleep(5000) 
    WinSetState($iNotePad,"",@SW_MINIMIZE)
    ProcessClose($iNotePad)
EndFunc

 

Edited November 19, 2021 by SkysLastChance

[Musashi]

3 hours ago, rix said:

i need a script to minimize an active windows Can you teach/help me? Thanks in advance...

To get the title or handle of the active window :

HotKeySet("{ESC}", "_Terminate")
HotKeySet("+!1", "_ActiveWindow") ; Shift-Alt-1

Global $sTitleActive, $hHandleActive ; Title or Handle

While True
    Sleep(100)
WEnd

Func _ActiveWindow()
    $sTitleActive = WinGetTitle("[active]")
    $hHandleActive = WinGetHandle("[active]")
    MsgBox(BitOR(4096, 64), "Minimize :", "Title  : " & @CRLF & $sTitleActive & @CRLF & _
                                          "Handle : " & @CRLF & $hHandleActive & @CRLF)
EndFunc

Func _Terminate()
    MsgBox(BitOR(4096, 64), "Message :", "Script terminated" & @CRLF)
    Exit
EndFunc

Use WinSetState  (with title or handle) to minimize the active window for example.

[rix]

I've an idea ( i'm juist a newbie): is it possible to simulate this sequence: alt+space and then i? 

[Danp2]

@rixYes, I'm sure it's possible. But it would be way less reliable than using

WinSetState("[ACTIVE]","",@SW_MINIMIZE)

 

[rix]

On 11/19/2021 at 11:31 PM, Musashi said:

To get the title or handle of the active window :

HotKeySet("{ESC}", "_Terminate")
HotKeySet("+!1", "_ActiveWindow") ; Shift-Alt-1

Global $sTitleActive, $hHandleActive ; Title or Handle

While True
    Sleep(100)
WEnd

Func _ActiveWindow()
    $sTitleActive = WinGetTitle("[active]")
    $hHandleActive = WinGetHandle("[active]")
    MsgBox(BitOR(4096, 64), "Minimize :", "Title  : " & @CRLF & $sTitleActive & @CRLF & _
                                          "Handle : " & @CRLF & $hHandleActive & @CRLF)
EndFunc

Func _Terminate()
    MsgBox(BitOR(4096, 64), "Message :", "Script terminated" & @CRLF)
    Exit
EndFunc

Use WinSetState  (with title or handle) to minimize the active window for example.

I've got a doubt: but is the script uncomplete? or do I have to change it? if I run it I get nothing. I apologize for the obvious, but I am not an expert. I tried to simulate win +down but it closes all the windows .... if I really press the keys it closes the active window

[Musashi]

54 minutes ago, rix said:

I've got a doubt: but is the script uncomplete? or do I have to change it? if I run it I get nothing.

The script runs in the background (until you press ESC). It does not minimize anything, but shows you the title and handle of the currently active window. You can use this information to e.g. minimize the active window.

[rix]

Yeap but i don't obtain a title, just the message script terminated when i press esc...

[Musashi]

45 minutes ago, rix said:

Yeap but i don't obtain a title, just the message script terminated when i press esc...

Please perform a test :

#include <MsgBoxConstants.au3>
HotKeySet("{ESC}", "_Terminate")
HotKeySet("+!1", "_ContolHasFocus") ; Shift-Alt-1

Run("notepad.exe")
Global $sControl, $hHandle, $sTitle
Global $hWnd = WinWait("[CLASS:Notepad]", "", 10)

While True
    Sleep(100)
WEnd

Func _ContolHasFocus()
    $hHandle  = WinGetHandle("[active]")
    $sTitle   = WinGetTitle("[active]")
    $sControl = ControlGetFocus($hWnd)
    MsgBox(BitOR(4096, 64), "Focus :", _
                            "Handle : " & @CRLF & $hHandle & @CRLF & _
                            "Titel  : " & @CRLF & $sTitle  & @CRLF & _
                            "Focus  : " & @CRLF & $sControl  & @CRLF)
EndFunc

Func _Terminate()
    MsgBox(BitOR(4096, 64), "Message :", "Script terminated" & @CRLF)
    Exit
EndFunc

Run the script. After Notepad is launched, then open whatever text file you want. Now press Shift Alt 1

Use the 1 from the keyboard, not the 1 from the Numpad. What happens now?

[rix]

This one, it works fine...i've got handle and title

[Musashi]

52 minutes ago, rix said:

This one, it works fine...i've got handle and title

OK !

Another test :
Start your application (may not be minimized). Now run the following script within the SciTE editor (F5).

(from @Subz : getting-list-of-all-normal-windows )

#include <Array.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Local $hWindow, $vWinStyle, $aWinNormal[1][2]
Local $aWinList = WinList("[REGEXPTITLE:(?i)(.+)]")
For $i = $aWinList[0][0] To 1 Step -1
    If $aWinList[$i][0] = "" Then ContinueLoop
    $hWindow = WinGetHandle($aWinList[$i][1], "")
    If Not $hWindow Then ContinueLoop
    $vWinStyle = _WinAPI_GetWindowLong($hWindow, $GWL_STYLE)
    If BitAND(WinGetState($aWinList[$i][1]), 4) = 4 _
            And BitAND($vWinStyle, $WS_VISIBLE) = $WS_VISIBLE _
            And BitAND($vWinStyle, $WS_MINIMIZE) <> $WS_MINIMIZE _
            And BitAND($vWinStyle, $WS_MINIMIZEBOX) = $WS_MINIMIZEBOX _
            And BitAND($vWinStyle, $WS_MAXIMIZEBOX) = $WS_MAXIMIZEBOX Then _ArrayAdd($aWinNormal, $aWinList[$i][0] & "|" & $aWinList[$i][1])
Next
$aWinNormal[0][0] = UBound($aWinNormal) - 1
_ArrayDisplay($aWinNormal)

Does your application appear in the list?

[rix]

Yeap at the end of the list, i've got my application name. Sorry my english isn't perfect

 

Edited December 4, 2021 by rix