WebDriver UDF - Help & Support (III)

[mLipok]

 Sorry @neypro I mistake it was request for @n3wbie

 

21 hours ago, n3wbie said:

\wd_helper.au3" (1408) : ==> The requested action with this object has failed.:
$FilesInZip = $oNameSpace.items
$FilesInZip = $oNameSpace^ ERROR

 

Still Getting Same error Downloaded Updated Version From Git Repo

 

 

@n3wbie try to use this: 

 

https://github.com/Danp2/au3WebDriver/pull/204/files

Here is direct link:

https://github.com/Danp2/au3WebDriver/blob/2bd163111ffe70c5c86604faed8e083650b32379/wd_helper.au3

 

Edited February 17, 2022 by mLipok

[Melba23]

neypro,

This sounds very like the request you made in this thread where you never gave a satisfactory reason for needing such a request - other then a vague "managing about 200 personal mail" which poses even more questions about your intentions.

So for the final time: why do you need to do this? And best make the explanation a good one.

M23

P.S. And just to be absolutely clear - this is the Mod team determining the legality of the this poster's intentions, so everyone else please do not offer any help until the Mod team are satisfied with the answer.

Edit: neypro has been back online since this post and has not answered (again). I have moved his posts to his earlier thread and he is now unable to post until he does.

Edited February 18, 2022 by Melba23

[mLipok]

On 2/15/2022 at 4:04 AM, mLipok said:

Here is good example test:

www.africau.edu/images/default/sample.pdf

I will create repro code.

 

I fix the issue with using prefs. I mean that PDF file is downloading automatically.

But I have some issue with navigate:

Please try this example:

expandcollapse popup

#include "wd_core.au3"
#include "wd_helper.au3"
#include "wd_capabilities.au3"

Global $_MY__WD_SESSION
_Test()

Exit

Func _Test()
    Local $s_FireFox_Binary = "C:\Program Files (x86)\Mozilla Firefox\firefox.exe"
    If $s_FireFox_Binary And FileExists($s_FireFox_Binary) = 0 Then $s_FireFox_Binary = ''

    Local $iAnswer = MsgBox($MB_YESNO + $MB_TOPMOST + $MB_ICONQUESTION + $MB_DEFBUTTON2, "Question", _
            "Open new sesion ?" & @CRLF & "[ NO ] = Try attach to active FireFox instance")
    If $iAnswer = $IDYES Then
        _Testing_CreateSession($s_FireFox_Binary)
;~      _Testing_WD_Navigate()
        Return     ; do not process next functions
    Else
        _Testing_AttachSession($s_FireFox_Binary)
        _WD_Navigate($_MY__WD_SESSION, 'https://www.google.com/')
    EndIf

    $iAnswer = MsgBox($MB_YESNO + $MB_TOPMOST + $MB_ICONQUESTION + $MB_DEFBUTTON2, "Question", _
            "Do you want to test ?" & @CRLF & "[ NO ] = Refresh - prevent expiration")
    If $iAnswer = $IDYES Then
        _Testing_WD_Navigate()
    Else
        _Testing_Refreshing()
    EndIf

    ; CleanUp
    _WD_DeleteSession($_MY__WD_SESSION)
    _WD_Shutdown()
EndFunc   ;==>_Test

Func _Testing_CreateSession($s_FireFox_Binary)
    $_MY__WD_SESSION = _MY__WD_SetupFireFox(False, '', $s_FireFox_Binary, True, False)
EndFunc   ;==>_Testing_CreateSession

Func _Testing_AttachSession($s_FireFox_Binary)
    $_MY__WD_SESSION = _MY__WD_SetupFireFox(False, '', $s_FireFox_Binary, False, True)
EndFunc   ;==>_Testing_AttachSession

Func _Testing_Refreshing()
    While 1
;~      _WD_Navigate($_MY__WD_SESSION, '')
        _WD_Action($_MY__WD_SESSION, 'REFRESH')
        Local $iAnswer = MsgBox($MB_YESNO + $MB_TOPMOST + $MB_ICONQUESTION + $MB_DEFBUTTON2, "Question", "Finish refreshing?" & @CRLF & "[No] = Refresh - prevent expiration", 60)
        If $iAnswer = $IDYES Then Return
    WEnd
