Remote Information (Help please) - (Moved)

[Willazuie]

Good night Guys, how are you?
I'm new here in the Forum and in the Autoit language, I tried to learn some things on my own and I even managed to, but as a work with T.I, I'm trying to develop a little program
which fetches information from other remote computers.
However, I'm trying to get information, but I can't send the computer name when I press the button for the command $ objWMIService = ObjGet ("winmgmts: \\" & $ strComputer & "\ root \ CIMV2").

 

 

#Include <Constants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>

exemplo()
Func exemplo()
    Local $Form1   = GUICreate("", 360, 190, 192, 124)
    Local $strComputer = GUICtrlCreateLabel("Enter the IP or Hostname", 10, 10, 140, 100)
    Local $infsn = GUICtrlCreateLabel("The Model you computer is: ", 10, 31, 140,100)
    Local $inserir = GUICtrlCreateInput("the IP or Hostname", 200, 10, 150, 20, 0x00020000)
    Local $result = GUICtrlCreateInput("Result", 200, 31, 150, 20, 0x00020000)
    Local $botao = GUICtrlCreateButton("Send", 200, 100, -1, -1)

    GUISetState(@SW_SHOW)

$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")
$colItems = $objWMIService.ExecQuery("Select * from Win32_Process")
For $objItem in $colItems
     $model=$objItem.Model
Next

While 1
$saida = GUIGetMsg()
Switch $saida
    Case $GUI_EVENT_CLOSE  ;$botao_1, $botao_2
        ExitLoop

    Case $botao
         $inserir = $model
        GUICtrlSetData($result, $inserir)
EndSwitch

WEnd
EndFunc

[mLipok]

38 minutes ago, Willazuie said:

Good night Guys, how are you?

I'm blind from looking at those huge letters 

but seriously.....

 to AutoIt forum.

Please edit your post accordingly to this How to post scriptsource   Forum etiquette  Forum Rules 
And please do not use such big letters  in more than 2 words.

Good night Guys, how are you?

because it looks like you're yelling at people.

[Melba23]

Moved to the appropriate forum.

Moderation Team

[Dan_555]

The problem is in the line

$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")

$strComputer is defined, and is returning the handle of the Label. 

But you want to read and insert the text from the $inserir

do something like this:

Local $ip=GuiCtrlRead($inserir)
$objWMIService = ObjGet("winmgmts:\\" & $ip & "\root\cimv2")

 

[Willazuie]

15 hours ago, mLipok said:

Estou cego de olhar para aquelas letras enormes 

mas seriamente.....

 para o fórum AutoIt.

Por favor, edite sua postagem de acordo com este  Como postar scriptsource    Regras de etiqueta do fórum   
E por favor, não use letras tão grandes em mais de 2 palavras.

Boa noite galera tudo bem

porque parece que você está gritando com as pessoas.

Sorry for the letters being large, I used google to translate and copied the font.

[Jos]

Just paste without formatting and PLEASE do not post the translated reply like in the last post!  

[Willazuie]

11 hours ago, Dan_555 said:

O problema está na linha

$ objWMIService  =  ObjGet ( "winmgmts: \\"  &  $ strComputer  &  "\ root \ cimv2" )

$ strComputer está definido e está retornando o identificador do Label. 

Mas você deseja ler e inserir o texto do $ inserir

faça algo assim:

Local  $ ip = GuiCtrlRead ( $ inserir ) 
$ objWMIService  =  ObjGet ( "winmgmts: \\"  &  $ ip  &  "\ root \ cimv2" )

 

Thanks for your help, I tried to use what you told me, but something I'm doing is still not making the code work, it could help me with that code.
Thank you again.

[TheXman]

There are a few major issues with your script:

1. On 9/19/2020 at 10:16 PM, Willazuie said:

   $strComputer = GUICtrlCreateLabel("Enter the IP or Hostname", 10, 10, 140, 100)

   As @Dan_555 said, GUICtrlCreateLabel returns a control ID, not the value of the control. GuiCtrlRead() returns the value of a input control.

