Getting the user's Fulll Name not the AD

[KickStarter15]

Hi Experts,

I'm trying to get the full name of the user by using below code (by Jos). I've been using this for 2years now but suddenly as of this day, the fullname will no longer generate in my msgBox. I tried fixing and recoding the below but still no success.

$oMyError = ObjEvent("AutoIt.Error", "ComError")
$UserObj = ObjGet("WinNT://" & @LogonDomain & "/" & @UserName)
If @error Then
    MsgBox(0, 'username', 'Error connecting to domain')
Else
    MsgBox(0, 'username', $UserObj.FullName)
EndIf
$UserObj = ""
$oMyError = ObjEvent("AutoIt.Error", "")


;FullName function
Func ComError()
    If IsObj($oMyError) Then
        $HexNumber = Hex($oMyError.number, 8)
        SetError($HexNumber)
    Else
        SetError(1)
    EndIf
    Return 0
EndFunc

 

Any advise would be appreciated, Experts. I just need to get the full name of our user.

 

Thanks,
KS15

[Marc]

Well, the code works fine and displays the full Name. So I suppose something else must have been changed on your system.

What result does the script give?

[KickStarter15]

@Marc, yup it's working before but not sure if the @LogonDomain has been changed or something in our system I just got this "MsgBox(0, 'username', 'Error connecting to domain')" when attempting to fix the code.

[water]

Here it is running as well.
If you run the following script you get the full error information written to the console:

$oError = ObjEvent("AutoIt.Error", "_COMError")
$oUser = ObjGet("WinNT://" & @LogonDomain & "/" & @UserName)
If @error Then Exit MsgBox(0, 'Username', 'Error ' & @error & ' connecting to domain!')
MsgBox(0, 'Username', $oUser.FullName)
$oUser = 0
$oError = ObjEvent("AutoIt.Error", "")
Exit

Func _COMError($oError)

    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)

EndFunc   ;==>_ErrFunc

 

[KickStarter15]

@water, here is the testing result with error.

[water]

Do you run your script from SciTE or as a compiled exe?
If it it an exe could you please copy the exe to a local drive and execute it from there? We have a security setting that limits programs to be run from "secure drives" (or whatever it is being called) only.

[KickStarter15]

@water, this is still in my scite. This was reported to me by our managers that the program is not generating anymore full name during the runtime.

[Marc]

Hm, tried to google for the error code and got some ramblings about enabling/disabling smb v1/2/3. Depending on your environment, it would be possible that the domaincontroller is old (only supporting smbv1) and if you are using windows 10, it would not be able to connect. Just a wild guess...

Out of curiousity, what does the following code do on your system?

$oError = ObjEvent("AutoIt.Error", "_COMError")

$objConnection = ObjCreate("ADODB.Connection") ; Create COM object to AD
$objConnection.ConnectionString = "Provider=ADsDSOObject"
$objConnection.Open("Active Directory Provider") ; Open connection to AD

$user = @UserName
$domain = @LogonDNSDomain

$strQuery = "<LDAP://" & $domain & ">;(&(objectCategory=person)(objectclass=user)(sAMAccountName=" & $user & "));ADsPath;subtree"
$objRecordSet = $objConnection.Execute($strQuery) ; Retrieve the FQDN if it exists

If $objRecordSet.RecordCount = 1 Then
    $ldap_entry = $objRecordSet.fields(0).value
    $oUsr = ObjGet($ldap_entry)
    $user = $oUsr.samAccountName
    $result = $oUsr.sn & ", " & $oUsr.givenName
    MsgBox(0, "Full Name", $result)
EndIf
$objConnection.close

Func _COMError($oError)
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_COMError

 

[KickStarter15]

@Marc, Thank you so much, the code is working fine and generates the fullname. However, how would we know about this smbv1 if it old or not. Anyways, thank you for your time and effort in checking my concern.😊🙏

[Marc]

Glad I could help. 🙂

About smbv1: If the domain controller is a Server 2003, you'd only be able to use smbv1. from 2008 and above, at least v2 is available.

[water]

@KickStarter15
If you need more Active Directory functions I suggest to have a look at my AD UDF

[KickStarter15]

@Marc yup got it, thanks for the information now I understand it. 👍

 

@water As always, I'm always sneaking at your UDFs which gives me more ideas and knowledge. I've learned a lot from your UDFs from the very beginning👍😏 but still there are things that I still need help😅 especially the Excel part which is very complex for me... Hehehe

[water]

Glad you like my UDFs