Hack that tells you what line# a compiled script actually crashed on...

[JockoDundee]

10 hours ago, mLipok said:

and here you go... an CUI example with no AutoIt Erorr MsgBox:

mLipok, it’s not the Autoit Error MsgBox that I object to, it’s the the data in the Error MsgBox (with compiled scripts) that’s the problem.  Your example is interesting but although you eliminate the pop-up, you are still showing the stripped error line #, not the actual line# in the source file. You still need to go to the stripped file and x-ref, and the come back to the actual source file - it’s another step.  
You may not feel it’s a big deal, but as I explained I am writing mostly CLI apps exclusively, it is a common occurrence.  
Do you use ScITe to develop in?  Now imagine every time you had a runtime error using SciTe that instead of the editor taking you right to the line, it just told you the line number into another file where you could see the errant line, but still had to go back to your source find it and pull it up.  You could do it, but you might wonder why.

Anyway, I do like the idea of the error line# being displayed on stdout, as long as it has the line# of the source file and not the stripped file.

So I took the liberty of merging the AddHookApi code with some of my functions to achieve that. Here is the output that mirrors yours, with the difference that the line # is a direct reference to the source file:

 

 

I made an #include called AddHookApi.au3 c using the code you provided, then I added my own code to it.  It works but it’s rather sloppy, and I expect I’ll break it out further.  That file looks like this:

expandcollapse popup

#include <WinApi.au3>
#include <StringConstants.au3>
#include <File.au3>
#pragma compile(Console, True)

Local  $fhInput, $fhOutput 
Local  $sErrorText, $sSourceFile, $sOutFileName
Local  $iErrLineNo, $iRefLineNo, $iLinesRead

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
AddHookApi("user32.dll", "MessageBoxW", "Intercept_MessageBoxW", "int", "hwnd;wstr;wstr;uint")

Func Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)

    Local $aOutput = StringRegExp($sText, '(?i)Line\s+(\d+)', $STR_REGEXPARRAYGLOBALMATCH)
    If @error Then Return

    If @ScriptName="_errormsghack.exe" Then
       ConsoleWrite($aOutput[0])
       Exit
    Else
       $aOutput[0]=GetTrueSourceErrorLine($aOutput[0])
    EndIf
    ConsoleWrite(@ScriptName & ' - !!! Error occured in line #' & $aOutput[0] & @CRLF)
    Return ; mLipok mod omnit MsgBox because of CUI=Y

    Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
            "hwnd", $hWnd, _
            "wstr", $sText, _
            "wstr", StringReplace($sTitle, "AutoIt", @ScriptName), _
            "uint", $iType)
    If @error Or Not $aCall[0] Then Return 0
    Return $aCall[0]
EndFunc   ;==>Intercept_MessageBoxW