EndFunc   ;==>_Testing_Refreshing

Func _MY__WD_SetupFireFox($b_Headless, $s_Download_dir = Default, $s_FireFox_Binary = '', $bMarionete = False, $bTryAttach = False)
    If $s_Download_dir = Default Then
        $s_Download_dir = ''
    ElseIf $s_Download_dir Then
        If FileExists($s_Download_dir) = 0 Then $s_Download_dir = ''
        $s_Download_dir = StringReplace($s_Download_dir, '\', '\\')
    EndIf

    _WD_UpdateDriver('firefox')
    If @error Then Return SetError(@error, @extended, '')

    #WARRNING DO NOT USE '--log-path=' BECAUSE OF   RODO / GDPR
    # _WD_Option('DriverParams', '--log-path="' & @ScriptDir & '\Log\' & @YEAR & @MON & @MDAY & '-' & @HOUR & @MIN & @SEC & ' Chrome - ZUS.log"')
    _WD_Option('Driver', 'geckodriver.exe')
    If $bMarionete Then _WD_Option('DriverParams', '--log trace --marionette-port 2828')
    If $bTryAttach Then _WD_Option('DriverParams', '--log trace --connect-existing  --marionette-port 2828')

    _WD_Option('Port', 4444)
    _WD_Option('DefaultTimeout', 1000)

    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch')
    _WD_CapabilitiesAdd('acceptInsecureCerts', True)
    _WD_CapabilitiesAdd('firstMatch', 'firefox')
    _WD_CapabilitiesAdd('args', '-profile')
    _WD_CapabilitiesAdd('args', @LocalAppDataDir & '\Mozilla\Firefox\Profiles\WD_Testing_Profile') ; CHANGE TO PROPER DIRECTORY PATH
    If $s_FireFox_Binary Then _WD_CapabilitiesAdd('binary', $s_FireFox_Binary)

;~  _WD_CapabilitiesAdd('prefs', 'browser.helperApps.neverAsk.saveToDisk', 'application/pdf')
;~  _WD_CapabilitiesAdd('prefs', 'browser.helperApps.neverAsk.saveToDisk', 'text/plain,text/csv,application/csv,application/vnd.ms-excel,text/comma-separat‌ed-values,application/excel,application/octet-stream,application/pdf')
    _WD_CapabilitiesAdd('prefs', 'browser.helperApps.neverAsk.saveToDisk', 'application/csv, text/csv, text/plain, application/pdf, application/octet-stream doc xls pdf txt')
    If $s_Download_dir Then _WD_CapabilitiesAdd('prefs', 'browser.download.dir', $s_Download_dir)
    If $s_Download_dir Then _WD_CapabilitiesAdd('prefs', 'download.default_directory', $s_Download_dir)
;~  https://gist.github.com/Kannamaraj/4ca929c4e63cc39958e75d5126c113ad
    _WD_CapabilitiesAdd('prefs', 'browser.helperApps.alwaysAsk.force', False)
    _WD_CapabilitiesAdd('prefs', 'browser.download.manager.showWhenStarting', False)
    _WD_CapabilitiesAdd('prefs', 'browser.download.manager.focusWhenStarting', False)
    _WD_CapabilitiesAdd('prefs', 'browser.download.manager.alertOnEXEOpen', False)
    _WD_CapabilitiesAdd('prefs', 'browser.download.manager.showAlertOnComplete', False)
    _WD_CapabilitiesAdd('prefs', 'browser.download.manager.useWindow', False)
    _WD_CapabilitiesAdd('prefs', 'browser.download.manager.closeWhenDone', True)
    _WD_CapabilitiesAdd('prefs', 'browser.download.useDownloadDir', True)
    _WD_CapabilitiesAdd('prefs', 'pdfjs.disabled', True)

    If $b_Headless Then _
            _WD_CapabilitiesAdd('args', '--headless')

    _WD_CapabilitiesDump(@ScriptLineNumber & ' :WebDriver:Capabilities:')
    Local $s_Capabilities = _WD_CapabilitiesGet()

    _WD_Startup()
    If @error Then Return SetError(@error, @extended, '')

    Local $WD_SESSION = _WD_CreateSession($s_Capabilities)
    Return SetError(@error, @extended, $WD_SESSION)

EndFunc   ;==>_MY__WD_SetupFireFox

Func _Testing_WD_Navigate()
    _WD_Navigate($_MY__WD_SESSION, 'http://www.africau.edu/images/default/sample.pdf')
EndFunc   ;==>_Testing_WD_Navigate

 

The problem which I see is here:

Quote

__WD_Post: URL=HTTP://127.0.0.1:4444/session/fe276ff2-09cd-4d3e-a2b2-775beb3eae90/url; $sData={"url":"http://www.africau.edu/images/default/sample.pdf"}
__WD_Post: StatusCode=0; ResponseText=WinHTTP request timed out before Webdriver...
__WD_Post ==> Send / Recv error: WinHTTP request timed out before Webdriver
_WD_Navigate: WinHTTP request timed out before Webdriver
_WD_Navigate ==> Send / Recv error: HTTP status = 0
__WD_Delete: URL=HTTP://127.0.0.1:4444/session/fe276ff2-09cd-4d3e-a2b2-775beb3eae90
__WD_Delete: StatusCode=0; ResponseText=WinHTTP request timed out before Webdriver...
__WD_Delete ==> Webdriver Exception: WinHTTP request timed out before Webdriver
_WD_DeleteSession: WinHTTP request timed out before Webdriver
_WD_DeleteSession ==> Webdriver Exception: HTTP status = 0

The question is why there is TimeOut ?
You must to know that the file is downloaded fine.

Edited February 18, 2022 by mLipok

[mLipok]

btw.
Did you know that you can do something like this:

Local $vResponse = __WD_GET('http://www.africau.edu/images/default/sample.pdf')
    FileWrite(@ScriptDir & '\Sample.pdf', $vResponse)

 

[Danp2]

2 hours ago, mLipok said:

The question is why there is TimeOut ?

Geckodriver clearly isn't receiving a response from the browser post navigation. Have you tried testing this with a different browser?

Quote

Did you know that you can do something like this

Yes, but it isn't recommended because 1) the function is flagged for internal use only, and 2) it will only with with direct URLs (no redirection or HTML processing)

[Danp2]

On 2/18/2022 at 8:25 PM, Danp2 said:

Geckodriver clearly isn't receiving a response from the browser post navigation. Have you tried testing this with a different browser?

FWIW, I performed a simple test with Chrome and it gave the expected response. Therefore I believe this is a bug in Firefox.

__WD_Post: StatusCode=200; ResponseText={"value":{"capabilities":{"acceptInsecureCerts":false,"browserName":"chrome","browserVersion":"98.0....
_WD_CreateSession: {"value":{"capabilities":{"acceptInsecureCerts":false,"browserName":"chrome","browserVersion":"98.0.4758.102","chrome":{"chromedriverVersion":"98.0.4758.102 (273bf7ac8c909cde36982d27f66f3c70846a3718-refs/branch-heads/4758@)","userDataDir":"C:\\Users\\danpo\\AppData\\Local\\Temp\\scoped_dir31052_491909246"},"goog:chromeOptions":{"debuggerAddress":"localhost:50483"},"networkConnectionEnabled":false,"pageLoadStrategy":"normal","platformName":"windows","proxy":{},"setWindowRect":true,"strictFileInteractability":false,"timeouts":{"implicit":0,"pageLoad":300000,"script":30000},"unhandledPromptBehavior":"dismiss and notify","webauthn:extension:credBlob":true,"webauthn:extension:largeBlob":true,"webauthn:virtualAuthenticators":true},"sessionId":"81d5fc4a2ee8b2e73e898c0585df60d9"}}
__WD_Post: URL=HTTP://127.0.0.1:9515/session/81d5fc4a2ee8b2e73e898c0585df60d9/url; $sData={"url":"http://www.africau.edu/images/default/sample.pdf"}
__WD_Post: StatusCode=200; ResponseText={"value":null}...
_WD_Navigate: {"value":null}
+>18:18:16 AutoIt3.exe ended.rc:0
+>18:18:16 AutoIt3Wrapper Finished.
>Exit code: 0    Time: 6.716

 

[n3wbie]

On 2/17/2022 at 4:28 AM, mLipok said:

fix is on the way

is ti fixed?

where can i get latest release?

[mLipok]

6 hours ago, n3wbie said:

is ti fixed?

where can i get latest release?

Not yet in release.
Still WorkInProgress.

https://github.com/Danp2/au3WebDriver/pull/204/files

You can use my branch (on which is temporary my current WIP stage).
https://github.com/mlipok/WebDriver/tree/wd_update

 

Edited February 21, 2022 by mLipok

[n3wbie]

6 minutes ago, mLipok said:

Not yet in release.
Still WorkInProgress.

https://github.com/Danp2/au3WebDriver/pull/204/files

You can use my branch (on which is temporary my current WIP stage).
https://github.com/mlipok/WebDriver/tree/wd_update

 

Okay thanks.

I Currently Updated Zip Code to 7Zip Code as it was already in my project.

Currently It Works Fine as i Removed All error Handlers and Just Goes In Background Wihtout Any Checks.

Although i understand this is not a good practice and cannot be updated in main library.

Thanks For So rapid Development of query

[mLipok]

2 hours ago, n3wbie said:

as i Removed All error Handlers and Just Goes In Background Wihtout Any Checks.

Please elaborate.

[n3wbie]

On 2/21/2022 at 7:54 PM, mLipok said:

Please elaborate.

Changes as In Wd_Helper.au3

#include <7Zip.au3> 

...

If @error Then
       $iErr = $_WD_ERROR_GeneralError
Else
        For $FileItem In $FilesInZip ; Check the files in the archive separately
        $hWnd = _7ZipStartup()
         _7ZipExtractEx("", $sTempFile, $sInstallDir, 1, 1)

 

 

This Changes Make Script Work for Me For Time Being.

Edited February 23, 2022 by n3wbie
Added Code Format Block to make it look pretty.

[mLipok]

@n3wbie

Did you check if the current version: https://github.com/Danp2/au3WebDriver/releases/tag/0.6.0
Solve this issue on your side?

Of course without any additionall fix made by your self:  

5 hours ago, n3wbie said:

Changes as In Wd_Helper.au3

#include <7Zip.au3> 

...

If @error Then
       $iErr = $_WD_ERROR_GeneralError
Else
        For $FileItem In $FilesInZip ; Check the files in the archive separately
        $hWnd = _7ZipStartup()
         _7ZipExtractEx("", $sTempFile, $sInstallDir, 1, 1)

 

 

Edited February 23, 2022 by mLipok

[mLipok]

Today I faced the problem on one of my clients PC.
I analyze the problem with this mod:

expandcollapse popup

Func _WD_UpdateDriver($sBrowser, $sInstallDir = Default, $bFlag64 = Default, $bForce = Default)
    Local Const $sFuncName = "_WD_UpdateDriver"
    $_WD_CONSOLE = _Log
    Local $iErr = $_WD_ERROR_Success, $sDriverEXE, $sBrowserVersion, $bResult = False
    Local $sDriverCurrent, $sVersionShort, $sDriverLatest, $sURLNewDriver
    Local $sTempFile, $oShell, $FilesInZip, $sResult, $iStartPos, $iConversion
    Local $bKeepArch = False

    If $sInstallDir = Default Then $sInstallDir = @ScriptDir
    If $bForce = Default Then $bForce = False
    If $bFlag64 = Default Then
        $bFlag64 = False
        $bKeepArch = True
    EndIf

    $sInstallDir = StringRegExpReplace($sInstallDir, '(?i)(\\)\Z', '') & '\' ; prevent double \\ on the end of directory
    Local $bNoUpdate = (IsKeyword($bForce) = $KEYWORD_NULL) ; Flag to track if updates should be performed

    ; If the Install directory doesn't exist and it can't be created, then set error
    If (Not FileExists($sInstallDir)) And (Not DirCreate($sInstallDir)) Then
        $iErr = $_WD_ERROR_InvalidValue
    Else
        ; Save current debug level and set to none
        Local $WDDebugSave = $_WD_DEBUG
        $_WD_DEBUG = $_WD_DEBUG_None

        $sBrowserVersion = _WD_GetBrowserVersion($sBrowser)
        $iErr = @error

        If $iErr = $_WD_ERROR_Success Then
            Switch $sBrowser
                Case 'chrome'
                    $sDriverEXE = "chromedriver.exe"
                Case 'firefox'
                    $sDriverEXE = "geckodriver.exe"
                Case 'msedge'
                    $sDriverEXE = "msedgedriver.exe"
            EndSwitch

            ; Determine current local webdriver Architecture
            If FileExists($sInstallDir & $sDriverEXE) Then
                _WinAPI_GetBinaryType($sInstallDir & $sDriverEXE)
                Local $bDriverIs64Bit = (@extended = $SCS_64BIT_BINARY)
                If $bKeepArch Then $bFlag64 = $bDriverIs64Bit
                If $sBrowser <> 'chrome' And $bDriverIs64Bit <> $bFlag64 Then
                    $bForce = True
;~                  If $WDDebugSave = $_WD_DEBUG_Info Then
;~                      __WD_ConsoleWrite($sFuncName & ': ' & $sDriverEXE & ' = ' & (($bDriverIs64Bit) ? ("switching 64>32 Bit") : ("switching 32>64 Bit")) & @CRLF)
;~                  EndIf
                EndIf
            EndIf

            $sDriverCurrent = _WD_GetWebDriverVersion($sInstallDir, $sDriverEXE)

            ; Determine latest available webdriver version for the designated browser
            Switch $sBrowser
                Case 'chrome'
                    $sVersionShort = StringLeft($sBrowserVersion, StringInStr($sBrowserVersion, ".", 0, -1) - 1)
                    $sDriverLatest = BinaryToString(InetRead('https://chromedriver.storage.googleapis.com/LATEST_RELEASE_' & $sVersionShort))
                    $sURLNewDriver = "https://chromedriver.storage.googleapis.com/" & $sDriverLatest & "/chromedriver_win32.zip"

                Case 'firefox'
                    $sResult = BinaryToString(InetRead("https://github.com/mozilla/geckodriver/releases/latest"))

                    If @error = $_WD_ERROR_Success Then
                        $sDriverLatest = StringRegExp($sResult, '<a.*href="\/mozilla\/geckodriver\/releases\/tag\/(.*?)"', 1)[0]
                        If StringLeft($sDriverLatest, 1) = 'v' Then $sDriverLatest = StringMid($sDriverLatest, 2)

                        $sURLNewDriver = "https://github.com/mozilla/geckodriver/releases/download/v" & $sDriverLatest & "/geckodriver-v" & $sDriverLatest
                        $sURLNewDriver &= ($bFlag64) ? "-win64.zip" : "-win32.zip"
                    Else
                        $iErr = $_WD_ERROR_GeneralError
                    EndIf

                Case 'msedge'
                    $sVersionShort = StringLeft($sBrowserVersion, StringInStr($sBrowserVersion, ".") - 1)
                    $sDriverLatest = InetRead('https://msedgedriver.azureedge.net/LATEST_RELEASE_' & $sVersionShort)

                    If @error = $_WD_ERROR_Success Then
                        Select
                            Case BinaryMid($sDriverLatest, 1, 4) = '0x0000FEFF'                   ; UTF-32 BE
                                $iStartPos = 5
                                $iConversion = $SB_UTF16LE
                            Case BinaryMid($sDriverLatest, 1, 4) = '0xFFFE0000'                   ; UTF-32 LE
                                $iStartPos = 5
                                $iConversion = $SB_UTF16LE
                            Case BinaryMid($sDriverLatest, 1, 2) = '0xFEFF'                       ; UTF-16 BE
                                $iStartPos = 3
                                $iConversion = $SB_UTF16BE
                            Case BinaryMid($sDriverLatest, 1, 2) = '0xFFFE'                       ; UTF-16 LE
                                $iStartPos = 3
                                $iConversion = $SB_UTF16LE
                            Case BinaryMid($sDriverLatest, 1, 3) = '0xEFBBBF'                     ; UTF-8
                                $iStartPos = 4
                                $iConversion = $SB_UTF8
                            Case Else
                                $iStartPos = 1
                                $iConversion = $SB_ANSI
                        EndSelect

                        $sDriverLatest = StringStripWS(BinaryToString(BinaryMid($sDriverLatest, $iStartPos), $iConversion), $STR_STRIPTRAILING)
                        $sURLNewDriver = "https://msedgedriver.azureedge.net/" & $sDriverLatest & "/edgedriver_"
                        $sURLNewDriver &= ($bFlag64) ? "win64.zip" : "win32.zip"
                    Else
                        $iErr = $_WD_ERROR_GeneralError
                    EndIf
            EndSwitch

            If $iErr = $_WD_ERROR_Success Then
                Local $bUpdateAvail = (_VersionCompare($sDriverCurrent, $sDriverLatest) < 0) ; 0 - Both versions equal ; 1 - Version1 greater ; -1 - Version2 greater

                If $bNoUpdate Then
                    ; Set return value to indicate if newer driver is available
                    $bResult = $bUpdateAvail
                ElseIf $bUpdateAvail Or $bForce Then
                    ; @TempDir should be used to avoid potential AV problems, for example by downloading stuff to @DesktopDir
                    $sTempFile = _TempFile(@TempDir, "webdriver_", ".zip")
                    _WD_DownloadFile($sURLNewDriver, $sTempFile)
                    If @error Then
                        $iErr = @error
                    Else
                        ; Close any instances of webdriver
                        __WD_CloseDriver($sDriverEXE)

                        #Region - Extract new instance of webdriver
                        ; Handle COM Errors
                        Local $oErr = ObjEvent("AutoIt.Error", __WD_ErrHnd)
                        #forceref $oErr
                        $oShell = ObjCreate("Shell.Application")
                        If @error Then
                            $iErr = $_WD_ERROR_GeneralError
                        ElseIf FileGetSize($sTempFile) = 0 Or IsObj($oShell.NameSpace($sTempFile)) = 0 Then
                            $iErr = $_WD_ERROR_FileIssue
                        Else
                            Local $oNameSpace = $oShell.NameSpace($sTempFile)
                            __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & @CRLF)
                            $FilesInZip = $oNameSpace.items
                            If @error Then
                                __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & @CRLF)
                                $iErr = $_WD_ERROR_GeneralError
                            Else
                                __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & @CRLF)
                                ; delete webdriver from disk before unpacking to avoid potential problems
                                FileDelete($sInstallDir & $sDriverEXE)
                                For $FileItem In $FilesInZip ; Check the files in the archive separately
                                    ; https://docs.microsoft.com/pl-pl/windows/win32/shell/folder
                                    ; https://docs.microsoft.com/pl-pl/windows/win32/shell/folder-items
                                    ; https://docs.microsoft.com/pl-pl/windows/win32/shell/folderitem
                                    __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & ' ' & $FileItem.Name & @CRLF)
                                    __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & ' ' & $FileItem.Type & @CRLF)
                                    __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & ' ' & $FileItem.Path & @CRLF)
                                    If StringRight($FileItem.Name, 4) = ".exe" Or StringRight($FileItem.Path, 4) = ".exe" Then ; extract only EXE files
