Script/Text/File Manager - Update 4/6/2015

randallc · February 23, 2008

Thanks for the support Manadar, Randallc, and especially GEOSoft with the Autoit Wrappers link!

@Randallc
I have noticed your effort on FileListToArrayNew() and supporting others with File-List UDF's. I am sure what you stated would speed-up the process, however, I wrote this for me and like the counter etc.
Actually, I use this almost daily.
Thanks again
Valuater
8)

OK!

Are you using it mostly

1. For text searches.

2. Mostly in small directories?

then I understand.. otherwise, I would be frustrated by the 10-20x slowness for filesearch on large directories; but power to you!

Still a great little program as it stands, i agree!

I'm always annoyed when I want to use it and can't find it agian.

best, Randall

GEOSoft · February 23, 2008

Thanks for the support Manadar, Randallc, and especially GEOSoft with the Autoit Wrappers link!

@Randallc
I have noticed your effort on FileListToArrayNew() and supporting others with File-List UDF's. I am sure what you stated would speed-up the process, however, I wrote this for me and like the counter etc.
Actually, I use this almost daily.
Thanks again
Valuater
8)

Glad to do it. As I've pointed out before, I don't know why that thread has not been made a sticky yet. At least having it in my sig makes it easy for me to find.

Valuater · February 23, 2008

OK!
Are you using it mostly
1. For text searches.
2. Mostly in small directories?
then I understand..

Yepper! that is mostly what I use it for....

However, if you wouild like to post a faster version here, I will link it to page #1

Thx

8)

gseller · April 19, 2008

*Bump!* *Bump!* Thia is way cool.. I use it alot to convert php files from mysql to mssql and vise versa! Also with this new global constant thing that bete 3.2.11.5 and up has this is awesome to point it towards the autoit include folder and find every global constant ya need.. Thanks again Valuater...

Valuater · April 22, 2008

... with this new global constant thing that bete 3.2.11.5 and up has this is awesome to point it towards the autoit include folder and find every global constant ya need...

I just tried that, and your right!

... thanks geller, I just found a new use too!

8)

jvanegmond · August 30, 2008

Still using this daily. I have a fixed version here that runs on latest AutoIt without problems.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Include <File.au3>
#Include <Array.au3>
#Include <GuiListBox.au3>

$SS_SUNKEN = 0x1000 
$SS_CENTER = 0x01 


FileDelete(@TempDir & "\au3.txt")
Opt("OnExitFunc", "endscript")
Dim $TInfo, $R_[7], $Temp_File, $Temp_Type = StringSplit(".au3,.txt,.ini,.dat,.log,", ",")
Dim $Last_loc = "C:\Program Files\AutoIt3\Examples"
$AutoItBetaLocation = IniRead(@ScriptDir & "\IE-library.ini", "exe", "dir", "")
$Program_2 = $AutoItBetaLocation & "\Autoit3.exe"

$maingui = GUICreate("Script/Text Manager       v1.0.5", 500, 365)
GUISetFont(9, 400, -1, "MS Sans Serif")
$vStatus = GUICtrlCreateLabel("View: Search Window", 0, 350, 130, 15, $SS_SUNKEN + $SS_CENTER)
GUICtrlCreateLabel("Manager Status:", 130, 350, 120, 15, $SS_SUNKEN + $SS_CENTER)
$Status = GUICtrlCreateLabel("System is Ready...", 250, 350, 250, 15, $SS_SUNKEN + $SS_CENTER)
GUICtrlSetColor(-1, 0xff0000)
GUISetState()