; The magic is down below
Func AddHookApi($sModuleName, $vFunctionName, $vNewFunction, $sRet = "", $sParams = "")
    Local Static $pImportDirectory, $hInstance
    Local Const $IMAGE_DIRECTORY_ENTRY_IMPORT = 1
    If Not $pImportDirectory Then
        $hInstance = _WinAPI_GetModuleHandle(0)
        $pImportDirectory = ImageDirectoryEntryToData($hInstance, $IMAGE_DIRECTORY_ENTRY_IMPORT)
        If @error Then Return SetError(1, 0, 0)
    EndIf
    Local $iIsInt = IsInt($vFunctionName)
    Local $iRestore = Not IsString($vNewFunction)
    Local $tIMAGE_IMPORT_MODULE_DIRECTORY
    Local $pDirectoryOffset = $pImportDirectory
    Local $tModuleName
    Local $iInitialOffset, $iInitialOffset2
    Local $iOffset2
    Local $tBufferOffset2, $iBufferOffset2
    Local $tBuffer, $tFunctionOffset, $pOld, $fMatch, $pModuleName, $pFuncName
    Local Const $PAGE_READWRITE = 0x04
    While 1
        $tIMAGE_IMPORT_MODULE_DIRECTORY = DllStructCreate("dword RVAOriginalFirstThunk;" & _
                "dword TimeDateStamp;" & _
                "dword ForwarderChain;" & _
                "dword RVAModuleName;" & _
                "dword RVAFirstThunk", _
                $pDirectoryOffset)
        If Not DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk") Then ExitLoop
        $pModuleName = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAModuleName")
        $tModuleName = DllStructCreate("char Name[" & _WinAPI_StringLenA($pModuleName) & "]", $pModuleName)
        If DllStructGetData($tModuleName, "Name") = $sModuleName Then ; function from this module
            $iInitialOffset = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk")
            $iInitialOffset2 = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAOriginalFirstThunk")
            If $iInitialOffset2 = $hInstance Then $iInitialOffset2 = $iInitialOffset
            $iOffset2 = 0
            While 1
                $tBufferOffset2 = DllStructCreate("dword_ptr", $iInitialOffset2 + $iOffset2)
                $iBufferOffset2 = DllStructGetData($tBufferOffset2, 1)
                If Not $iBufferOffset2 Then ExitLoop
                If $iIsInt Then
                    If BitAND($iBufferOffset2, 0xFFFFFF) = $vFunctionName Then $fMatch = True ; wanted function
                Else
                    $pFuncName = $hInstance + $iBufferOffset2 + 2 ; 2 is size od "word", see line below...
                    $tBuffer = DllStructCreate("word Ordinal; char Name[" & _WinAPI_StringLenA($pFuncName) & "]", $hInstance + $iBufferOffset2)
                    If DllStructGetData($tBuffer, "Name") == $vFunctionName Then $fMatch = True ; wanted function
                EndIf
                If $fMatch Then
                    $tFunctionOffset = DllStructCreate("ptr", $iInitialOffset + $iOffset2)
                    VirtualProtect(DllStructGetPtr($tFunctionOffset), DllStructGetSize($tFunctionOffset), $PAGE_READWRITE)
                    If @error Then Return SetError(3, 0, 0)
                    $pOld = DllStructGetData($tFunctionOffset, 1)
                    If $iRestore Then
                        DllStructSetData($tFunctionOffset, 1, $vNewFunction)
                    Else
                        DllStructSetData($tFunctionOffset, 1, DllCallbackGetPtr(DllCallbackRegister($vNewFunction, $sRet, $sParams)))
                    EndIf
                    Return $pOld
                EndIf
                $iOffset2 += DllStructGetSize($tBufferOffset2)
            WEnd
            ExitLoop
        EndIf
        $pDirectoryOffset += 20 ; size of $tIMAGE_IMPORT_MODULE_DIRECTORY
    WEnd
    Return SetError(4, 0, 0)
EndFunc   ;==>AddHookApi

Func VirtualProtect($pAddress, $iSize, $iProtection)
    Local $aCall = DllCall("kernel32.dll", "bool", "VirtualProtect", "ptr", $pAddress, "dword_ptr", $iSize, "dword", $iProtection, "dword*", 0)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return 1
EndFunc   ;==>VirtualProtect