2. On 9/19/2020 at 10:16 PM, Willazuie said:

   $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")
   $colItems = $objWMIService.ExecQuery("Select * from Win32_Process")
   For $objItem in $colItems
        $model=$objItem.Model
   Next

   The Win32_Process class returns process information not computer system information.  Also, "model" is not a valid property of Win32_Process.  The Win32_ComputerSystem class has a "Model" property.  I think that is what you may have been wanting to use.

3. Your script only attempts to execute the retrieval of the model once, right after showing the form.  If you want to be able to get the model each time you hit the send button, then that logic needs to be called or executed when you receive the message that button has been pressed.  I have suggested putting it a function so that you can easily reuse the function in other scripts.  However, you could have also put the logic in the message loop where the button message is processed.

 

Here is a reworked, over-simplified, well-documented example with error-checking for you to compare & contrast:

expandcollapse popup

#AutoIt3Wrapper_AU3Check_Parameters=-w 3 -w 4 -w 5 -w 6 -d

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Global $Form1    = GUICreate("", 360, 150, 192, 124)
Global $lblHost  = GUICtrlCreateLabel("Enter the IP or Hostname", 10, 10, 140, 100)
Global $inpHost  = GUICtrlCreateInput("the IP or Hostname", 200, 10, 150, 20, 0x00020000)
Global $lblModel = GUICtrlCreateLabel("The Model you computer is: ", 10, 31, 140,100)
Global $inpModel = GUICtrlCreateInput("Result", 200, 31, 150, 20, 0x00020000)
Global $btnSend  = GUICtrlCreateButton("Send", 200, 60, -1, -1, $BS_DEFPUSHBUTTON)

example()
Func example()

    Local $sHost = "", $sModel = ""

    ;Initialize host field with the current computer name
    GUICtrlSetData($inpHost, @ComputerName)

    ;Show form and process messages
    GUISetState(@SW_SHOW, $Form1)
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btnSend
                ;Get model and update form field
                $sHost  = GUICtrlRead($inpHost)
                $sModel = get_computer_model($sHost)
                GUICtrlSetData($inpModel, $sModel)
        EndSwitch
    WEnd

EndFunc

Func get_computer_model($sHost = @ComputerName)

    Local $oWmi, $oCollection

    ObjEvent("AutoIt.Error", com_error_handler)

    ;Create WMI object
    $oWmi = ObjGet("winmgmts:\\" & $sHost & "\root\cimv2")
    If Not IsObj($oWmi) Then
        MsgBox($MB_ICONERROR, "ERROR", "Error creating WMI object for " & $sHost)
        Return ""
    EndIf

    ;Get computer info instance
    $oCollection = $oWmi.ExecQuery("SELECT model FROM Win32_ComputerSystem")
    If Not IsObj($oCollection) Then
        MsgBox($MB_ICONERROR, "ERROR", "Error retrieving computer information.")
        Return ""
    EndIf

    ;Return model
    Return $oCollection.ItemIndex(0).Model ;Only 1 instance so no need for ForNext.

EndFunc

Func com_error_handler($oComErr)
    Local $sErrMsg

    With $oComErr
        $sErrMsg =  @CRLF
        $sErrMsg &= ">>>  COM ERROR  <<<" & @CRLF
        $sErrMsg &= StringFormat("Script Line Number : %s", .ScriptLine) & @CRLF
        $sErrMsg &= StringFormat("HRESULT            : 0x%x (%s)", .Number, .Number) & @CRLF
        $sErrMsg &= StringFormat("Windows Error      : %s", StringStripWS(.WinDescription, $STR_STRIPTRAILING)) & @CRLF
        $sErrMsg &= StringFormat("Object Description : %s", StringStripWS(.Description, $STR_STRIPTRAILING)) & @CRLF
        ConsoleWrite($sErrMsg)
    EndWith

    Exit
EndFunc

 

Edited September 21, 2020 by TheXman
Fixed typos and tweaked example script

[Willazuie]

On 9/20/2020 at 11:29 PM, TheXman said:

There are a few major issues with your script:

