[Gdip] How to draw text on transparent bitmap?

[memerim]

#include <GDIPlus.au3>

Text2PNG(@ScriptDir & "\x_2.png", 0x7DFFFFFF) ; Transparent text


Func Text2PNG($sFile, $iColor)
    _GDIPlus_Startup()
    Local $hImage = _GDIPlus_BitmapCreateFromFile ( $sFile )
    ;Local $hImage = _GDIPlus_BitmapCreateFromScan0(400, 250)

    ;$sFile2 = @ScriptDir & "\x_3.png"
    ;_GDIPlus_ImageSaveToFile($hImage, $sFile2)

    Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphics, $GDIP_TEXTRENDERINGHINT_ANTIALIAS)
    _GDIPlus_GraphicsClear($hGraphics, $iColor)
    _GDIPlus_GraphicsDrawString($hGraphics, "Hello", 0, 0, "Arial", 32, 0)
    _GDIPlus_ImageSaveToFile($hImage, $sFile)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hImage)
    _GDIPlus_Shutdown()
EndFunc   ;==>Text2PNG

The image is at 50% transparency, im trying to write the text on it with the same transparency.

What transparency lvl the text will need to be drawn, to achieve the same transparency as on the image, 50% too? (0x7DFFFFFF)

But atm it does not draw anything unless i create a new bitmap from scan, whats going on?

 

Spoiler

 

Edited July 21, 2021 by memerim

[UEZ]

Try this:

#include <GDIPlus.au3>

Text2PNG(@ScriptDir & "\x_2.png", 0xE0FFFFFF) ; Transparent text
ShellExecute(@ScriptDir & "\x_2.png")

Func Text2PNG($sFile, $iColor)
    _GDIPlus_Startup()
    Local $hImage = _GDIPlus_BitmapCreateFromScan0(400, 250)
    Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)
    _GDIPlus_GraphicsClear($hGraphics, 0x7F000000)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphics, $GDIP_TEXTRENDERINGHINT_ANTIALIAS)
    Local $hFormat = _GDIPlus_StringFormatCreate()
    Local $hFamily = _GDIPlus_FontFamilyCreate("Consolas")
    Local $hFont = _GDIPlus_FontCreate($hFamily, 32)
    Local $hBrush = _GDIPlus_BrushCreateSolid($iColor)
    _GDIPlus_StringFormatSetAlign($hFormat, 1)
    _GDIPlus_StringFormatSetLineAlign($hFormat, 1)
    _GDIPlus_GraphicsDrawStringEx($hGraphics, "Hello World", $hFont, _GDIPlus_RectFCreate(0, 0, 400, 250), $hFormat, $hBrush)
    _GDIPlus_ImageSaveToFile($hImage, $sFile)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hImage)
    _GDIPlus_Shutdown()
EndFunc   ;==>Text2PNG

 

Edited July 23, 2021 by UEZ

[memerim]

Hello @UEZ, the script resulted in a image without background, just the text, i would like to keep the background and just draw the text over it with the same level of transparency.

The result im trying to achieve is something similar to this image:

Spoiler

Its the same image of my first post, but now with the text  drawn, and both have the same level of transparency.

[UEZ]

Just add

_GDIPlus_GraphicsClear($hGraphics, 0xFF7F7F7F)

after 

Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)

and it should work as expected.

[memerim]

#include <GDIPlus.au3>

Text2PNG(@ScriptDir & "\x_2.png", 0x7DFFFFFF) ; Transparent text
ShellExecute(@ScriptDir & "\x_2.png")

Func Text2PNG($sFile, $iColor)
    _GDIPlus_Startup()
    Local $hImage = _GDIPlus_BitmapCreateFromScan0(400, 250)
    Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF7F7F7F)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphics, $GDIP_TEXTRENDERINGHINT_ANTIALIAS)
    Local $hFormat = _GDIPlus_StringFormatCreate()
    Local $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    Local $hFont = _GDIPlus_FontCreate($hFamily, 32)
    Local $hBrush = _GDIPlus_BrushCreateSolid($iColor)
    _GDIPlus_StringFormatSetAlign($hFormat, 1)
    _GDIPlus_StringFormatSetLineAlign($hFormat, 1)
    _GDIPlus_GraphicsDrawStringEx($hGraphics, "Hello World", $hFont, _GDIPlus_RectFCreate(0, 0, 400, 250), $hFormat, $hBrush)
    _GDIPlus_ImageSaveToFile($hImage, $sFile)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hImage)
    _GDIPlus_Shutdown()
EndFunc   ;==>Text2PNG

Now the image have no transparency:

Spoiler

 

[UEZ]

If you mean the background then set alpha channel of

_GDIPlus_GraphicsClear($hGraphics, 0x7F7F7F7F) (ARGB)

accordingly. Here 0x7F is semi-transparent.

Edited July 23, 2021 by UEZ

[memerim]

Thank you UEZ, the image generated by the script have much more less quality when you compare with this one:

Edited July 23, 2021 by memerim

[UEZ]

The code above

produces this output: 

You have to adjust the color of the background / text accordingly.

 

 

Edited July 23, 2021 by UEZ

[memerim]

And when the image is not just a single color but a gradient like this:

Edited July 23, 2021 by memerim

[UEZ]

Then look into the help file to checkout how to create a gradient background. 😉