Func ImageDirectoryEntryToData($hInstance, $iDirectoryEntry)
    ; Get pointer to data
    Local $pPointer = $hInstance
    ; Start processing passed binary data. 'Reading' PE format follows.
    Local $tIMAGE_DOS_HEADER = DllStructCreate("char Magic[2];" & _
            "word BytesOnLastPage;" & _
            "word Pages;" & _
            "word Relocations;" & _
            "word SizeofHeader;" & _
            "word MinimumExtra;" & _
            "word MaximumExtra;" & _
            "word SS;" & _
            "word SP;" & _
            "word Checksum;" & _
            "word IP;" & _
            "word CS;" & _
            "word Relocation;" & _
            "word Overlay;" & _
            "char Reserved[8];" & _
            "word OEMIdentifier;" & _
            "word OEMInformation;" & _
            "char Reserved2[20];" & _
            "dword AddressOfNewExeHeader", _
            $pPointer)
    Local $sMagic = DllStructGetData($tIMAGE_DOS_HEADER, "Magic")
    ; Check if it's valid format
    If Not ($sMagic == "MZ") Then Return SetError(1, 0, 0) ; MS-DOS header missing. Btw 'MZ' are the initials of Mark Zbikowski in case you didn't know.
    ; Move pointer
    $pPointer += DllStructGetData($tIMAGE_DOS_HEADER, "AddressOfNewExeHeader") ; move to PE file header
    ; In place of IMAGE_NT_SIGNATURE structure
    Local $tIMAGE_NT_SIGNATURE = DllStructCreate("dword Signature", $pPointer)
    ; Check signature
    If DllStructGetData($tIMAGE_NT_SIGNATURE, "Signature") <> 17744 Then ; IMAGE_NT_SIGNATURE
        Return SetError(2, 0, 0) ; wrong signature. For PE image should be "PE\0\0" or 17744 dword.
    EndIf
    ; Move pointer
    $pPointer += 4 ; size of $tIMAGE_NT_SIGNATURE structure
    ; In place of IMAGE_FILE_HEADER structure
    ; Move pointer
    $pPointer += 20 ; size of $tIMAGE_FILE_HEADER structure
    ; Determine the type
    Local $tMagic = DllStructCreate("word Magic;", $pPointer)
    Local $iMagic = DllStructGetData($tMagic, 1)
    Local $tIMAGE_OPTIONAL_HEADER
    If $iMagic = 267 Then ; x86 version
        ; Move pointer
        $pPointer += 96 ; size of $tIMAGE_OPTIONAL_HEADER
    ElseIf $iMagic = 523 Then ; x64 version
        ; Move pointer
        $pPointer += 112 ; size of $tIMAGE_OPTIONAL_HEADER
    Else
        Return SetError(3, 0, 0) ; unsupported module type
    EndIf
    ; Validate input by checking available number of structures that are in the module
    Local Const $IMAGE_NUMBEROF_DIRECTORY_ENTRIES = 16 ; predefined value that PE modules always use (AutoIt certainly)
    If $iDirectoryEntry > $IMAGE_NUMBEROF_DIRECTORY_ENTRIES - 1 Then Return SetError(4, 0, 0) ; invalid input
    ; Calculate the offset to wanted entry (every entry is 8 bytes)
    $pPointer += 8 * $iDirectoryEntry
    ; At place of correst directory entry
    Local $tIMAGE_DIRECTORY_ENTRY = DllStructCreate("dword VirtualAddress; dword Size", $pPointer)
    ; Collect data
    Local $pAddress = DllStructGetData($tIMAGE_DIRECTORY_ENTRY, "VirtualAddress")
    If $pAddress = 0 Then Return SetError(5, 0, 0) ; invalid input
    ; $pAddress is RVA, add it to base address
    Return $hInstance + $pAddress
EndFunc   ;==>ImageDirectoryEntryToData

;;;;;;;;;;;;;;START OF FUNCTIONS TAKEN FROM ErrMsgHack;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func GetTrueSourceErrorLine($aOut)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$sSourceFile=@ScriptName
$iErrLineNo=$aOut

If CreateRefFile() Then
   CompileAndRunRefFile() 
   CalculateOffset()
   Return $iLinesRead
EndIf

EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func CreateRefFile()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Local $sLine="" , $bIncludeFound=False

$sSourceFile=StringReplace($sSourceFile, ".exe", ".au3")

$sOutFileName="_errormsghack"
$fhInput=FileOpen($sSourceFile)
$fhOutput=FileOpen($sOutFileName &".au3",2)

If $fhInput=-1 Then Return False

While True
   $sLine=FileReadLine($fhInput)
   If @error=-1 Then ExitLoop
   $sLine=StringStripWS($sLine,8)
   If StringLeft($sline,8)="#include" Then
      FileWriteLine($fhOutput, $sLine)
      $bIncludeFound=True
   ElseIf $sline="" Then
   Else
      ExitLoop 
   EndIf
WEnd
   
If Not $bIncludeFound Then Return False

FileWriteLine($fhOutput, "[[[")
FileClose($fhOutput)

Return True 

EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func CompileAndRunRefFile()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
RunWait(@ProgramFilesDir &"\AutoIt3\Aut2Exe\Aut2exe.exe /in "& $sOutFileName &".au3 /console")

