Step through and rewrite Json

[wisem2540]

Below is a sample output from xteve.  Xteve is used to pass streams from an HDHomeRun, modify them, then pass to plex.  When doing testing, I frequently have to rebuild my config, and readd the icons and such.  I would like to use auto it to step through the Json and take certain actions.  But, I do not know the best way to target each line.

 

Obviously, I do not know a ton about the json structure, but each element or section represents a single channel.  So I would want to do something like this...

 

If "name" contains "Fox 2" Then...

"x-update-channel-icon" = True
    "x-update-channel-name" = True

then anytime I need to rebuild, I can just execute the script.  

 

Any help would be appreciated.  Thanks

 

 

 

 

"x-ID.0": {
    "_file.m3u.id": "MK5LHDCC78UBXBVV9K1W",
    "_file.m3u.name": "File",
    "_file.m3u.path": "/root/.xteve/data/MK5LHDCC78UBXBVV9K1W.m3u",
    "group-title": "",
    "name": "Fox 2 KTVI",
    "tvg-id": "fox2ktvi.us",
    "tvg-logo": "",
    "tvg-name": "",
    "url": "",
    "_uuid.key": "",
    "_values": "",
    "x-active": false,
    "x-category": "",
    "x-channelID": "1000",
    "x-epg": "x-ID.0",
    "x-group-title": "",
    "x-mapping": "-",
    "x-xmltv-file": "-",
    "x-name": "Fox 2 KTVI | HD",
    "x-update-channel-icon": false,
    "x-update-channel-name": false,
    "x-description": ""
  },

"x-ID.1": {
    "_file.m3u.id": "MK5LHDCC78UBXBVV9K1W",
    "_file.m3u.name": "File",
    "_file.m3u.path": "/root/.xteve/data/MK5LHDCC78UBXBVV9K1W.m3u",
    "group-title": "",
    "name": "CBS 4 KMOV",
    "tvg-id": "kmov4.us",
    "tvg-logo": "",
    "tvg-name": "",
    "url": "",
    "_uuid.key": "",
    "_values": "",
    "x-active": false,
    "x-category": "",
    "x-channelID": "1000",
    "x-epg": "x-ID.0",
    "x-group-title": "",
    "x-mapping": "-",
    "x-xmltv-file": "-",
    "x-name": "CBS 4 | HD",
    "x-update-channel-icon": false,
    "x-update-channel-name": false,
    "x-description": ""
  },

[MrCreatoR]

Something like this?

 

$sJSON = ClipGet() ;This is the json string

$aRet = StringRegExp($sJSON, '(?s)("[^"]+": {.*?})', 3)
$sFind = 'Fox 2'

For $sStr In $aRet
    If StringRegExp($sStr, '"name": ".*' & $sFind & '.*",') Then
        $sRep = StringRegExpReplace($sStr, '("x-update-channel-icon": )false', '\1true')
        $sRep = StringRegExpReplace($sRep, '("x-update-channel-name": )false', '\1true')
        $sJSON = StringReplace($sJSON, $sStr, $sRep)
    EndIf
Next

ConsoleWrite($sJSON & @CRLF)

 

[Nine]

Or using UDF :

#include <Constants.au3>
#include <json.au3>

$data = FileRead("Test2.json")
$json_data = json_decode($data)
If @error Then Exit MsgBox(0, "decode", @error)

;Json_Dump($data)

Local $value
For $x = 1 To 3 Step 2
  $value = json_get($json_data, "[" & $x & "][name]")
  If @error Then Exit MsgBox(0, "get", @error)
  If StringInStr($value, "Fox 2") Then
    json_put($json_data, "[" & $x & "][x-update-channel-icon]", "True")
    json_put($json_data, "[" & $x & "][x-update-channel-name]", "True")
  EndIf
Next

ConsoleWrite (Json_Encode_Pretty($json_data, 0, "  ", @CRLF, "," & @CRLF, ": ") & @CRLF)

 

[AspirinJunkie]

There exists also a json-processor UDF for manipulate json: jq-udf

Admittedly, the syntax is not very intuitive, but this is how it could work with this UDF:

#include "jq.au3"

$data = FileRead("Test2.json")

_jqInit()
$sCmdOutput = _jqExec($data, '.[] | (objects | select(.name | contains("Fox 2")) | ."x-update-channel-icon" = true) // . ')

ConsoleWrite($sCmdOutput)

 

[MrCreatoR]

7 hours ago, Nine said:

Or using UDF

Which one?

I have tried few, but on the fragment from the first post they are not working.

[mLipok]

1 hour ago, MrCreatoR said:

Which one?

I have tried few, but on the fragment from the first post they are not working.

