So many applications have the ability to make sure that their window is always on bottom. How are they doing it?

[Draygoes]

Has anyone that can understand it seen the source code for something that creates a window that it wants to keep on bottom to see how it's done? I'm at a loss! All I can think of to do is repeatedly set its position to bottom most window, but there has to be a better way, right? 
Doing it my way causes the window to flicker.

A great example of an app that sets and keeps one of its windows always on bottom is any app that wants to write text on the wallpaper. 

Right now, my reason for wanting to do this is to make my own launcher that has buttons, my wifes picture, the ability to play audio... all of that. 

Why is there a way to set windows always on top, but not bottom? 

[Gianni]

??

; https://www.autoitscript.com/forum/topic/111608-window-always-on-bottom/?do=findComment&comment=782930
; https://www.autoitscript.com/forum/topic/104080-open-winow-in-background/?do=findComment&comment=736679

#include <WinAPI.au3>
$PID = Run("notepad.exe", "", @SW_HIDE) ; run notepad
$handle = _GetHwndFromPID($PID) ; get its handle

; set the parent to the desktop window so when you shownoactivate it is behind all other windows.
$origParent = DllCall("user32.dll", "int", "SetParent", "hwnd", $handle, "hwnd", WinGetHandle("Program Manager"))

; shownoactivate the window (notepad)
; it will stay behind all other windows even when you drag it around
_WinAPI_ShowWindow($handle, @SW_SHOWNOACTIVATE)
; $origParent2 = DllCall("user32.dll", "int", "SetParent", "hwnd", $handle, "hwnd",  $origParent[0])

; https://www.autoitscript.com/forum/topic/86680-pid-window-handle-hwnd-conversion/?do=findComment&comment=621521
Func _GetHwndFromPID($PID)
    $hWnd = 0
    $stPID = DllStructCreate("int")
    Do
        $winlist2 = WinList()
        For $i = 1 To $winlist2[0][0]
            If $winlist2[$i][0] <> "" Then
                DllCall("user32.dll", "int", "GetWindowThreadProcessId", "hwnd", $winlist2[$i][1], "ptr", DllStructGetPtr($stPID))
                If DllStructGetData($stPID, 1) = $PID Then
                    $hWnd = $winlist2[$i][1]
                    ExitLoop
                EndIf
            EndIf
        Next
        Sleep(100)
    Until $hWnd <> 0
    Return $hWnd
EndFunc   ;==>_GetHwndFromPID