StringRegExpReplace help

[JamesDover]

I know this is a simple script however, I can't seem to get the code correct. I'm pulling in domain users in this format mydomain\firstname.lastname and I would like the output to be firstname.lastname (basically just removing the mydomain\ ). Here is the code below that I am working on. Cheers

#include <MsgBoxConstants.au3>
Test1()

Func Test1()
Local $sInput = "mydomain\firstname.lastname"
Local $sOutput = StringRegExpReplace($sInput, 'mydomain\', '$1')
Display($sInput, $sOutput)
EndFunc

Edited October 15, 2021 by JamesDover

[Jos]

You need to escape the backslash:

Test1()

Func Test1()
    Local $sInput = "mydomain\firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, 'mydomain\\', '$1')
    ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sOutput = ' & $sOutput & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
EndFunc   ;==>Test1

Jos  

[Musashi]

#include <MsgBoxConstants.au3>
Test1()

Func Test1()
    Local $sInput   = "mydomain\firstname.lastname"
    Local $sOutput1 = StringRegExpReplace($sInput, '(mydomain\\)', '$1')
    Local $sOutput2 = StringReplace($sInput, 'mydomain\', '')
    ConsoleWrite("Input   = " & $sInput & @CRLF)
    ConsoleWrite("Output1 = " & $sOutput1 & @CRLF)
    ConsoleWrite("Output2 = " & $sOutput2 & @CRLF)
EndFunc

EDIT :

@Jos was faster. BTW : In your case a simple StringReplace would also be sufficient.

Edited October 15, 2021 by Musashi

[JamesDover]

Excellent! Thanks for the quick responses. 

[mikell]

Assuming that the "mydomain" part may vary :

Test1()
Test2()

; get what you want
Func Test1()
    Local $sInput = "mydomain\firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '.*?\\(.*)', "$1")
    Msgbox(0,"1", $sOutput)
EndFunc

; or fire what you don't want
Func Test2()
    Local $sInput = "mydomain\firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '[^\\]+\\', "")
    Msgbox(0,"2", $sOutput)
EndFunc

 

[JamesDover]

23 minutes ago, mikell said:

Assuming that the "mydomain" part may vary :

Test1()
Test2()

; get what you want
Func Test1()
    Local $sInput = "mydomain\firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '.*?\\(.*)', "$1")
    Msgbox(0,"1", $sOutput)
EndFunc

; or fire what you don't want
Func Test2()
    Local $sInput = "mydomain\firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '[^\\]+\\', "")
    Msgbox(0,"2", $sOutput)
EndFunc

 

That's a good example. I've always struggled with StringRegExpReplace expressions so this was very helpful. 

[JamesDover]

I just found one that was in this format mydomain/firstname.lastname and the StringRegExpReplace doesn't seem to effect it. Would this be because the \ is in a different direction on the StringRegExpReplace?

Func Test2()
    Local $sInput = "mydomain/firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '[^//]+//', "")
    Msgbox(0,"2", $sOutput)
EndFunc

 

[Musashi]

1 hour ago, JamesDover said:

Would this be because the \ is in a different direction on the StringRegExpReplace?

Yes !

Metacharacters :
PCRE metacharacters are \ . ^ $ | [ ( { * + ? # which have one or more special meaning, depending on context.
To insert a literal metacharacter, precede it by adding a backslash (this is called escaping (or quoting) a character).

/ is not a metacharacter and need not be escaped with \

Test1()
Test2()

Func Test1()
    Local $sInput = "mydomain/firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '.*?/(.*)', "$1")
    Msgbox(0,"1", $sOutput)
EndFunc

Func Test2()
    Local $sInput = "mydomain/firstname.lastname"
    Local $sOutput = StringRegExpReplace($sInput, '[^/]+/', "")
    Msgbox(0,"2", $sOutput)
EndFunc

 

Edited October 15, 2021 by Musashi
typo

[JamesDover]

Thanks everyone.