Can GUICtrlSetOnEvent() be right clicked to catch events?Can Guictrlsetonevent() be right clicked to catch events?

[Loc]

I am needing to catch events with right click on Guictrlcreatebutton() and label

[Melba23]

ANHVN,

Welcome to the AutoIt forums.

If you look in the Help file under <GUI Reference - OnEvent Mode> you will see that you can detect the $GUI_EVENT_SECONDARYDOWN/UP messages in the @GUI_CtrlId macro. That should enable you to do what you require.

M23

[Loc]

I have found the code, please allow me to be saved here. Now I'm not sitting at the computer. I'm afraid the next time I look I won't find it

 

 

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetOnEvent($GUI_EVENT_SECONDARYUP, "_SecondaryUp")

$cButton = GUICtrlCreateButton("Test", 10, 10, 80, 30)
GUICtrlSetOnEvent($cButton, "_Button")
$cButton2 = GUICtrlCreateButton("Testz", 10, 50, 80, 30)
GUICtrlSetOnEvent($cButton2, "_Button")
GUISetState()

While 1
    Sleep(10)
WEnd

Func _Button()
    $nTempId = GUICtrlRead(@GUI_CtrlId)
    MsgBox($MB_SYSTEMMODAL, "Pressed", "LEFT " & $nTempId)
EndFunc   ;==>_Button

Func _SecondaryUp()
    $aCInfo = GUIGetCursorInfo($hGUI)
    Switch $aCInfo[4]
        Case $cButton
            $nTempId = GUICtrlRead($cButton) ;can get
            MsgBox($MB_SYSTEMMODAL, "Pressed", "RIGHT " & $nTempId)
        Case $cButton2
            $nTempId = GUICtrlRead($cButton2) ;can get
            MsgBox($MB_SYSTEMMODAL, "Pressed", "RIGHT2 " & $nTempId)
    EndSwitch

EndFunc   ;==>_SecondaryUp

Func _Exit()
    Exit
EndFunc   ;==>_Exit