_excel_rangeRead() return cell index

[nikosliapis]

Hello everybody 

When I use _excel_rangeRead() function with $vRange value set to Default, is there a way to add the Row Index of the excel file at a column in the returned array ?

For example at the following excel file 

 I need the returned array to be like this 

As far as I understand the function needs to be modified in the <Excel.au3> UDF. I tried using the "Cell.IndexRow" property, but my poor understanding of VBA doesn't help.

I would appreciate any help you could give me.

Thanks

 

[water]

Something like this?

#include <Excel.au3>

; Prepare the workbook
Global $oExcel = _Excel_Open()
Global $oWorkbook = _Excel_BookNew($oExcel, 1)
Global $aData[][] = [["A.A", "name", "phone", "mail"], _
        [1, "andreas", 12345678, "a@gmail.com"], _
        [2, "michael", 12345, "mic@yahoo.gr"], _
        [3, "john", 1234567, "jc@gmail.gr"]]
_Excel_RangeWrite($oWorkbook, 1, $aData, "B2")

Global $aRead = _Excel_RangeRead($oWorkbook, 1)                           ; Read the used range of the worksheet to an array
ReDim $aRead[UBound($aRead, 1)][UBound($aRead, 2)+1]                      ; Add a column to the array
Global $iFirstRow = $oWorkbook.Sheets(1).UsedRange.Row                    ; Get the first row number of the used range
Global $sFirstCell = $oWorkbook.Sheets(1).UsedRange.Range("A1").Address   ; Get the address of the top left cell of the used range
Global $ilastCol = UBound($aRead, 2)-1                                    ; Add the row index of the used range to the array
For $i = 0 To UBound($aRead, 1)-1
    $aRead[$i][$iLastCol] = $i + $iFirstRow
Next
_Excel_RangeWrite($oWorkbook, 1, $aRead, $sFirstCell)                     ; Write the modified array to the worksheet

 

Edited October 11, 2021 by water

[nikosliapis]

Quote

Global $iFirstRow = $oWorkbook.Sheets(1).UsedRange.Row                    ; Get the first row number of the used range
Global $sFirstCell = $oWorkbook.Sheets(1).UsedRange.Range("A1").Address

This was the "key" code that I couldn't figure out.

Thank you very much !!!

[water]

😃