;~                                      Windows Feature Experience Pack 120.2212.4170.0
                                        $oShell.NameSpace($sInstallDir).CopyHere($FileItem, 20) ; 20 = (4) Do not display a progress dialog box. + (16) Respond with "Yes to All" for any dialog box that is displayed.
                                        __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber)
                                    EndIf
                                Next
                                If @error Then
                                    $iErr = $_WD_ERROR_GeneralError
                                Else
                                    $iErr = $_WD_ERROR_Success
                                    $bResult = True
                                EndIf
                            EndIf
                        EndIf
                        #EndRegion - Extract new instance of webdriver
                    EndIf
                    __WD_ConsoleWrite($sFuncName & ': TempFile = ' & $sTempFile & ' >> Size =' & FileGetSize($sTempFile) & @CRLF)
                    __WD_ConsoleWrite($sFuncName & ': Local File = ' & $sInstallDir & $sDriverEXE & @CRLF)
                    __WD_ConsoleWrite($sFuncName & ': URLNewDriver = ' & $sURLNewDriver & @CRLF)
                    __WD_ConsoleWrite($sFuncName & ': DriverCurrent = ' & $sDriverCurrent & ' : DriverLatest = ' & $sDriverLatest & @CRLF)
                    __WD_ConsoleWrite($sFuncName & ': Error = ' & $iErr & ' : Result = ' & $bResult & @CRLF)
                    MsgBox(0, "TEST UPDATE", @ScriptLineNumber)
                    FileDelete($sTempFile)
                EndIf
            EndIf
        EndIf

        ; Restore prior setting
        $_WD_DEBUG = $WDDebugSave
    EndIf

    If $_WD_DEBUG = $_WD_DEBUG_Info Then
        __WD_ConsoleWrite($sFuncName & ': TempFile = ' & $sTempFile & ' >> Size =' & FileGetSize($sTempFile) & @CRLF)
        __WD_ConsoleWrite($sFuncName & ': Local File = ' & $sInstallDir & $sDriverEXE & @CRLF)
        __WD_ConsoleWrite($sFuncName & ': URLNewDriver = ' & $sURLNewDriver & @CRLF)
        __WD_ConsoleWrite($sFuncName & ': DriverCurrent = ' & $sDriverCurrent & ' : DriverLatest = ' & $sDriverLatest & @CRLF)
        __WD_ConsoleWrite($sFuncName & ': Error = ' & $iErr & ' : Result = ' & $bResult & @CRLF)
    EndIf

    $_WD_CONSOLE = Null

    Return SetError(__WD_Error($sFuncName, $iErr), 0, $bResult)
