AD UDF: lastLogon, lastLogonTimestamp results empty values

[mko]

$l_ret = _AD_GetObjectAttribute(@username,"lastLogon")
MsgBox(64,"whenCreated",$l_ret & @crlf & @error)

$l_ret has no value and no error (error is 0).

Same Probleme here:

$l_user = _AD_GetObjectsInOU("OU=test,OU=example,DC=mydomain,DC=domain,DC=com","(name=*)",2,"sAMAccountName,whenCreated,lastLogon,userAccountControl","sAMAccountName")

If i displays this array sAMAccountName,whenCreated and userAccountControl have values

lastlogon values are missing...

With an LDAP Browser  i could see those values...

any ideas ??

Thanks and Regards

Martin

 

Edited July 30, 2021 by mko

[Subz]

It returns an object from memory, I use the following to calculate the date from the object:

expandcollapse popup

#include <AD.au3>
#include <Array.au3>
#include <Date.au3>

_AD_Open()
    Global $g_aUserAccount = _AD_GetObjectProperties(@UserName, "samaccountname,lastlogon")
    Global $g_aUserAccounts = _AD_GetObjectsInOU("", "(&(&(objectcategory=person)(objectclass=user)(samaccountname=*)))", 2, "sAMAccountName,whenCreated,lastLogon,userAccountControl","sAMAccountName")
_AD_Close()
For $i = 1 To $g_aUserAccounts[0][0]
    $g_aUserAccounts[$i][2] = _Get_LastLogonDate($g_aUserAccounts[$i][2], 1)
Next
_ArrayDisplay($g_aUserAccount)
_ArrayDisplay($g_aUserAccounts)

Func _Get_LastLogonDate($_oLastLogon, $_iLastLogon = 1)
    Local $sAD_DTStruct, $sTemp3
    If $_iLastLogon = 1 Then
        If Not IsObj($_oLastLogon) Then Return ""
        If $_oLastLogon.LowPart = -1 Then Return ""
        If $_oLastLogon.LowPart > 0 And $_oLastLogon.HighPart > 0 Then
            $sAD_DTStruct = DllStructCreate("dword low;dword high")
            DllStructSetData($sAD_DTStruct, "Low", $_oLastLogon.LowPart)
            DllStructSetData($sAD_DTStruct, "High", $_oLastLogon.HighPart)
            $sAD_Temp = _Date_Time_FileTimeToSystemTime(DllStructGetPtr($sAD_DTStruct))
            $sTemp3 = _Date_Time_SystemTimeToTzSpecificLocalTime(DllStructGetPtr($sAD_Temp))
            Return _Date_Time_SystemTimeToDateTimeStr($sTemp3, 1)
        EndIf
    EndIf
    ; Convert IADsLargeInteger parts to 100ns count
    Local $iLastLogonLow = $_oLastLogon.LowPart
    Local $iLastLogonHigh = $_oLastLogon.HighPart
    If $iLastLogonLow < 0 Then $iLastLogonHigh += 1; Compensate for IADsLargeInteger interface error
    $iLastLogon = $iLastLogonHigh * 2 ^ 32
    $iLastLogon += $iLastLogonLow

    ; Check if user ever logged in
    If $iLastLogon = 0 Then
        Return ""
    Else
        ; Convert 100ns count to integer seconds
        Local $iSeconds = Floor($iLastLogon / 10000000)
        ; Convert seconds since 12:00AM January 01, 1601 to date string
        Local $sLastLogon = _DateAdd("S", $iSeconds, "1601/01/01 00:00:00")
        ; Return result
        Return $sLastLogon
    EndIf
EndFunc

 

Edited July 30, 2021 by Subz

[water]

Function _AD_GetObjectAttribute returns the values AS IS.
To get the attributes in a readable format use function _AD_GetObjetPÜroperties.

I just noticed that the documentation of this two functions needs to be enhanced

[mko]

Thanks for your answer.

 

I cound not imagine how i should create  the $_oLastLogon object.

 

I have tried this...

_Ad_Open()

$sUser="myuser"

Local $oUser = __AD_ObjGet("LDAP://" & $sAD_HostServer & "/" & $sUser)
MsgBox(64,$sUser,_Get_LastLogonDate($oUser))

_AD_Close()

Result is 0

 

Regads

 

 

 

[Subz]

Updated the post above with examples for both the _Get_LastLogonDate as well as _AD_GetObjectProperties which @water mentioned.

[mko]

Realy Great !  - I thought about it too complicated

Thanks for your help - already your first answer was correct, but I didn't read it carefully enough

Keypoint is to use: _Ad_GetObjectProperties instead of AD_GetObjectAttribute 

For all who stumble upon it here : If you have more then one domain controller use lastLogonTimestamp instead of lastLogon