$searchgui = GUICreate("Script Finder", 500, 350, 0, 0, $WS_CHILD + $WS_BORDER, "", $maingui)
GUISetFont(9, 400, -1, "MS Sans Serif")
$location = GUICtrlCreateInput($Last_loc, 20, 20, 340, 20)
$C_browse = GUICtrlCreateCheckbox("All Sub-Folders", 380, 20, 100, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
$browse_btn = GUICtrlCreateButton("Browse Folders", 380, 50, 100, 20)
$R_word = GUICtrlCreateRadio("", 20, 50, 20, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
$word_search = GUICtrlCreateInput("Search word/phrase", 40, 50, 145, 20)
$R_title = GUICtrlCreateRadio("", 195, 50, 20, 20)
$title_search = GUICtrlCreateInput("Search FileName/Folder", 215, 50, 145, 20)
GUICtrlCreateGroup('File Type', 20, 78, 340, 38)
$R_[1] = GUICtrlCreateRadio(".au3", 30, 92, 50, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
$R_[2] = GUICtrlCreateRadio(".txt", 80, 92, 50, 20)
$R_[3] = GUICtrlCreateRadio(".ini", 130, 92, 50, 20)
$R_[4] = GUICtrlCreateRadio(".dat", 180, 92, 50, 20)
$R_[5] = GUICtrlCreateRadio(".log", 230, 92, 50, 20)
$R_[6] = GUICtrlCreateRadio("", 280, 92, 15, 20)
$R_Input = GUICtrlCreateInput("Type", 298, 90, 50, 20)
$go_btn = GUICtrlCreateButton("Start Search", 380, 85, 100, 30)
GUICtrlSetState(-1, $GUI_DEFBUTTON)
$Edit1 = GUICtrlCreateList("Found File list", 20, 130, 460, 150, BitOR($LBS_SORT, $WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
_GUICtrlListBox_SetHorizontalExtent ($Edit1, 720)
$label = GUICtrlCreateLabel("Files Found with Phrase: None", 140, 290, 220, 20, $SS_SUNKEN + $SS_CENTER)
$label2 = GUICtrlCreateLabel("Files Found: None", 20, 290, 100, 20, $SS_SUNKEN + $SS_CENTER)
$manage_btn = GUICtrlCreateButton("Manage View", 20, 320, 100, 20)
$view_btn = GUICtrlCreateButton("View File", 140, 320, 100, 20)
$SciTE_btn = GUICtrlCreateButton("Open in SciTE", 260, 320, 100, 20)
$Run_btn = GUICtrlCreateButton("Run File", 380, 290, 100, 20)
$Exit_btn = GUICtrlCreateButton("Close", 380, 320, 100, 20)
GUISetState()

$filesgui = GUICreate("Script Finder", 500, 350, 0, 0, $WS_CHILD + $WS_BORDER, "", $maingui)
$Edit2 = GUICtrlCreateList("Searched File list", 20, 20, 460, 270, BitOR($LBS_SORT, $WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
_GUICtrlListBox_SetHorizontalExtent ($Edit2, 720)
$Search_btn = GUICtrlCreateButton("Search View", 20, 320, 100, 20)
$copy_btn = GUICtrlCreateButton("Copy File", 140, 320, 100, 20)
$rename_btn = GUICtrlCreateButton("Rename File", 260, 320, 100, 20)
$Delete_btn = GUICtrlCreateButton("Delete File", 380, 320, 100, 20)
$labelA = GUICtrlCreateLabel("Files Found with Phrase: None", 140, 290, 220, 20, $SS_SUNKEN + $SS_CENTER)
$label2A = GUICtrlCreateLabel("Files Found: None", 20, 290, 100, 20, $SS_SUNKEN + $SS_CENTER)
$Run_btnA = GUICtrlCreateButton("Run File", 380, 290, 100, 20)
GUISetState(@SW_HIDE)



While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE Or $msg = $Exit_btn
            Exit
        Case $msg = $browse_btn
            GUICtrlSetData($Status, "Selecting Folder to Search...")
            $find_loc = FileSelectFolder("Choose a Folder.", "")
            If $find_loc = "" Then ContinueLoop
            GUICtrlSetData($location, $find_loc)
            IniWrite(@ScriptDir & "\IE-library.ini", "search", "dir", $find_loc)
        Case $msg = $go_btn
            search_Folders()
            GUICtrlSetState($word_search, $GUI_FOCUS)
        Case $msg = $view_btn
            view()
        Case $msg = $copy_btn
            Set_Copy()
        Case $msg = $rename_btn
            Set_Rename()
        Case $msg = $Delete_btn
            Set_Delete()
        Case $msg = $Run_btn
            $TInfo = GUICtrlRead($Edit1)
            Set_Run($TInfo)
        Case $msg = $Run_btnA
            $TInfo = GUICtrlRead($Edit2)
            Set_Run($TInfo)
        Case $msg = $SciTE_btn
            open_SciTE()
        Case $msg = $manage_btn
            GUICtrlSetData($vStatus, "View: Manage Window")
            GUISetState(@SW_HIDE, $searchgui)
            GUISetState(@SW_SHOW, $filesgui)
            view_all()
        Case $msg = $Search_btn
            GUICtrlSetData($vStatus, "View: Search Window")
            GUISetState(@SW_HIDE, $filesgui)
            GUISetState(@SW_SHOW, $searchgui)
    EndSelect
    GUICtrlSetData($Status, "System is Ready...")
    Sleep(20)
WEnd

Func search_Folders()
    If Set_File() = -1 Then Return
    GUICtrlSetData($Status, "Searching for Files...")
    FileDelete(@TempDir & "\au3.txt")
    $Found = 0
    $Searched = 0
    $title = 0
    GUICtrlSetData($label, "Files Found with Phrase: " & $Found)
    GUICtrlSetData($labelA, "Files Found with Phrase: " & $Found)
    GUICtrlSetData($label2, "Files Found: " & $Searched)
    GUICtrlSetData($label2A, "Files Found: " & $Searched)
    GUICtrlSetData($Edit1, "")
    GUICtrlSetData($Edit2, "")
    $Temp_Dir = (GUICtrlRead($location))
    If $Temp_Dir = "" Then
        GUICtrlSetData($Status, "No Folder Selected...")
        MsgBox(262208, "Sorry", "No Folders Selected.   ", 2)
        Return
    EndIf
    If StringRight($Temp_Dir, 1) <> "\"  Then $Temp_Dir = $Temp_Dir & "\"
    $Temp_Word = (GUICtrlRead($word_search))
    If GUICtrlRead($C_browse) = 1 Then
        GUICtrlSetData($Status, "Searching in Sub-Folders...PLEASE WAIT")
        RunWait(@ComSpec & ' /c ' & 'dir "' & $Temp_Dir & $Temp_File & '" /a :h /b /s' & ' > "' & @TempDir & '\au3.txt"', '', @SW_HIDE)
    Else
        GUICtrlSetData($Status, "Searching in Local Folder...")
        $FileList = _FileListToArray($Temp_Dir, $Temp_File, 1)
        If (Not IsArray($FileList)) Or (@error = 1) Then
            GUICtrlSetData($Status, "No Files Found...")
            MsgBox(262208, "Sorry", "No Files Found.", 2)
            Return
        EndIf
        $F_File = FileOpen(@TempDir & "\au3.txt", 2)
        For $x = 1 To $FileList[0]
            FileWriteLine($F_File, $Temp_Dir & $FileList[$x])
        Next
        FileClose($F_File)
    EndIf
    GUICtrlSetData($Status, "Listing...")
    If GUICtrlRead($R_title) = 1 Then
        $Temp_Word = (GUICtrlRead($title_search))
        $title = 1
    EndIf
    $hFile = FileOpen(@TempDir & "\au3.txt", 0)
    While 1
        $sLine = FileReadLine($hFile)
        If @error = -1 Then
            FileClose($hFile)
            Return
        EndIf
        $Temp_Dir = $sLine
        If $title = 0 Then $Temp_Search = FileRead($sLine, FileGetSize($sLine))
        If $title = 1 Then $Temp_Search = $sLine
        If StringInStr($Temp_Search, $Temp_Word) Then
            GUICtrlSetData($Edit1, $sLine, 1)
            $Found = $Found + 1
            GUICtrlSetData($label, "Files Found with Phrase: " & $Found)
            GUICtrlSetData($labelA, "Files Found with Phrase: " & $Found)
        EndIf
        $Searched = $Searched + 1
        GUICtrlSetData($label2, "Files Found: " & $Searched)
        GUICtrlSetData($label2A, "Files Found: " & $Searched)
        GUICtrlSetData($Status, "Searched:" & $sLine)
    WEnd
    FileClose($hFile)
EndFunc   ;==>search_Folders

Func view()
    GUICtrlSetData($Status, "Viewing in Notepad...")
    $Temp_Edit = GUICtrlRead($Edit1)
    $Temp_Word = (GUICtrlRead($word_search))
    If $Temp_Edit = "" Or $Temp_Edit = "Found File list"  Then
        GUICtrlSetData($Status, "No File/Folder Selected...")
        MsgBox(262208, "Sorry", "No Files\Folders Selected.   ", 2)
        Return
    EndIf
    Run("notepad.exe " & $Temp_Edit)
    WinWaitActive("")
    If GUICtrlRead($R_title) = 1 Then Return
    GUICtrlSetData($Status, "Searching Notepad...")
    Sleep(200)
    Send("!EF")
    Sleep(200)
    Send($Temp_Word, 1)
    Sleep(200)
    Send("!f")
EndFunc   ;==>view

Func view_all()
    GUICtrlSetData($Status, "Viewing Manager window...")
    If Not FileExists(@TempDir & "\au3.txt") Then
        GUICtrlSetData($Status, "No Searches Were Completed...")
        MsgBox(262208, "Sorry", "No Files\Folders Searched.   ", 2)
        Return
    EndIf
    GUICtrlSetData($Edit2, "")
    $vFile = FileOpen(@TempDir & "\au3.txt", 0)
    While 1
        $vLine = FileReadLine($vFile)
        If @error = -1 Then ExitLoop
        GUICtrlSetData($Edit2, $vLine, 1)
        GUICtrlSetData($Status, "Setting Files: " & $vLine)
    WEnd
EndFunc   ;==>view_all

Func Set_Run(ByRef $TInfo)
    GUICtrlSetData($Status, "Setting up Run Command...")
    If $TInfo = "" Or $TInfo = "Found File list"  Or $TInfo = "Searched File list"  Then
        GUICtrlSetData($Status, "No File Selected to Run...")
        MsgBox(262208, "Sorry", "No Run File was Selected.   ", 2)
        Return
    EndIf
    If GUICtrlRead($R_[6]) = 1 And StringInStr($TInfo, ".au3") = 0 Then
        GUICtrlSetData($Status, "Running File...")
        $TInfo = FileGetShortName($TInfo)
        ShellExecute($TInfo)
        $TInfo = ""
        Return
    EndIf
    If StringInStr($TInfo, ".au3") = 0 Then
        GUICtrlSetData($Status, "File Not an Au3 Type...")
        MsgBox(262208, "Sorry", "Run File was NOT an *au3* Type.   " & @CRLF & @CRLF & "Opening File in Notepad   ", 2)
        GUICtrlSetData($Status, "Viewing in Notepad...")
        Run("notepad.exe " & $TInfo)
        $TInfo = ""
        Return
    EndIf
    $TInfo = FileGetShortName($TInfo)
    GUICtrlSetData($Status, "Running File...")
    RunWait($Program_2 & " " & $TInfo)
    $TInfo = ""
EndFunc   ;==>Set_Run

Func Set_Copy()
    GUICtrlSetData($Status, "Setting up Copy...")
    $CInfo = GUICtrlRead($Edit2)
    If $CInfo = "" Or $CInfo = "Found File list"  Or $CInfo = "Searched File list"  Then
        GUICtrlSetData($Status, "No File Selected to Copy...")
        MsgBox(262208, "Sorry", "No Copy File was Selected.   ", 2)
        Return
    EndIf
    GUICtrlSetData($Status, "Find Destination Folder...")
    $Linfo = FileSelectFolder("Choose a Destination Folder.", "")
    If $Linfo = "" Then
        GUICtrlSetData($Status, "No Folder Selected...")
        MsgBox(262208, "Sorry", "No Destination Folder was Selected.   ", 2)
        Return
    EndIf
    $NInfo = StringSplit($CInfo, "\")
    $NInfo = $Linfo & "\" & $NInfo[$NInfo[0]]
    GUICtrlSetData($Status, "Checking if file exists...")
    If FileExists($NInfo) Then
        $iMsgBoxAnswer = MsgBox(262212, "Overwrite Existing File?", "The File " & $NInfo & " was found    " & @CRLF & @CRLF & "Over-Write File?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData($Status, "Copying File...")
    $var1 = FileCopy($CInfo, $NInfo, 1)
    If $var1 = 1 Then
        MsgBox(262208, "Success", "The file was Copied   ", 2)
    Else
        MsgBox(262208, "Fail", "The file was NOT Copied   ", 2)
    EndIf
EndFunc   ;==>Set_Copy

Func Set_Rename()
    GUICtrlSetData($Status, "Setting Rename File...")
    $RInfo = GUICtrlRead($Edit2)
    If $RInfo = "" Or $RInfo = "Found File list"  Or $RInfo = "Searched File list"  Then
        GUICtrlSetData($Status, "No File Selected...")
        MsgBox(262208, "Sorry", "No Rename File was Selected.   ", 2)
        Return
    EndIf
    GUICtrlSetData($Status, "Prompt for FileName...")
    $Minfo = InputBox("Rename File", "Please Type a New FileName. ", "", "", -1, 150)
    If $Minfo = "" Then
        GUICtrlSetData($Status, "No Name Given...")
        MsgBox(262208, "Sorry", "No File Name was Selected.   ", 2)
        Return
    EndIf
    $result = StringInStr($RInfo, "\", 0, -1)
    $NInfo = StringLeft($RInfo, $result) & $Minfo & StringRight($Temp_File, 4)
    GUICtrlSetData($Status, "Checking if File Exists...")
    If FileExists($NInfo) Then
        $iMsgBoxAnswer = MsgBox(262212, "Overwrite Existing File?", "The File " & $NInfo & " was found    " & @CRLF & @CRLF & "Over-Write File?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData($Status, "Renaming File...")
    $var1 = FileMove($RInfo, $NInfo, 1)
    If $var1 = 1 Then
        FileDelete($RInfo)
        MsgBox(262208, "Success", "The file was Renamed   ", 2)
    Else
        MsgBox(262208, "Fail", "The file was NOT Renamed   ", 2)
    EndIf
    $ret = _GUICtrlListBox_FindString ($Edit2, $RInfo, 1)
    If ($ret == $LB_ERR) Then
        MsgBox(16, "Error #1", "Unknown error from _GUICtrlListBox_FindString")
    Else
        $ret2 = _GUICtrlListBox_DeleteString ($Edit2, $ret)
        If ($ret2 == $LB_ERR) Then
            MsgBox(16, "Error #2", "Unknown error from _GUICtrlListDeleteItem")
        EndIf
    EndIf
EndFunc   ;==>Set_Rename

Func Set_Delete()
    GUICtrlSetData($Status, "Setting up Delete...")
    $DInfo = GUICtrlRead($Edit2)
    If $DInfo = "" Or $DInfo = "Found File list"  Or $DInfo = "Searched File list"  Then
        GUICtrlSetData($Status, "No File Selected...")
        MsgBox(262208, "Sorry", "No Delete File was Selected.   ", 2)
        Return
    EndIf
    GUICtrlSetData($Status, "Verify that File Exists...")
    If FileExists($DInfo) Then
        $iMsgBoxAnswer = MsgBox(262212, "Confirm - Delete File?", "The File " & $DInfo & " was found    " & @CRLF & @CRLF & "Delete File?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData($Status, "Deleting File...")
    $var1 = FileDelete($DInfo)
    If $var1 = 1 Then
        MsgBox(262208, "Success", "The file was Deleted   ", 2)
    Else
        MsgBox(262208, "Fail", "The file was NOT Deleted   ", 2)
    EndIf
    $ret = _GUICtrlListBox_FindString ($Edit2, $DInfo, 1)
    If ($ret == $LB_ERR) Then
        MsgBox(16, "Error #1", "Unknown error from _GUICtrlListBox_FindString")
    Else
        $ret2 = _GUICtrlListBox_DeleteString ($Edit2, $ret)
        If ($ret2 == $LB_ERR) Then
            MsgBox(16, "Error #2", "Unknown error from _GUICtrlListDeleteItem")
        EndIf
    EndIf
EndFunc   ;==>Set_Delete

Func Set_File()
    GUICtrlSetData($Status, "Checking File Type...")
    For $t = 1 To $Temp_Type[0]
        If GUICtrlRead($R_[$t]) = 1 Then
            If $t = $Temp_Type[0] Then
                $Read_Temp = GUICtrlRead($R_Input)
                If $Read_Temp = "" Or StringInStr($Read_Temp, ".") = 0 Then
                    GUICtrlSetData($Status, "No File Type Selected...")
                    MsgBox(262208, "Sorry", "No File Type Selected.   " & @CRLF & "Example .exe or .dll    ", 5)
                    Return -1
                EndIf
                $Temp_File = "*" & $Read_Temp
            Else
                $Temp_File = "*" & $Temp_Type[$t]
            EndIf
            Return
        EndIf
    Next
EndFunc   ;==>Set_File

Func open_SciTE()
    GUICtrlSetData($Status, "Setting up SciTE...")
    $Temp_Edit = GUICtrlRead($Edit1)
    If $Temp_Edit = "" Or $Temp_Edit = "Found File list"  Then
        GUICtrlSetData($Status, "No File Selected for SciTE...")
        MsgBox(262208, "Sorry", "No Files\Folders Selected.   ", 2)
        Return
    EndIf
    GUICtrlSetData($Status, "Checking for Au3 File...")
    If StringInStr($Temp_Edit, ".au3") = 0 Then
        $iMsgBoxAnswer = MsgBox(262212, "Verify File Type", "The File " & $Temp_Edit & " is NOT an *au3* Type.    " & @CRLF & @CRLF & "Open in SciTE.exe?")
        If $iMsgBoxAnswer = 7 Then
            Return
        EndIf
    EndIf
    GUICtrlSetData($Status, "Check if SciTE is Running...")
    If ProcessExists("SciTE.exe") Then
        MsgBox(262208, "SciTE is Running", "Placing File in Scite.exe   ", 2)
        Opt("WinTitleMatchMode", 4)
        $Temp_Text = FileRead($Temp_Edit, FileGetSize($Temp_Edit))
        WinActivate("classname=SciTEWindow")
        WinWaitActive("classname=SciTEWindow")
        ControlSend("classname=SciTEWindow", "", "", "^n")
        Sleep(50)
        ControlSetText("classname=SciTEWindow", "", "Scintilla1", $Temp_Text)
        Opt("WinTitleMatchMode", 1)
        Return
    EndIf
    GUICtrlSetData($Status, "Running SciTE Now...")
    $Temp_Edit = FileGetShortName($Temp_Edit)
    Run(@ComSpec & " /c Start " & $Temp_Edit, "", @SW_HIDE)
EndFunc   ;==>open_SciTE

Func endscript()
    MsgBox(262208, "Thanks", "... Valuater   ", 1)
    FileDelete(@TempDir & "\au3.txt")
EndFunc   ;==>endscript

Valuater · August 30, 2008

Still using this daily. I have a fixed version here that runs on latest AutoIt without problems.

Thanks Manadar....

I replaced the script on page #1 and used your fix as ver 1.0.6

8)

Valuater · October 11, 2008

Hello,
If you don't lend assistance...
I located your Script/Text Manager and found it was to powerful for what I need. What I have is some 20 text files (all.txt) that I download periodically and need to search those files for certain words and show which files have those. Once found I just need to open the file in Notepad and maybe highlight the line. I'll work on that a bit later.
Thanks for your time and assistance,
Scott

Hey Scott, I don't mind helping it's just using the PM is not very desirable to me. If you use the forum, others can help too.... and I am not always here.

Once found I just need to open the file in Notepad and maybe highlight the line. I'll work on that a bit later.

Mine will do that for you!

When it comes to the piece of script you gave me, that appears kinda like a hack of mine in this thread. That's a little hard to help with.... cause I already made it!!!

Good Luck

8)

TheSaint · October 12, 2008

I love surprises!

Somehow I'd overlooked this topic ... maybe the title fooled me ... anyway, it was not what I thought it was going to be.

What a great little program and a pleasing discovery!

Thanks Valuater!

:idea:

P.S. Maybe you should have called it 'Advanced Simple Script Finder' - that's the folder name I saved it under?

Edited October 12, 2008 by TheSaint

Valuater · October 19, 2008

I love surprises!
Somehow I'd overlooked this topic ... maybe the title fooled me ... anyway, it was not what I thought it was going to be.
What a great little program and a pleasing discovery!
Thanks Valuater!

P.S. Maybe you should have called it 'Advanced Simple Script Finder' - that's the folder name I saved it under?

Thanks Saint!!!

I was looking in this to show it to a newbie and saw your great post!

thanks again

8)

jvanegmond · October 19, 2008

I am still using this daily, and I feel I could brush it up a little in some areas (Remember file types, remember path, add some options for search). I was just wondering whether you would be ok with that, and if I could possibly release it again.

P.S. I also found $SS_SUNKEN and $SS_CENTER to be in StaticConstants.au3

Valuater · October 20, 2008

I am still using this daily, and I feel I could brush it up a little in some areas (Remember file types, remember path, add some options for search). I was just wondering whether you would be ok with that, and if I could possibly release it again.
P.S. I also found $SS_SUNKEN and $SS_CENTER to be in StaticConstants.au3

Sure... make it better!!

My other prog 'EzSkin' has an improvement from JScript.

8)

Valuater · December 28, 2008

UpDated - Ver 1.0.7 - December 27, 2008

8)

BJJ · December 30, 2008

Your program is so good but there i can copy only one .txt file i wana copy all find .txt file so who can i do it ??

Valuater · December 30, 2008

Your program is so good but there i can copy only one .txt file i wana copy all find .txt file so who can i do it ??

change the code a little

8)

BJJ · December 30, 2008

unluckily i can't

jvanegmond · April 16, 2009

Val, what license is this released under? I'd like to modify it just ever so slightly and put it as free open-source software on my website. If you have no idea yet, then I recommend GPL.

icadea · April 16, 2009

Thanks val. sure is a great script from the former findstr i have been using. Thanks ^_^

Valuater · April 21, 2009

@Manadar, I always figured anything I place here, unless otherwise stated, is free and open to the public to do with as they wish ( except malicious actions). I would like to have mentioned myself and Autoit,..... Thanks for askling!!

@icadea, thanks, glad it helped!

8)

Zedna · April 21, 2009

Nice tool Valuater!

Five stars from me for good idea/implementation :-)

Sign In

Script/Text/File Manager - Update 4/6/2015

Recommended Posts

randallc

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

Valuater

argumentum

GEOSoft

Valuater

gseller

Valuater

jvanegmond

Valuater

Valuater

TheSaint

Valuater

jvanegmond

Valuater

Valuater

BJJ

Valuater

BJJ

jvanegmond

icadea

Valuater

Zedna

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta