_GUICtrlEdit_SetSel() does not work in Beta v3.3.15.3.

[patshi]

Sadly the UDF function _GUICtrlEdit_SetSel() does not work in Beta v3.3.15.3.

It was still working in Beta v3.3.15.1

It seems to be not the UDF, but the compiler produces this bug.

Any chance to get a quick fix of this function to work again?

Thanks,

Patrick.

 

Edited October 22, 2020 by patshi

[Jos]

17 minutes ago, patshi said:

does not work

Meaning ??????

17 minutes ago, patshi said:

Any chance to get a quick fix of this function to work again?

What about you tell us what isn't working ?  

[patshi]

1 hour ago, Jos said:

Meaning ??????

What about you tell us what isn't working ?  

The function just does not select the text in the edit box. The main purpose of the function. The editbox just blinks very briefly as it would select all text and then deselects it again.

 

[Jos]

Show us an script that demonstrates the issue please.

Jos

ps: This will be split off into a thread in the support forum soon.

 

 

[patshi]

4 minutes ago, Jos said:

Show us an script that demonstrates the issue please.

Jos

ps: This will be split off into a thread in the support forum soon.

 

 

 

#Include <GuiEdit.au3>
#Include <GUIConstantsEx.au3>

$gGUI = GUICreate("Test")
$but = GUICtrlCreateButton("Select Text", 0, 0, 60, 20)
$edit = GUICtrlCreateEdit("Some Text Is Here", 0, 30, 640, 200)
GUISetState()

While 1
    $guiM = GUIGetMsg()
    Switch $guiM
        Case $GUI_EVENT_CLOSE
            Exit
        Case $but
            _GUICtrlEdit_SetSel($edit, 5, 6)
    EndSwitch
WEnd

 

This is the example. Works with v3.3.15.1 but not with v3.3.15.2 and v3.3.15.3

 

Thanks for any help on this.

[Nine]

Set focus to the edit box before setting the selection :

ControlFocus ($gGUI, "", $edit)
_GUICtrlEdit_SetSel($edit, 5, 6)

 

Edited October 22, 2020 by Nine

[patshi]

1 hour ago, Nine said:

Set focus to the edit box before setting the selection :

ControlFocus ($gGUI, "", $edit)
_GUICtrlEdit_SetSel($edit, 5, 6)

 

This works with v3.3.15.1 but unfortunately not with v3.3.15.3

 

[Nine]

Unfortunately it works for me in 3.3.15.3 both Win7 and Win10.

[Melba23]

patshi,

Same here - what OS are you running?

M23

[patshi]

10 hours ago, Melba23 said:

patshi,

Same here - what OS are you running?

M23

Windows 7 and Windows 10. I try a clean install of AutoIt. Maybe the files of stable/beta versions got mixed up. I report the outcome soon.

[patshi]

18 hours ago, Melba23 said:

patshi,

Same here - what OS are you running?

M23

Tested it right now with a clean install on a Win10 machine. Same result. Works with v3.3.15.1-BETA but not with v3.3.15.3-BETA, so still not solved.
Is there anything I could look up what this could cause?

 

EDIT:
i also tried to focus the editbox first, but no luck.

#Include <GuiEdit.au3>
#Include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Dim $gGUI = GUICreate(@AutoItVersion, 640, 200)
Dim $but = GUICtrlCreateButton("Select Text", 5, 5, 60, 20)
Dim $edit = GUICtrlCreateEdit("", 0, 30, 640, 120)

GUISetState()

_GUICtrlEdit_AppendText($edit, "df sdfg sdfg fdg s dfg sdfg")

Sleep(3000)

While 1
    $guiM = GUIGetMsg()
    Switch $guiM
        Case $GUI_EVENT_CLOSE
            Exit
        Case $but
            GUICtrlSetState($edit, $GUI_FOCUS)
            _GUICtrlEdit_SetSel($edit, 5, 10)
    EndSwitch
WEnd

 

Edited October 23, 2020 by patshi

[Melba23]

patshi,

Quote

Is there anything I could look up what this could cause?

As it works for the 2 responders to this thread I do not see how we can offer any more suggestions, sorry.

M23 

[Jos]

When running the OP's script with PROD (3.3.14.5) it works fine, but with BETA (3.3.15.3) nothing happens.
Will try to do some debugging to see what is happening.

Jos

Edited October 23, 2020 by Jos

[patshi]

22 hours ago, Nine said:

Set focus to the edit box before setting the selection :

ControlFocus ($gGUI, "", $edit)
_GUICtrlEdit_SetSel($edit, 5, 6)

 

Ok, somehow, magically this works now also with v3.3.15.3  🤩

Thanks all.

The final Script:

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(@AutoItVersion, 400, 300)
    Local $idEdit = GUICtrlCreateEdit("", 2, 2+20, 394, 268-20)
    Local $but = GUICtrlCreateButton("ok", 2, 2, 60, 20)
    GUISetState(@SW_SHOW)

    _GUICtrlEdit_SetText($idEdit, "Hsdf asdf ksdfhg jsdfghjsdf gdsd")
    
    While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $but
                ControlFocus($hGUI, "", $idEdit)
                _GUICtrlEdit_SetSel($idEdit, 5, 15)
        EndSwitch
    WEnd
EndFunc   ;==>Example

 

Edited October 23, 2020 by patshi

[Jos]

25 minutes ago, Jos said:

When running the OP's script with PROD (3.3.14.5) it works fine, but with BETA (3.3.15.3) nothing happens.
Will try to do some debugging to see what is happening.

Jos

Changing :

GUICtrlSetState($edit, $GUI_FOCUS)

to :

ControlFocus($hGUI, "", $Edit)

Fixes the issue in the original script. 
Does anybody know why we need to set the focus as I would have thought the Windows Message was send to the control without the requirement for giving it the focus? ..... I haven't look under the hood as yet...

Edited October 23, 2020 by Jos
typo

[funkey]

Specifying $ES_NOHIDESEL works.

Maybe there was something changed in how edit controls are generated?

 

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(@AutoItVersion, 400, 300)
    Local $idEdit = GUICtrlCreateEdit("", 2, 2+20, 394, 268-20, $ES_NOHIDESEL)
    Local $but = GUICtrlCreateButton("ok", 2, 2, 60, 20)
    GUISetState(@SW_SHOW)

    _GUICtrlEdit_SetText($idEdit, "Hsdf asdf ksdfhg jsdfghjsdf gdsd")

    While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $but
                _GUICtrlEdit_SetSel($idEdit, 5, 15)
        EndSwitch
    WEnd
EndFunc   ;==>Example

 

Edited October 23, 2020 by funkey

[Jos]

15 minutes ago, funkey said:

Maybe there was something changed in how edit controls are generated?

Good find on how to properly fix it, but strangely the default attributes for the Edit Control haven't changed since 2006, so still lost where the difference is between PROD/BETA 1&2 and BETA 3. There has to be a change there that causes this or maybe we need to set that the defaults for the edit control to include $ES_NOHIDESEL.

I leave it to the folks that build/messed with these function internally to check it.

Jos

 

[patshi]

1 hour ago, funkey said:

Specifying $ES_NOHIDESEL works.

Maybe there was something changed in how edit controls are generated?

 

funkey: i tried if with the below combinations (because I have them in a script like that)  and again, does not work - only with prior focus set to the edit.

BitOR($ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL, $ES_READONLY)

BitOR($ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL)

 

[patshi]

OK, I found something strange:

When there ist a   GUICtrlSetState($eNote, $GUI_FOCUS)  before the   _GUICtrlEdit_SetSel(....  this effect happens - even with $ES_NOHIDESEL defined.

There's something fishy with that focus stuff.

 

[Nine]

Not sure it is a good idea to have $ES_NOHIDESEL as default to edit box.  Look what is happening if you set the text at control creation :

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
  Local $hGUI = GUICreate(@AutoItVersion, 400, 300)
  Local $idEdit = GUICtrlCreateEdit("This is a test", 2, 2 + 20, 394, 268 - 20, $ES_NOHIDESEL)
  Local $but = GUICtrlCreateButton("ok", 2, 2, 60, 20)
  GUISetState(@SW_SHOW)

  While 1
    $msg = GUIGetMsg()
    Switch $msg
      Case $GUI_EVENT_CLOSE
        Exit
      Case $but
        _GUICtrlEdit_SetSel($idEdit, 5, 15)
    EndSwitch
  WEnd
EndFunc   ;==>Example

I don't like much the edit box being selected by default...