wd_capabilities.au3 - support topic - early BETA version - Work In Progress

[mLipok]

wd_capabilities.au3 UDF was changed/modified/refactored .... and commited/merged (02-12-2021) to https://github.com/Danp2/WebDriver

WARNING: Before you start using this UDF be sure you download the recent version from: https://github.com/Danp2/WebDriver
 

==================================================================================================

Recently I start wd_capabilities.au3 project on my side.
I think this is time to share to AutoIt community.

Check attached UDF: wd_capabilities.au3

Here is a scratch example showing how to use them:

#include "wd_helper.au3"
#include "wd_capabilities.au3"

_Example()

Func _Example()
    ........
    ........
    ........
    _WD_Capabilities_Build_Arguments(Null) ; CLEANUP ARGS
    _WD_Capabilities_Build_Arguments('--headless')
    _WD_Capabilities_Build_Arguments('start-maximized')
    _WD_Capabilities_Build_Arguments('disable-infobars')
    _WD_Capabilities_Build_Arguments('user-data-dir', 'C:\Users\' & @UserName & '\AppData\Local\Google\Chrome\User Data\Default')
    Local $s_WD_Capabilities_Arguments = _WD_Capabilities_Build_Arguments(Default) ; GET ARGS

    _WD_Capabilities_Build_Preferences(Null) ; CLEANUP PREFS
    If $s_Download_dir Then _WD_Capabilities_Build_Preferences('download.default_directory', $s_Download_dir)
    Local $s_WD_Capabilities_Preferences = _WD_Capabilities_Build_Preferences(Default) ; GET PREFS

    Local $s_Desired_Capabilities = _WD_Capabilities_Build_JSON('chrome', $s_WD_Capabilities_Arguments, $s_WD_Capabilities_Preferences)

    Local $WD_SESSION = _WD_CreateSession($s_Desired_Capabilities)
    ........
    ........
    ........
EndFunc

 

I plan to publish the code on GitHub.
In the indefinite future, when the project becomes more functional, if @Danp2 accepts it, I hope it may be included in the main WebDriver UDF.

I am waiting for yours feedback and help in the further development of this project.

REMARK 1:
As so far this UDF only supports GoogleChrome.
Adding support for other browsers shouldn't be difficult, I just didn't need to.

REMARK 2:
For now, this project is working but still as a early BETA, so please do not discuss, ask questions, or post examples or snippets of code that pertain to any function of this UDF in other part of this forum, until it is found acceptable. Simply: discusion and tests only here in this topic.


Regards,
@mLipok

 

Edited December 1, 2021 by mLipok
wordings, some code improvements

[mLipok]

Here:
https://developer.mozilla.org/en-US/docs/Web/WebDriver/Capabilities#combining_alwaysmatch_and_firstmatch

I found this example:

{
  "capabilities": {
    "alwaysMatch": {
      "browserName": "firefox",
      "moz:firefoxOptions": {
        "profile": "<base64 encoded profile>",
        "args": ["-headless"],
        "prefs": {"dom.ipc.processCount": 8},
        "log":{"level": "trace"}
      }
    },
    "firstMatch": [
      {"platformName": "macos"},
      {"platformName": "linux"}
    ]
  }
}

My question is:
Do we need a feature to combine alwaysMatch and firstMatch ?

[Danyfirex]

I'm not sure about If It's required or no. But Maybe you can deduct it reading this. 

 

Saludos

[Danp2]

40 minutes ago, mLipok said:

Do we need a feature to combine alwaysMatch and firstMatch ?

My vote is no. 😉

[mLipok]

3 minutes ago, Danyfirex said:

But Maybe you can deduct it reading this. 

Nice findings.

[mLipok]

1 minute ago, Danp2 said:

My vote is no. 😉

Ok.

Do we need  alwaysMatch or firstMatch  but separately ?
I mean do we need a feature to choose between them ?

[Danp2]

Yes, I would recommend support for both options since that's in line with the W3C specs.

[mLipok]

Which one should be default for  WD UDF ?

[Danyfirex]

alwaysMatch I think. 

[mLipok]

I did a lot of further work on this project.
Currently, the example looks like this:

#include "wd_helper.au3"
#include "wd_capabilities.au3"

_Example()

Func _Example()
    ........
    ........
    ........
    _WD_Capabilities_BrowserSpecific_AddArgument(Null) ; CLEANUP ARGS
;~  _WD_Capabilities_BrowserSpecific_AddArgument('--headless')
    _WD_Capabilities_BrowserSpecific_AddArgument('start-maximized')
    _WD_Capabilities_BrowserSpecific_AddArgument('disable-infobars')
    _WD_Capabilities_BrowserSpecific_AddArgument('user-data-dir', 'C:\Users\' & @UserName & '\AppData\Local\Google\Chrome\User Data\Default')
    Local $s_WD_Capabilities_Arguments = _WD_Capabilities_BrowserSpecific_AddArgument(Default) ; GET ARGS

    _WD_Capabilities_BrowserSpecific_AddPreference(Null) ; CLEANUP PREFS
    If $s_Download_dir Then _WD_Capabilities_BrowserSpecific_AddPreference('download.default_directory', $s_Download_dir)
    Local $s_WD_Capabilities_Preferences = _WD_Capabilities_BrowserSpecific_AddPreference(Default) ; GET PREFS

    _WD_Capabilities_BrowserSpecific_AddLog(Null) ; CLEANUP LOGS
    Local $s_WD_Capabilities_BrowserSpecific_Logs = _WD_Capabilities_BrowserSpecific_AddLog(Default) ; GET LOGS

    _WD_Capabilities_BrowserSpecific_AddEnv(Null) ; CLEANUP ENVS
    Local $s_WD_Capabilities_BrowserSpecific_Envs = _WD_Capabilities_BrowserSpecific_AddEnv(Default) ; GET ENVS

    Local $s_Desired_Capabilities = _WD_Capabilities_Build_JSON('chrome', '', $s_WD_Capabilities_BrowserSpecific_Arguments, $s_WD_Capabilities_BrowserSpecific_Preferences, $s_WD_Capabilities_BrowserSpecific_Logs, $s_WD_Capabilities_BrowserSpecific_Envs)

    Local $WD_SESSION = _WD_CreateSession($s_Desired_Capabilities)
    ........
    ........
    ........
EndFunc   ;==>_Example

This should give a picture of the direction of change.

[Danyfirex]

wouldn't  it be possible to make it easier? I don't know but your suggested UDF seems to be complex for me. I also notice it could be ambiguous  to use _Add as a getter passing default as parameter. 

 

Saludos

 

 

[Danp2]

I wonder if it would make more sense to provide a GUI interface that can be used to generate the Capabilities string. I've found a couple of web-based examples --

https://www.browserstack.com/automate/capabilities

https://saucelabs.com/platform/platform-configurator#/

[mLipok]

For now I have such example:

Func _Example_Chrome()
    _WD_Capabilities_BrowserSpecific_AddArgument(Null) ; CLEANUP ARGS
;~  _WD_Capabilities_BrowserSpecific_AddArgument('--headless')
    _WD_Capabilities_BrowserSpecific_AddArgument('start-maximized')
    _WD_Capabilities_BrowserSpecific_AddArgument('disable-infobars')
    _WD_Capabilities_BrowserSpecific_AddArgument('user-data-dir', 'C:\Users\' & @UserName & '\AppData\Local\Google\Chrome\User Data\Default')

    _WD_Capabilities_BrowserSpecific_AddPreference(Null) ; CLEANUP PREFS
    _WD_Capabilities_BrowserSpecific_AddPreference('download.default_directory', @ScriptDir)

    _WD_Capabilities_BrowserSpecific_AddLog(Null) ; CLEANUP LOGS

    _WD_Capabilities_BrowserSpecific_AddEnv(Null) ; CLEANUP ENVS

    Local $s_Desired_Capabilities = _WD_Capabilities_Build_JSON('chrome')

    _WD_Option('Driver', 'chromedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()
    Local $WD_SESSION = _WD_CreateSession($s_Desired_Capabilities)
    #forceref $WD_SESSION
    MsgBox($MB_OK + $MB_TOPMOST + $MB_ICONINFORMATION, "Information #" & @ScriptLineNumber, "Waiting for close")
    _WD_Shutdown()
EndFunc   ;==>_Example_Chrome

I plan to remove the requirment of MANUALY CLEANUP.

@Danyfirex Is this what you thought about?

[Danyfirex]

Yes It's ok, What's the purpose of that long name _WD_Capabilities_BrowserSpecific_AddPreference? what about using a shorter name like _WD_Capabilities_AddPreference ,_WD_Capabilities_AddArgument

 

Saludos

 

[mLipok]

14 minutes ago, Danyfirex said:

What's the purpose of that long name _WD_Capabilities_BrowserSpecific_AddPreference?

It refers to the place where it is in WD and JSON
If AutoIt will be fully objective language I will do this like this:

....
$oWD_Capabilities.BrowserSpecific.AddPreference('download.default_directory', @ScriptDir)
....
Local $s_Desired_Capabilities = $oWD_Capabilities.Build_JSON()
....

 

btw.
I hope this is possible with some kind of magical AutoIt coding technique.

Edited September 2, 2021 by mLipok

[mLipok]

20 minutes ago, Danyfirex said:

what about using a shorter name like _WD_Capabilities_AddPreference ,_WD_Capabilities_AddArgument

Could be changed. Waiting for other users/members opinion ....

Edited September 2, 2021 by mLipok

[Danp2]

4 hours ago, Danyfirex said:

alwaysMatch I think. 

I agree. firstMatch usage could be indicated with an optional parameter.

I also agree that removing "BrowserSpecific" from the function name would be preferred.

 

[Danp2]

1 hour ago, mLipok said:

I hope this is possible with some kind of magical AutoIt coding technique

AKA maps 😃

[mLipok]

New version:
 

expandcollapse popup

#include "wd_helper.au3"
#include "wd_capabilities.au3"
_Example()
Exit

Func _Example()
    If $IDYES = MsgBox($MB_YESNO + $MB_TOPMOST + $MB_ICONQUESTION + $MB_DEFBUTTON1, "Question", _
            "Do you want to test with running browsers ?") Then
        Local $b_Headless = ($IDYES = MsgBox($MB_YESNO + $MB_TOPMOST + $MB_ICONQUESTION + $MB_DEFBUTTON1, "Question", "Do you want to test with headless mode ?"))
        _Example_Chrome(True, $b_Headless)
        _Example_FireFox(True, $b_Headless)
    Else ; only show $s_Desired_Capabilities in console
        _Example_Chrome(False)
        _Example_FireFox(False)
    EndIf
EndFunc   ;==>_Example

Func _Example_Chrome($b_Run_Browser, $b_Headless = False)
    _WD_Capabilities_Startup()
    _WD_Capabilities_AddOption('w3c', True)
;~  _WD_Capabilities_AddOption('browserName', 'chrome')
    If $b_Headless Then _
            _WD_Capabilities_AddArgument('--headless')
    _WD_Capabilities_AddArgument('start-maximized')
    _WD_Capabilities_AddArgument('disable-infobars')
    _WD_Capabilities_AddArgument('user-data-dir', 'C:\Users\' & @UserName & '\AppData\Local\Google\Chrome\User Data\Default')
    _WD_Capabilities_AddPreference('download.default_directory', @ScriptDir)

    Local $s_Desired_Capabilities = _WD_Capabilities_Build_JSON('chrome')
    If Not $b_Run_Browser Then
        ConsoleWrite($s_Desired_Capabilities & @CRLF)
        ConsoleWrite('=============' & @CRLF)
        Return
    EndIf

;~  $s_Desired_Capabilities = StringStripCR($s_Desired_Capabilities)
;~  $s_Desired_Capabilities = StringReplace($s_Desired_Capabilities, @TAB, '')
;~  ConsoleWrite($s_Desired_Capabilities & @CRLF)
;~  ConsoleWrite('=============' & @CRLF)

    _WD_Option('Driver', 'chromedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Startup()
    Local $WD_SESSION = _WD_CreateSession($s_Desired_Capabilities)
    MsgBox($MB_OK + $MB_TOPMOST + $MB_ICONINFORMATION, "Information #" & @ScriptLineNumber, "Waiting before _WD_Shutdown()")
    _WD_DeleteSession($WD_SESSION)
    _WD_Shutdown()
EndFunc   ;==>_Example_Chrome

Func _Example_FireFox($b_Run_Browser, $b_Headless = False)
    _WD_Capabilities_Startup()
;~  _WD_Capabilities_AddOption('browserName', 'firefox')
    If $b_Headless Then _
            _WD_Capabilities_AddArgument('--headless')
    Local $s_My_Profile_Dir = 'c:\Users\' & @UserName & '\AppData\Local\Mozilla\Firefox\Profiles\TESTING.default'
    _WD_Capabilities_AddArgument('-profile')
    _WD_Capabilities_AddArgument($s_My_Profile_Dir)

    _WD_Capabilities_AddPreference('dom.ipc.processCount', 8)
    _WD_Capabilities_AddPreference('javascript.options.showInConsole', 'false')
    _WD_Capabilities_AddPreference('browser.toolbars.bookmarks.visibility', 'always') ; check    about:config
    _WD_Capabilities_AddPreference('app.update.download.attempts', 0) ; check    about:config
    _WD_Capabilities_AddPreference('browser.safebrowsing.downloads.enabled', 'false') ; check    about:config

    _WD_Capabilities_AddLog('level', 'trace')

    _WD_Capabilities_AddEnv('MOZ_LOG', 'nsHttp:5')
    _WD_Capabilities_AddEnv('MOZ_LOG_FILE', $s_My_Profile_Dir & '\log')

    Local $s_Desired_Capabilities = _WD_Capabilities_Build_JSON('firefox')

    If Not $b_Run_Browser Then
        ConsoleWrite($s_Desired_Capabilities & @CRLF)
        ConsoleWrite('=============' & @CRLF)

        Return
    EndIf

;~  $s_Desired_Capabilities = StringStripCR($s_Desired_Capabilities)
;~  $s_Desired_Capabilities = StringReplace($s_Desired_Capabilities, @TAB, '')
;~  ConsoleWrite($s_Desired_Capabilities & @CRLF)
;~  ConsoleWrite('=============' & @CRLF)

    _WD_Option('Driver', 'geckodriver.exe')
    _WD_Option('Port', 4444)
    _WD_Startup()
    Local $WD_SESSION = _WD_CreateSession($s_Desired_Capabilities)
    MsgBox($MB_OK + $MB_TOPMOST + $MB_ICONINFORMATION, "Information #" & @ScriptLineNumber, "Waiting before _WD_Shutdown()")
    _WD_DeleteSession($WD_SESSION)
    _WD_Shutdown()
EndFunc   ;==>_Example_FireFox

 

wd_capabilities.zip

Edited September 3, 2021 by mLipok

[mLipok]

Did you try the latest version?
Is it works for you?

Do you have any other requests related to this UDF?

REMARK:
About feature "firstMatch" ... I have some concept in my mind.
But I don't think I would start implementing and testing it earlier than next week.

Edited September 3, 2021 by mLipok