1. As @Dan_555 said, GUICtrlCreateLabel returns a control ID, not the value of the control. GuiCtrlRead() returns the value of a input control.

2. The Win32_Process class returns process information not computer system information.  Also, "model" is not a valid property of Win32_Process.  The Win32_ComputerSystem class has a "Model" property.  I think that is what you may have been wanting to use.

3. Your script only attempts to execute the retrieval of the model once, right after showing the form.  If you want to be able to get the model each time you hit the send button, then that logic needs to be called or executed when you receive the message that button has been pressed.  I have suggested putting it a function so that you can easily reuse the function in other scripts.  However, you could have also put the logic in the message loop where the button message is processed.

 

Here is a reworked, over-simplified, well-documented example with error-checking for you to compare & contrast:

expandcollapse popup

#AutoIt3Wrapper_AU3Check_Parameters=-w 3 -w 4 -w 5 -w 6 -d

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Global $Form1    = GUICreate("", 360, 150, 192, 124)
Global $lblHost  = GUICtrlCreateLabel("Enter the IP or Hostname", 10, 10, 140, 100)
Global $inpHost  = GUICtrlCreateInput("the IP or Hostname", 200, 10, 150, 20, 0x00020000)
Global $lblModel = GUICtrlCreateLabel("The Model you computer is: ", 10, 31, 140,100)
Global $inpModel = GUICtrlCreateInput("Result", 200, 31, 150, 20, 0x00020000)
Global $btnSend  = GUICtrlCreateButton("Send", 200, 60, -1, -1, $BS_DEFPUSHBUTTON)

example()
Func example()

    Local $sHost = "", $sModel = ""

    ;Initialize host field with the current computer name
    GUICtrlSetData($inpHost, @ComputerName)

    ;Show form and process messages
    GUISetState(@SW_SHOW, $Form1)
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btnSend
                ;Get model and update form field
                $sHost  = GUICtrlRead($inpHost)
                $sModel = get_computer_model($sHost)
                GUICtrlSetData($inpModel, $sModel)
        EndSwitch
    WEnd

EndFunc

Func get_computer_model($sHost = @ComputerName)

    Local $oWmi, $oCollection

    ObjEvent("AutoIt.Error", com_error_handler)

    ;Create WMI object
    $oWmi = ObjGet("winmgmts:\\" & $sHost & "\root\cimv2")
    If Not IsObj($oWmi) Then
        MsgBox($MB_ICONERROR, "ERROR", "Error creating WMI object for " & $sHost)
        Return ""
    EndIf

    ;Get computer info instance
    $oCollection = $oWmi.ExecQuery("SELECT model FROM Win32_ComputerSystem")
    If Not IsObj($oCollection) Then
        MsgBox($MB_ICONERROR, "ERROR", "Error retrieving computer information.")
        Return ""
    EndIf

    ;Return model
    Return $oCollection.ItemIndex(0).Model ;Only 1 instance so no need for ForNext.

EndFunc

Func com_error_handler($oComErr)
    Local $sErrMsg

    With $oComErr
        $sErrMsg =  @CRLF
        $sErrMsg &= ">>>  COM ERROR  <<<" & @CRLF
        $sErrMsg &= StringFormat("Script Line Number : %s", .ScriptLine) & @CRLF
        $sErrMsg &= StringFormat("HRESULT            : 0x%x (%s)", .Number, .Number) & @CRLF
        $sErrMsg &= StringFormat("Windows Error      : %s", StringStripWS(.WinDescription, $STR_STRIPTRAILING)) & @CRLF
        $sErrMsg &= StringFormat("Object Description : %s", StringStripWS(.Description, $STR_STRIPTRAILING)) & @CRLF
        ConsoleWrite($sErrMsg)
    EndWith

    Exit
EndFunc

 

Mr. TheXman,I thank you for all your attention and for helping me with this code that is in perfect formatting and orientation.I will study over this code to have more knowledge on the subject.Thank you for your time in helping me and everyone here who guided me with my problem.

[TheXman]

You're welcome!