Did you try Chilkat.au3 UDF ?
JSON if free componet in Chilkat.

 

[Jos]

2 hours ago, MrCreatoR said:

I have tried few, but on the fragment from the first post they are not working.

Guess that is because the fragment isn't a valid JSON as posted and is missing the opening and closing brackets. 

[Nine]

2 hours ago, MrCreatoR said:

Which one?

 

_Json(2019.01.17).zip

[Nine]

And @Jos is right, you need to add those brackets...

[TheXman]

11 hours ago, AspirinJunkie said:

There exists also a json-processor UDF for manipulate json: jq-udf

Admittedly, the syntax is not very intuitive, but this is how it could work with this UDF:

#include "jq.au3"

$data = FileRead("Test2.json")

_jqInit()
$sCmdOutput = _jqExec($data, '.[] | (objects | select(.name | contains("Fox 2")) | ."x-update-channel-icon" = true) // . ')

ConsoleWrite($sCmdOutput)

 

First, thank you for mentioning jq.

The only issue with your example is that the result will only be the selected keys' object values without their keys.  If I understood the OP correctly, the result should be a complete, modified json configuration file.  The example below, using jq, shows one way to replace just the specified values while leaving the rest of the data as-is.  For brevity, I've condensed the json source but kept the relevant fields.  I have also assumed that the original json snippet was of a json object with multiple key/value pairs.  If it was supposed to be an array of json objects, it would be a simple modification to the jq filter to get the required result.

#cs
    This example uses the jq UDF.
    https://www.autoitscript.com/forum/files/file/502-jq-udf-a-powerful-flexible-json-processor/
#ce

#include <Constants.au3>
#include <jq.au3> ;<== Modify as needed

Const $JSON_DATA  = '{"x-ID.0":{"name":"Fox 2 KTVI","x-update-channel-icon":false,"x-update-channel-name":false,"x-description":""},"x-ID.1":{"name":"CBS 4 KMOV","x-name":"CBS 4 | HD","x-update-channel-icon":false,"x-update-channel-name":false,"x-description":""}}'

Const $JQ_FILTER  = 'walk( '                                                                   & _
                    '  if (.name? // ""| startswith("Fox 2") ) then '                          & _
                    '    (."x-update-channel-icon" = true | ."x-update-channel-name" = true) ' & _
                    '  else '                                                                  & _
                    '    . '                                                                   & _
                    '  end '                                                                   & _
                    ')'

;Initialize jq
_jqInit("C:\<path to jq executable>\jq-win64.exe") ;<== Modify as needed
If @error Then Exit MsgBox($MB_ICONERROR + $MB_TOPMOST, "ERROR", "ERROR: Unable to initialize jq - @error = " & @error)

;Replace specified values
$sCmdOutput = _jqExec($JSON_DATA, $JQ_FILTER)

;Display results
ConsoleWrite("Before:" & @CRLF)
ConsoleWrite(_jqPrettyPrintJson($JSON_DATA) & @CRLF)
ConsoleWrite(@CRLF)
ConsoleWrite("After:" & @CRLF)
ConsoleWrite($sCmdOutput & @CRLF)

Console output

Before:
{
  "x-ID.0": {
    "name": "Fox 2 KTVI",
    "x-update-channel-icon": false,
    "x-update-channel-name": false,
    "x-description": ""
  },
  "x-ID.1": {
    "name": "CBS 4 KMOV",
    "x-name": "CBS 4 | HD",
    "x-update-channel-icon": false,
    "x-update-channel-name": false,
    "x-description": ""
  }
}

After:
{
  "x-ID.0": {
    "name": "Fox 2 KTVI",
    "x-update-channel-icon": true,
    "x-update-channel-name": true,
    "x-description": ""
  },
  "x-ID.1": {
    "name": "CBS 4 KMOV",
    "x-name": "CBS 4 | HD",
    "x-update-channel-icon": false,
    "x-update-channel-name": false,
    "x-description": ""
  }
}

 

Edited February 23, 2021 by TheXman

[AspirinJunkie]

1 hour ago, TheXman said:

The only issue with your example is that the result will only be the selected keys' object values without their keys. 

Ah now i see the difference in our results. You're completely right - I simply did not look closely at my result.

Since this was the very first time I ever dealt with jq, I assumed anyway that improvements to my approach were needed.

[TheXman]

21 minutes ago, AspirinJunkie said:

was the very first time I ever dealt with jq

For being the very first time dealing with jq. or even the first few times, that was a relatively complex filter that you came up with.  It was definitely on the right path to a different way to achieve the same result.  Nice job!  Like anything else, the more you do/use it, the easier it becomes. 

Edited February 23, 2021 by TheXman