Msgbox with cancel button only

[igana]

Hi guys,

I'm trying to create a shutdown application and it will automatically shutdown the pc after working hours. But if the user is still working overtime, they will be able to cancel it. Is it possible to have only the cancel button on the message box? Please see below script for reference.

$x = MsgBox(17+256+4096,"Shutdown","In accordance with company power saving policies, your computer will be shutdown in 1 minute." & @CRLF & @CRLF & "If you wish to abort this process, click the Cancel button below.",60)

If $x = -1 Then
    ; Code 13 = 1 (shutdown) + 4 (force) + 8 (power down)
    Shutdown(13)
Else
    MsgBox(0,"Shutdown Aborted","Please remember to power off your computer when you are done.")
EndIf

 

[FrancescoDiMuro]

@igana

Since a "Cancel only" MsgBox seems not be available, you could use the style $MB_OKCANCEL, and maybe a timeout.

If the user presses "OK" or the Timeout has been reached, than shutdown the PC; else, if the user presses "Cancel", then don't shutdown the PC and display the other MsgBox

Alternatively, you have to create your own MsgBox, or (I don't know if it would be the case), an amazing UDF by Melba23

[igana]

1 hour ago, FrancescoDiMuro said:

@igana

Since a "Cancel only" MsgBox seems not be available, you could use the style $MB_OKCANCEL, and maybe a timeout.

If the user presses "OK" or the Timeout has been reached, than shutdown the PC; else, if the user presses "Cancel", then don't shutdown the PC and display the other MsgBox

Alternatively, you have to create your own MsgBox, or (I don't know if it would be the case), an amazing UDF by Melba23

Thanks @FrancescoDiMuro! I was able to create it. However, I tested the close button on the window and my pc shuts down lol. Do you know how to fix this? Sorry I'm not really good with programming

[FrancescoDiMuro]

@igana

Could you please post the code so we can take a look

EDIT: just use the reply to this topic instead of quoting the whole reply, so the thread structure remains more fluid and less long

Edited January 31, 2021 by FrancescoDiMuro

[igana]

Hahaha my apologies. Noted on that Mr.

_ExtMsgBoxSet(1, 4, -1, -1, 11)

$sMsg = "In accordance with company power saving policies, your computer will be shutdown in 1 minute." & @CRLF & @CRLF & "If you wish to abort this process, click the Cancel button below."

$x = _ExtMsgBox($EMB_ICONSTOP, "Cancel", "Shutdown", $sMsg,60)

If $x = 1 Then
   MsgBox(0,"Shutdown Aborted","Please remember to power off your computer when you are done.")
Else
    ; Code 13 = 1 (shutdown) + 4 (force) + 8 (power down)
    Shutdown(13)
EndIf

 

[Melba23]

igana.

With that code only pressing the "Cancel" button will prevent shutdown - closing the ExtMsgBox with [X] or allowing the timeout will run the shutdown code.

If you want ONLY the timeout to shutdown then you need this:

If $x = 9 Then
    MsgBox($MB_SYSTEMMODAL, 0, "Shutdown", "Shutting down")
    ; shutdown code
Else
    MsgBox(0, "Shutdown Aborted", "Please remember to power off your computer when you are done.")
EndIf

M23

[Nine]

But if you still want to have a single button "Cancel", here how you could do it with MsgBox :

#include <WindowsConstants.au3>
#include <Constants.au3>
#include <SendMessage.au3>
#include <WinAPIError.au3>

$sCommand = " /AutoIt3ExecuteLine ""MsgBox(0, 'Shutdown'," & _
  "'In accordance with company power saving policies, your computer will be shutdown in 1 minute.' & @CRLF & @CRLF & " & _
  "'If you wish to abort this process, click the Cancel button below.', 60)"""
ConsoleWrite ($sCommand & @CRLF)
Run(@AutoItExe & $sCommand)
$hWnd = WinWait("Shutdown")
$hCtrl = ControlGetHandle($hWnd, "", "Button1")
ConsoleWrite ($hWnd & "/" & $hCtrl & @CRLF)

$tString = DllStructCreate("char text[7]")
$tString.text = "Cancel"
_SendMessageA($hCtrl, $WM_SETTEXT, 0, DllStructGetPtr($tString))
ConsoleWrite (_WinAPI_GetLastError() & @CRLF)

 

[mikell]

An other way...

#include <Constants.au3>
#include <WinAPI.au3>

Local $hProcMsgBox = DllCallbackRegister("CbtHookProcMsgBox", "int", "int;int;int")
Local $TIDMsgBox = _WinAPI_GetCurrentThreadId()
Local $hHookMsgBox = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($hProcMsgBox), 0, $TIDMsgBox)

Local $iRet = MsgBox(0, "test", "test")

_WinAPI_UnhookWindowsHookEx($hHookMsgBox)
DllCallbackFree($hProcMsgBox)


Func CbtHookProcMsgBox($nCode, $wParam, $lParam)
    Local $RET = 0
    If $nCode < 0 Then
        $RET = _WinAPI_CallNextHookEx($hHookMsgBox, $nCode, $wParam, $lParam)
        Return $RET
    EndIf
    Switch $nCode
        Case 5 ;5=HCBT_ACTIVATE
        DllCall('user32.dll', "int", "SetDlgItemText", "hwnd", $wParam, "int", 1, "str", "Cancel")
    EndSwitch
    Return
EndFunc   ;==>CbtHookProcMsgBox

 

[Nine]

@mikell Nice solution.  But shouldn't you call _WinAPI_CallNextHookEx at the end of the callback function ?

[mikell]

@Nine
Usually I use this in a custom _Msgbox function to set text/position of the Msgbox

Func _MsgBox($flag, $title, $text)
    Local $hProcMsgBox = DllCallbackRegister("CbtHookProcMsgBox", "int", "int;int;int")
    Local $TIDMsgBox = _WinAPI_GetCurrentThreadId()
    Local $hHookMsgBox = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($hProcMsgBox), 0, $TIDMsgBox)
    Local $iRet = MsgBox($flag, $title, $text)
    _WinAPI_UnhookWindowsHookEx($hHookMsgBox)
    DllCallbackFree($hProcMsgBox)
    Return $iRet 
EndFunc

Maybe I'm wrong but in this case calling _WinAPI_CallNextHookEx at the end of the callback function seems useless

[Nine]

Hmm, you got a good point there.  On the other hand, calling it doesn't hurt for sure.  But then calling it if code < 0 should also be considered useless, no ?

[mikell]

Maybe. I chose to keep on following lazily MS instructions 
If nCode is less than zero, the hook procedure must pass the message to the CallNextHookEx function without further processing and should return the value returned by CallNextHookEx