Local $childId=Run(@ComSpec & " /c " & $sOutFileName &".exe", "", @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($childId)
$iRefLineNo=StdOutRead($childId)

FileDelete($sOutFileName &".au3")
FileDelete($sOutFileName &".exe")

EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func CalculateOffset()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Local $iCnt=$iRefLineNo, $bInComment=False, $sLine="" 

$iLinesRead=0

FileSetPos($fhInput,0,0)

While True
   $sLine=FileReadLine($fhInput)
   If @error=-1 Then ExitLoop
   $sLine=StringStripWS($sLine,8)
   $iLinesRead+=1
   $stok=StringLeft($sLine,3)
   If $stok="#cs" Then 
      $bInComment=True
   ElseIf $stok="#ce" Then
      $bInComment=False
   EndIf
   If $sLine="" Or StringLeft($sLine,1)="#" Or StringLeft($sLine,1)=";" Or StringRight($sLine, 1)="_" Or $bInComment Then 
   Else
      If $iCnt=$iErrLineNo Then
            ExitLoop
      EndIf
      $iCnt+=1
   EndIf
WEnd

Which leaves the AvoidErrAu3Error.au3 looking like this:

#include <WinApi.au3>
#include <StringConstants.au3>
#include <AddHookApi.au3>

_Example()

Func _Example() ; mLipok example
    Local $aTest[0]
    ConsoleWrite("! " & $aTest[2] & @CRLF)
EndFunc   ;==>_Example

Just to note I took out the Wrapper directives and added a pragma to force console compile, only because I don’t normally work thru SciTe.

Thanks to both you and @trancexx for the ideas!

 

[mLipok]

Interesting.

But I got #7 instead #8

 

AovidAu3Error.zip

[mLipok]

And as I see it catch only from main Au3 file

 

AovidAu3Error_withInclude.zip

 

Edited November 8, 2020 by mLipok

[JockoDundee]

12 minutes ago, mLipok said:

But I got #7 instead #8

Interesting.  I’ll check out your zip and see what I get.

Did you by chance try it exactly as I posted it, with the include file referenced as <AddHookApi.au3>?

Not that it should matter, but I am curious if the exact same code gives different results.

How did you compile?  I used

Aut2exe /in AvoidAu3Err.au3 /console

[JockoDundee]

1 hour ago, mLipok said:

But I got #7 instead #8

I can reproduce on my side.  As far as I can tell, at least one of the files (AvoidAu3Error_Example.au3) in the zip is coming over with some high order bytes at the beginning of the file.

That may be interpreted as an extra line.  Do you see that on your end?

[mLipok]

This script is UTF + BOM

 

[JockoDundee]

9 hours ago, mLipok said:

This script is UTF + BOM

Good call.  Apparently, after a FileSetPos($fh,0,0) - FileReadLine($fh) on a UTF-8 BOM file, you pick up the BOM.  Who knew?

Here’s the fixed file.  Should be good.  Thanks!

expandcollapse popup

#include <WinApi.au3>
#include <StringConstants.au3>
#include <File.au3>
#pragma compile(Console, True)

Local  $fhInput, $fhOutput 
Local  $sErrorText, $sSourceFile, $sOutFileName
Local  $iErrLineNo, $iRefLineNo, $iLinesRead

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
AddHookApi("user32.dll", "MessageBoxW", "Intercept_MessageBoxW", "int", "hwnd;wstr;wstr;uint")

Func Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)

    Local $aOutput = StringRegExp($sText, '(?i)Line\s+(\d+)', $STR_REGEXPARRAYGLOBALMATCH)
    If @error Then Return

    If @ScriptName="_errormsghack.exe" Then
       ConsoleWrite($aOutput[0])
       Exit
    Else
       $aOutput[0]=GetTrueSourceErrorLine($aOutput[0])
    EndIf
    ConsoleWrite(@ScriptName & ' - !!! Error occured in line #' & $aOutput[0] & @CRLF)
    Return ; mLipok mod omnit MsgBox because of CUI=Y

    Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
            "hwnd", $hWnd, _
            "wstr", $sText, _
            "wstr", StringReplace($sTitle, "AutoIt", @ScriptName), _
            "uint", $iType)
    If @error Or Not $aCall[0] Then Return 0
    Return $aCall[0]
