ASC wrong number

[mike1950r]

Hi

i want the Asc Number of "ć", which is 262.

But with Asc("ć") i get 99 instead, which is the number for "c".

It's used in a script, which checks if a string contents any characters above 255.

Thanks for assistance.

 

cheers mike

[Danp2]

Have you looked into using AscW() instead of Asc()?

[mike1950r]

hi danp2,

i have tried without success.

cheers mike

[jchd]

The Unicode codepoint of ć is 0x107, that is decimal 263, not 262.

ConsoleWrite(AscW("ć") & @LF)

 

[mike1950r]

thanks jchd,

i do it this way, works fine.
was my fault.

thanks also danp2.

cheers mike

Edited July 7, 2021 by mike1950r

[mike1950r]

hi again,

is there an existing autoit function
or atleast a faster way for this:

$bSuccess = True

For $i = 1 To StringLen($sString)
    If ASCW(StringMid($sString, $i, 1)) > 255 Then
        $bSuccess = False

        ExitLoop
    EndIf
Next

Return $bSuccess

in fact "StringIsASCII($sString)" works much faster.

thanks for advice

cheers mike

[jchd]

; sample Unicode strings in AutoIt encoding (UCS2)
Local $a = [ _
    "All lower ASCII here!", _
    "Some characters ¼½¾ÀÁÇÖæÿ in upper ANSI 1252", _
    "Some characters > 0xFF: Μεγάλο πρόβλημα" _
]

For $s In $a
    ConsoleWrite('"' & $s & '"' & " contains " & (StringRegExp($s, "^[\x00-\x7F]*$") ? "" : "NOT ") & "only lower ASCII" & @LF)
    ConsoleWrite('"' & $s & '"' & " contains " & (StringRegExp($s, "[\x80-\xFF]") ? "some" : "NO ") & "upper ASCII" & @LF)
    ConsoleWrite('"' & $s & '"' & " contains " & (StringRegExp($s, "[\x{100}-\x{FFFF}]") ? "" : "NO ") & "characters > 0x100" & @LF)
Next

 

[mike1950r]

hi jchd,

thanks lot for the regex.

I modified my function with them:

Func StringIsANSI($sString)
    Local $bSuccess, $iLen

    $bSuccess = False

    $iLen = StringLen($sString)

    If $iLen > 0 Then
        If StringRegExp($sString, "[\x00-\x7F]") Or StringRegExp($sString, "[\x80-\xFF]") Then
            $bSuccess = True
        EndIf

        If StringRegExp($sString, "[\x{100}-\x{FFFF}]") Then
            $bSuccess = False
        EndIf
    EndIf

    Return $bSuccess
EndFunc   ;==>StringIsANSI

This works now exellent like in notepad.

If a string passes this function with success it can be saved with notepad as ANSI.

If the string includes for example "Mišel Matičević",
it does not pass the function with success and cannot be saved with notepad as ANSI.

Thanks lot again.

Cheers mike

[Danp2]

@mike1950r You should be able to do it with a single regex --

Func StringIsANSI($sString)
    Local $bSuccess, $iLen

    $bSuccess = True

    $iLen = StringLen($sString)

    If $iLen And StringRegEx($sString, "[^\x00-\xFF]") Then
        $bSuccess = False
    EndIf

    Return $bSuccess    
EndFunc   ;==>StringIsANSI

This returns True for an empty string, but otherwise it should match your earlier code.

[mike1950r]

thanks

cheers mike

Edited July 8, 2021 by mike1950r