Pause For loop when lost connection

[dphuc23]

Hi all

Is had a problem when using For loop. I want to stop the For loop when Internet connection is lost but it still execute.

Here is my code. Is there anything wrong?

#include <Constants.au3>
#include <WinAPIDiag.au3>

For $i = 1000 To 1 Step -1
    If _WinAPI_IsInternetConnected() Then
        ConsoleWrite($i & @CRLF)
        Sleep(1000) ; The variable $i will decrease by 1 unit every second
     Else
        ConsoleWrite("Connection no exists" & @CRLF)
        Sleep(1000)
     EndIf
Next

[FrancescoDiMuro]

ExitLoop

[dphuc23]

3 minutes ago, FrancescoDiMuro said:

ExitLoop

It will exit the For loop. I want the loop to stop and continue running after the network connection is back

[Jos]

Something like this (Untested):

#include <Constants.au3>
#include <WinAPIDiag.au3>

For $i = 1000 To 1 Step -1

    If Check_Connected() Then
        ConsoleWrite($i & @CRLF)
        Sleep(1000) ; The variable $i will decrease by 1 unit every second
    EndIf
Next

Func Check_Connected()
    While 1
        If _WinAPI_IsInternetConnected() Then
            Return true
        Else
            ConsoleWrite("Connection no exists" & @CRLF)
            Sleep(1000)
        EndIf
    WEnd
EndFunc   ;==>Check_Connected

Jos

[dphuc23]

2 minutes ago, Jos said:

Something like this (Untested):

#include <Constants.au3>
#include <WinAPIDiag.au3>

For $i = 1000 To 1 Step -1

    If Check_Connected() Then
        ConsoleWrite($i & @CRLF)
        Sleep(1000) ; The variable $i will decrease by 1 unit every second
    EndIf
Next

Func Check_Connected()
    While 1
        If _WinAPI_IsInternetConnected() Then
            Return true
        Else
            ConsoleWrite("Connection no exists" & @CRLF)
            Sleep(1000)
        EndIf
    WEnd
EndFunc   ;==>Check_Connected

Jos

Thanks. It worked perfectly. Also, I tried my code (below) but It doesn't seem to work very well 😅😅

Func Wait()
   Do
      ConsoleWrite("Connection no exists" & @CRLF)
   Until _WinAPI_IsInternetConnected() = True
  EndFunc

 

[JockoDundee]

Keeping your original code and adding one line:

#include <Constants.au3>
#include <WinAPIDiag.au3>

For $i = 1000 To 1 Step -1
    If _WinAPI_IsInternetConnected() Then
        ConsoleWrite($i & @CRLF)
        Sleep(1000) ; The variable $i will decrease by 1 unit every second
     Else
        ConsoleWrite("Connection no exists" & @CRLF)
        $i+=1
        Sleep(1000)
     EndIf
Next

 

[Dana]

Why not (untested):

For $i = 1000 To 1 Step -1
    While Not _WinAPI_IsInternetConnected()
        ConsoleWrite("Connection no exists" & @CRLF)
        Sleep(1000)
    WEnd
    ConsoleWrite($i & @CRLF)
    Sleep(1000) ; The variable $i will decrease by 1 unit every second
Next

 

[JockoDundee]

1 hour ago, Dana said:

Why not (untested):

Because if it can’t connect after so many tries, he wants it to exit.