EndFunc   ;==>Intercept_MessageBoxW

; The magic is down below
Func AddHookApi($sModuleName, $vFunctionName, $vNewFunction, $sRet = "", $sParams = "")
    Local Static $pImportDirectory, $hInstance
    Local Const $IMAGE_DIRECTORY_ENTRY_IMPORT = 1
    If Not $pImportDirectory Then
        $hInstance = _WinAPI_GetModuleHandle(0)
        $pImportDirectory = ImageDirectoryEntryToData($hInstance, $IMAGE_DIRECTORY_ENTRY_IMPORT)
        If @error Then Return SetError(1, 0, 0)
    EndIf
    Local $iIsInt = IsInt($vFunctionName)
    Local $iRestore = Not IsString($vNewFunction)
    Local $tIMAGE_IMPORT_MODULE_DIRECTORY
    Local $pDirectoryOffset = $pImportDirectory
    Local $tModuleName
    Local $iInitialOffset, $iInitialOffset2
    Local $iOffset2
    Local $tBufferOffset2, $iBufferOffset2
    Local $tBuffer, $tFunctionOffset, $pOld, $fMatch, $pModuleName, $pFuncName
    Local Const $PAGE_READWRITE = 0x04
    While 1
        $tIMAGE_IMPORT_MODULE_DIRECTORY = DllStructCreate("dword RVAOriginalFirstThunk;" & _
                "dword TimeDateStamp;" & _
                "dword ForwarderChain;" & _
                "dword RVAModuleName;" & _
                "dword RVAFirstThunk", _
                $pDirectoryOffset)
        If Not DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk") Then ExitLoop
        $pModuleName = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAModuleName")
        $tModuleName = DllStructCreate("char Name[" & _WinAPI_StringLenA($pModuleName) & "]", $pModuleName)
        If DllStructGetData($tModuleName, "Name") = $sModuleName Then ; function from this module
            $iInitialOffset = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk")
            $iInitialOffset2 = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAOriginalFirstThunk")
            If $iInitialOffset2 = $hInstance Then $iInitialOffset2 = $iInitialOffset
            $iOffset2 = 0
            While 1
                $tBufferOffset2 = DllStructCreate("dword_ptr", $iInitialOffset2 + $iOffset2)
                $iBufferOffset2 = DllStructGetData($tBufferOffset2, 1)
                If Not $iBufferOffset2 Then ExitLoop
                If $iIsInt Then
                    If BitAND($iBufferOffset2, 0xFFFFFF) = $vFunctionName Then $fMatch = True ; wanted function
                Else
                    $pFuncName = $hInstance + $iBufferOffset2 + 2 ; 2 is size od "word", see line below...
                    $tBuffer = DllStructCreate("word Ordinal; char Name[" & _WinAPI_StringLenA($pFuncName) & "]", $hInstance + $iBufferOffset2)
                    If DllStructGetData($tBuffer, "Name") == $vFunctionName Then $fMatch = True ; wanted function
                EndIf
                If $fMatch Then
                    $tFunctionOffset = DllStructCreate("ptr", $iInitialOffset + $iOffset2)
                    VirtualProtect(DllStructGetPtr($tFunctionOffset), DllStructGetSize($tFunctionOffset), $PAGE_READWRITE)
                    If @error Then Return SetError(3, 0, 0)
                    $pOld = DllStructGetData($tFunctionOffset, 1)
                    If $iRestore Then
                        DllStructSetData($tFunctionOffset, 1, $vNewFunction)
                    Else
                        DllStructSetData($tFunctionOffset, 1, DllCallbackGetPtr(DllCallbackRegister($vNewFunction, $sRet, $sParams)))
                    EndIf
                    Return $pOld
                EndIf
                $iOffset2 += DllStructGetSize($tBufferOffset2)
            WEnd
            ExitLoop
        EndIf
        $pDirectoryOffset += 20 ; size of $tIMAGE_IMPORT_MODULE_DIRECTORY
    WEnd
    Return SetError(4, 0, 0)
EndFunc   ;==>AddHookApi