EndFunc   ;==>_WD_UpdateDriver

The main issue was here:

For $FileItem In $FilesInZip ; Check the files in the archive separately
                                    ; https://docs.microsoft.com/pl-pl/windows/win32/shell/folder
                                    ; https://docs.microsoft.com/pl-pl/windows/win32/shell/folder-items
                                    ; https://docs.microsoft.com/pl-pl/windows/win32/shell/folderitem
                                    __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & ' ' & $FileItem.Name & @CRLF)
                                    __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & ' ' & $FileItem.Type & @CRLF)
                                    __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber & ' ' & $FileItem.Path & @CRLF)
                                    If StringRight($FileItem.Name, 4) = ".exe" Or StringRight($FileItem.Path, 4) = ".exe" Then ; extract only EXE files
;~                                      Windows Feature Experience Pack 120.2212.4170.0
                                        $oShell.NameSpace($sInstallDir).CopyHere($FileItem, 20) ; 20 = (4) Do not display a progress dialog box. + (16) Respond with "Yes to All" for any dialog box that is displayed.
                                        __WD_ConsoleWrite($sFuncName & ': ' & @ScriptLineNumber)
                                    EndIf
                                Next

The reson was that on some system $FileItem.Name returns only name without extension.
Solution was to check also: $FileItem.Path

