_ArrayColInsert

[jugador]

Slight modification of @Melba23 _ArrayColInsert.

version 1.0 (support)
   > insert single blank row
   > insert 1D Array

 

expandcollapse popup

#include <Array.au3>

Local $o_Eg[6][] = [['A', 11, 22, 33, 44], _
                    ['B', 11, 22, 33, 44], _
                    ['C', 11, 22, 33, 44], _
                    ['D', 11, 22, 33, 44], _
                    ['E', 11, 22, 33, 44], _
                    ['F', 11, 22, 33, 44]]
_ArrayDisplay($o_Eg)

Local $fillArray[6] = ['XX', 'XX', 'XX', 'XX', 'XX', 'XX']
_ArrayDisplay($fillArray)

__ArrayColInsert($o_Eg, 5)
_ArrayDisplay($o_Eg)

__ArrayColInsert($o_Eg, 0)
_ArrayDisplay($o_Eg)

__ArrayColInsert($o_Eg, 0, $fillArray)
_ArrayDisplay($o_Eg)

__ArrayColInsert($o_Eg, UBound($o_Eg, 2), $fillArray)
_ArrayDisplay($o_Eg)


; #FUNCTION# =============================================================================
; Name...........: __ArrayColInsert()
; =========================================================================================
Func __ArrayColInsert(ByRef $aArray, $iColumn = 0, $ArrayFill = '')
    If Not IsArray($aArray) Then Return SetError(1, 0, -1)

    Local $bArray[UBound($aArray, 1)]
    If IsArray($ArrayFill) Then
        If (UBound($aArray, 1) <> UBound($ArrayFill, 1)) Then  Return SetError(1, 0, -1)
        $bArray = $ArrayFill
    Endif

    Local $iDim_1 = UBound($aArray, 1)
    Switch UBound($aArray, 0)
        Case 1
            Local $aTempArray[$iDim_1][2]
            Switch $iColumn
                Case 0, 1
                    For $i = 0 To $iDim_1 - 1
                        $aTempArray[$i][(Not $iColumn)] = $aArray[$i]
                        $aTempArray[$i][$iColumn] = $bArray[$i]
                    Next
                Case Else
                    Return SetError(3, 0, -1)
            EndSwitch
            $aArray = $aTempArray

        Case 2
            Local $iDim_2 = UBound($aArray, 2)
            If $iColumn < 0 Or $iColumn > $iDim_2 Then Return SetError(3, 0, -1)
            ReDim $aArray[$iDim_1][$iDim_2 + 1]
            For $i = 0 To $iDim_1 - 1
                For $j = $iDim_2 To $iColumn + 1 Step -1
                    $aArray[$i][$j] = $aArray[$i][$j - 1]
                Next
                $aArray[$i][$iColumn] = $bArray[$i]
            Next
        Case Else
            Return SetError(2, 0, -1)
    EndSwitch
    Return UBound($aArray, 0)
EndFunc

 

to download Array Insert Column ( version 2.0 )
https://www.autoitscript.com/forum/topic/206264-_arraycolinsert/?do=findComment&comment=1485725

Edited March 2, 2022 by jugador

[water]

Could you please be so kind and add some documentation to your example scripts?
Why is your code better than the original function?
Is it faster? Does it add functionality? Does it fix a bug? Unfortunately my cristal ball doesn't tell me
 

[jugador]

In Autoit 3.3.14.5 version (that's what I am using)

; #FUNCTION# ====================================================================================================================
; Author ........: Melba23
; Modified.......:
; ===============================================================================================================================
Func _ArrayColInsert(ByRef $aArray, $iColumn)

So @water you don't need cristal ball to know the difference 😛. Besides example is given just run it .

 

[Melba23]

jugador,

i agree with water. Please do offer some explanations of why you felt the need to create your specific UDF and how it differs from any existing function.

M23

[jugador]

@Melba23 now I am confuse 🤔 seeing you asking for explanation
with default _ArrayColInsert you can only insert blank column
but now you can insert blank column and also can insert 1D array (like $fillArray from 1st post)

Local $fillArray[6] = ['XX', 'XX', 'XX', 'XX', 'XX', 'XX']

 

[Nine]

@jugador  Maybe it is clear for you.  But not everybody remembers exactly all the parameters of all the functions.  This is why it is a good practice to give a bit of an explanation when posting an example.  You will most likely get a larger audience doing so...

[Melba23]

jugador,

Quote

@Melba23 now I am confuse 🤔 seeing you asking for explanation

As Nine pointed out above, not everyone remembers every parameter for every function. Even though I wrote the current versions of some of your recent _Array* examples I had to go and look at the details in the Help file before I spotted the difference in your versions. Explaining theses differences when you post would help everyone to see why you felt the need to produce slightly different functionalities.

And please do not take this as criticism of the UDFs themselves - if they are good enough we might even add them to the standard library.

M23

[jugador]

Don't feel updating 1st post as it complete different code

Array Insert Column ( version 2.0 )
    > insert single / multiple blank row
    > support insertion of 1D & 2D Array

Now do run the code for better explanation

#include <Array.au3>
#include "ArrayInsertCol.au3"

Local $o_Eg[6][] = [['A', 11, 22, 33, 44], _
                    ['B', 11, 22, 33, 44], _
                    ['C', 11, 22, 33, 44], _
                    ['D', 11, 22, 33, 44], _
                    ['E', 11, 22, 33, 44], _
                    ['F', 11, 22, 33, 44]]

Local $fillArray_A[6] = ['PP', 'PP', 'PP', 'PP', 'PP', 'PP']
Local $fillArray_C[6][] = [['AA', 'BB'], ['AA', 'BB'], ['AA', 'BB'], ['AA', 'BB'], ['AA', 'BB'], ['AA', 'BB']]

;__ArrayColInsert_V2($o_Eg, 1, '', 4)
__ArrayColInsert_V2($o_Eg, 0, '', 6)

;__ArrayColInsert_V2($o_Eg, 0, $fillArray_A)
;__ArrayColInsert_V2($o_Eg, 1, $fillArray_A)
;__ArrayColInsert_V2($o_Eg, UBound($o_Eg, 2), $fillArray_A)

;__ArrayColInsert_V2($o_Eg, 0, $fillArray_C)
;__ArrayColInsert_V2($o_Eg, 1, $fillArray_C)
;__ArrayColInsert_V2($o_Eg, UBound($o_Eg, 2), $fillArray_C)
_ArrayDisplay($o_Eg)


;__ArrayColInsert_V2($fillArray_A, 1, '', 2)
;__ArrayColInsert_V2($fillArray_A, 0, '', 4)

;__ArrayColInsert_V2($fillArray_A, 0, $fillArray_C)
;__ArrayColInsert_V2($fillArray_A, 1, $fillArray_C)
;_ArrayDisplay($fillArray_A)

 

__ArrayColInsert_V2 UDF

ArrayInsertCol.au3

Edited March 2, 2022 by jugador

[jugador]

Array Insert Column ( version 2.0 ) example link

https://www.autoitscript.com/forum/topic/207912-array-add-multiple-columns-with-data-array-right-add/?do=findComment&comment=1499926

Edited April 8, 2022 by jugador