Func VirtualProtect($pAddress, $iSize, $iProtection)
    Local $aCall = DllCall("kernel32.dll", "bool", "VirtualProtect", "ptr", $pAddress, "dword_ptr", $iSize, "dword", $iProtection, "dword*", 0)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return 1
EndFunc   ;==>VirtualProtect

Func ImageDirectoryEntryToData($hInstance, $iDirectoryEntry)
    ; Get pointer to data
    Local $pPointer = $hInstance
    ; Start processing passed binary data. 'Reading' PE format follows.
    Local $tIMAGE_DOS_HEADER = DllStructCreate("char Magic[2];" & _
            "word BytesOnLastPage;" & _
            "word Pages;" & _
            "word Relocations;" & _
            "word SizeofHeader;" & _
            "word MinimumExtra;" & _
            "word MaximumExtra;" & _
            "word SS;" & _
            "word SP;" & _
            "word Checksum;" & _
            "word IP;" & _
            "word CS;" & _
            "word Relocation;" & _
            "word Overlay;" & _
            "char Reserved[8];" & _
            "word OEMIdentifier;" & _
            "word OEMInformation;" & _
            "char Reserved2[20];" & _
            "dword AddressOfNewExeHeader", _
            $pPointer)
    Local $sMagic = DllStructGetData($tIMAGE_DOS_HEADER, "Magic")
    ; Check if it's valid format
    If Not ($sMagic == "MZ") Then Return SetError(1, 0, 0) ; MS-DOS header missing. Btw 'MZ' are the initials of Mark Zbikowski in case you didn't know.
    ; Move pointer
    $pPointer += DllStructGetData($tIMAGE_DOS_HEADER, "AddressOfNewExeHeader") ; move to PE file header
    ; In place of IMAGE_NT_SIGNATURE structure
    Local $tIMAGE_NT_SIGNATURE = DllStructCreate("dword Signature", $pPointer)
    ; Check signature
    If DllStructGetData($tIMAGE_NT_SIGNATURE, "Signature") <> 17744 Then ; IMAGE_NT_SIGNATURE
        Return SetError(2, 0, 0) ; wrong signature. For PE image should be "PE\0\0" or 17744 dword.
    EndIf
    ; Move pointer
    $pPointer += 4 ; size of $tIMAGE_NT_SIGNATURE structure
    ; In place of IMAGE_FILE_HEADER structure
    ; Move pointer
    $pPointer += 20 ; size of $tIMAGE_FILE_HEADER structure
    ; Determine the type
    Local $tMagic = DllStructCreate("word Magic;", $pPointer)
    Local $iMagic = DllStructGetData($tMagic, 1)
    Local $tIMAGE_OPTIONAL_HEADER
    If $iMagic = 267 Then ; x86 version
        ; Move pointer
        $pPointer += 96 ; size of $tIMAGE_OPTIONAL_HEADER
    ElseIf $iMagic = 523 Then ; x64 version
        ; Move pointer
        $pPointer += 112 ; size of $tIMAGE_OPTIONAL_HEADER
    Else
        Return SetError(3, 0, 0) ; unsupported module type
    EndIf
    ; Validate input by checking available number of structures that are in the module
    Local Const $IMAGE_NUMBEROF_DIRECTORY_ENTRIES = 16 ; predefined value that PE modules always use (AutoIt certainly)
    If $iDirectoryEntry > $IMAGE_NUMBEROF_DIRECTORY_ENTRIES - 1 Then Return SetError(4, 0, 0) ; invalid input
    ; Calculate the offset to wanted entry (every entry is 8 bytes)
    $pPointer += 8 * $iDirectoryEntry
    ; At place of correst directory entry
    Local $tIMAGE_DIRECTORY_ENTRY = DllStructCreate("dword VirtualAddress; dword Size", $pPointer)
    ; Collect data
    Local $pAddress = DllStructGetData($tIMAGE_DIRECTORY_ENTRY, "VirtualAddress")
    If $pAddress = 0 Then Return SetError(5, 0, 0) ; invalid input
    ; $pAddress is RVA, add it to base address
    Return $hInstance + $pAddress