I create PR ASAP.

 

EDIT:
It occurs on Windows 10 Pro 64Bit Windows Feature Experience Pack 120.2212.4170.0
 

@n3wbie please share informationa about yours windows version.

 

Edited February 23, 2022 by mLipok

[mLipok]

@n3wbie

Take a look here:

https://github.com/Danp2/au3WebDriver/pull/215

https://github.com/Danp2/au3WebDriver/pull/215/files

 

You can try to use the file from here:

https://github.com/Danp2/au3WebDriver/blob/998d430f682611caa6a0ff704a7c5d447ecc7b3d/wd_helper.au3

 

[n3wbie]

1 hour ago, mLipok said:

@n3wbie

Take a look here:

https://github.com/Danp2/au3WebDriver/pull/215

https://github.com/Danp2/au3WebDriver/pull/215/files

 

You can try to use the file from here:

https://github.com/Danp2/au3WebDriver/blob/998d430f682611caa6a0ff704a7c5d447ecc7b3d/wd_helper.au3

 

 

>"C:\Program Files (x86)\AutoIt3\SciTE\..\AutoIt3.exe" "C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.au3" /run /prod /ErrorStdOut /in "G:\GIT\Vinfur 2\Vinfur-2\Application\Itax.au3" /UserParams    
+>18:51:19 Starting AutoIt3Wrapper (19.1127.1402.0} from:SciTE.exe (4.2.0.0)  Keyboard:00000409  OS:WIN_7/Service Pack 1  CPU:X64 OS:X64  Environment(Language:0409)  CodePage:0  utf8.auto.check:4
+>         SciTEDir => C:\Program Files (x86)\AutoIt3\SciTE   UserDir => C:\Users\COMP\AppData\Local\AutoIt v3\SciTE\AutoIt3Wrapper   SCITE_USERHOME => C:\Users\COMP\AppData\Local\AutoIt v3\SciTE 
>Running AU3Check (3.3.14.5)  from:C:\Program Files (x86)\AutoIt3  input:G:\GIT\Vinfur 2\Vinfur-2\Application\Itax.au3
+>18:51:21 AU3Check ended.rc:0
>Running:(3.3.14.5):C:\Program Files (x86)\AutoIt3\autoit3.exe "G:\GIT\Vinfur 2\Vinfur-2\Application\Itax.au3"    
+>Setting Hotkeys...--> Press Ctrl+Alt+Break to Restart or Ctrl+BREAK to Stop.

]"G:\GIT\Vinfur 2\Vinfur-2\Application\wd_helper.au3" (1424) : ==> The requested action with this object has failed.:
$oShell.NameSpace($sInstallDir).CopyHere($FileItem, 20)
$oShell.NameSpace($sInstallDir)^ ERROR
->18:51:59 AutoIt3.exe ended.rc:1
+>18:51:59 AutoIt3Wrapper Finished.
>Exit code: 1    Time: 41.12