EndFunc   ;==>ImageDirectoryEntryToData

;;;;;;;;;;;;;;START OF FUNCTIONS TAKEN FROM ErrMsgHack;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func GetTrueSourceErrorLine($aOut)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$sSourceFile=@ScriptName
$iErrLineNo=$aOut

If CreateRefFile() Then
   CompileAndRunRefFile() 
   CalculateOffset()
   Return $iLinesRead
EndIf

EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func CreateRefFile()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Local $sLine="" , $bIncludeFound=False

$sSourceFile=StringReplace($sSourceFile, ".exe", ".au3")

$sOutFileName="_errormsghack"
$fhInput=FileOpen($sSourceFile)
$fhOutput=FileOpen($sOutFileName &".au3",2)

If $fhInput=-1 Then Return False

While True
   $sLine=FileReadLine($fhInput)
   If @error=-1 Then ExitLoop
   $sLine=StringStripWS($sLine,8)
   If StringLeft($sline,8)="#include" Then
      FileWriteLine($fhOutput, $sLine)
      $bIncludeFound=True
   ElseIf $sline="" Then
   Else
      ExitLoop 
   EndIf
WEnd
   
If Not $bIncludeFound Then Return False

FileWriteLine($fhOutput, "[[[")
FileClose($fhOutput)

Return True 

EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func CompileAndRunRefFile()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
RunWait(@ProgramFilesDir &"\AutoIt3\Aut2Exe\Aut2exe.exe /in "& $sOutFileName &".au3 /console")

Local $childId=Run(@ComSpec & " /c " & $sOutFileName &".exe", "", @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($childId)
$iRefLineNo=StdOutRead($childId)

FileDelete($sOutFileName &".au3")
FileDelete($sOutFileName &".exe")

EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func CalculateOffset()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Local $iCnt=$iRefLineNo, $bInComment=False, $sLine="" 

$iLinesRead=0

FileClose($fhInput)
$fhInput=FileOpen($sSourceFile)

While True
   $sLine=FileReadLine($fhInput)
   If @error=-1 Then ExitLoop
   $sLine=StringStripWS($sLine,8)
   $iLinesRead+=1
   $stok=StringLeft($sLine,3)
   If $stok="#cs" Then 
      $bInComment=True
   ElseIf $stok="#ce" Then
      $bInComment=False
   EndIf
   If $sLine="" Or StringLeft($sLine,1)="#" Or StringLeft($sLine,1)=";" Or StringRight($sLine, 1)="_" Or $bInComment Then 
   Else
      If $iCnt=$iErrLineNo Then
            ExitLoop
      EndIf
      $iCnt+=1
   EndIf
WEnd

EndFunc

 

[JockoDundee]

On 11/8/2020 at 8:00 AM, mLipok said:

And as I see it catch only from main Au3 file

If you get a sec, would you mind retesting it?  The new code (without _Example) is in my last post. 

[argumentum]

so I put this together: 

and is ignored. I'm about to feel offended.
Is a big forum

[JockoDundee]

1 hour ago, argumentum said:

so I put this together: 

looks good

to be clear, my main goal was not to suppress the msg box (although I see the value there), it was just to get the msg box to display the correct error line number for compiled programs when it did come up.

so I just wait for the msg box to come up (by a separate process), run some calculations and replace the text with the correct number.

pretty straightforward compared to what y’all are doing with dll injections and apihooking.

but since I do console mode apps, it really helps to see where your error is without any digging.

good luck!

[JockoDundee]

On 11/8/2020 at 7:55 AM, mLipok said:

But I got #7 instead #8

Hello, mLipok! 
Currently we show an open support ticket #19426 for the “off by one error” you were encountering.  We believe this has been remediated, but we have not received confirmation from you regarding this matter.

As is our policy, we close all tickets without activity for 24 hours.  If this situation reoccurs, or you have any other difficulties, please feel free to open a new case.

Thank You!

[mLipok]

 @JockoDundee ?? What you mean ?

[Jos]

49 minutes ago, mLipok said:

 @JockoDundee ?? What you mean ?

My guess would be that this is a "tongue in cheek" way of asking whether it now also works for you.