I Changed Wd_helper.au3

and Added error codes to wd_core.au3 as 

        $_WD_ERROR_FileIssue, _ ;
        $_WD_ERROR_COUNTER ;

this and 

        "User Aborted", _
        "File issue" _

were changed.

Still Getting The same issue.

Edited February 23, 2022 by n3wbie

[mLipok]

2 hours ago, n3wbie said:

I Changed Wd_helper.au3

and Added error codes to wd_core.au3 as 

        $_WD_ERROR_FileIssue, _ ;
        $_WD_ERROR_COUNTER ;

this and 

        "User Aborted", _
        "File issue" _

were changed.

You do not need to do this.

Just firstly upgrade yours Au3WD to: https://github.com/Danp2/au3WebDriver/releases/tag/0.6.0

And I have a question:
Can you use non compiled version to test or you need to provide EXE to your testing environment ?

EDIT:
Or just use download current https://github.com/Danp2/au3WebDriver 

Or even by using this link: https://github.com/Danp2/au3WebDriver/archive/refs/heads/master.zip
Which already contain my todays fix.

 

Edited February 23, 2022 by mLipok

[n3wbie]

2 hours ago, mLipok said:

You do not need to do this.

Just firstly upgrade yours Au3WD to: https://github.com/Danp2/au3WebDriver/releases/tag/0.6.0

And I have a question:
Can you use non compiled version to test or you need to provide EXE to your testing environment ?

EDIT:
Or just use download current https://github.com/Danp2/au3WebDriver 

Or even by using this link: https://github.com/Danp2/au3WebDriver/archive/refs/heads/master.zip
Which already contain my todays fix.

 

I can use non compiled version to test...

Also I can share system via anydesk if required

I have system access .as the error is at my own place...

I ll download latest version...

I didn't change whole of udf as I had changed some of desired capabilities args as per my requirements.

Will test tomorrow and repost the results again

 

 

[mLipok]

59 minutes ago, n3wbie said:

I had changed some of desired capabilities args as per my requirements

Please elaborate.

[minhuy]

Hello everyone. i am using an application that requires cURL input to be able to run the program. currently it takes time to get cURL manually, is there any way I can get cURL quickly? i can login the website using webdriver

[Danp2]

Hi @minhuy,

Please provide additional details so that we can better assist you. For example --

• Browser in use
• Basic steps to perform the function manually
• etc

Dan

P.S. One of the nice admins moved your post to this thread instead of the one in the Examples section. Please post any further inquiries here.