[SOLVED] _SendDocument missing "parse_mode"

[Colduction]

Hi guys, i'm using Telegram UDF by @LinkOut from github with latest update, but this UDF has not any parse_mode ability in SendDocument and other send file's functions to make texts bold, italic or underline and i can't send Emojis via these functions too. i've tried to change HTML section of multipart/form-data but i did not get correct results.

For example, i can't get correct results by sending a document with this URL Encoded caption: %F0%9F%93%84%20*Test*%20%F0%9F%93%84

I will be happy to help me in this section. Thanks!

Edited July 4, 2020 by Colduction

[Colduction]

Any idea? 

[Jos]

It always helps when you post a replication script as many don't feel the urge to help when they all have to figure it out what you mean and type the code to test.
... but when the option is available in the Telegram bot definition, it should be simple to modify.

Jos 

[Colduction]

13 minutes ago, Jos said:

type the code to test

Func _SendDocument($ChatID, $Document, $Caption = '', $ReplyMarkup = Default, $ReplyToMessage = '', $DisableNotification = False)
    Local $Query = $URL & '/sendDocument'
    Local $hOpen = _WinHttpOpen()
    Local $Form = '<form action="' & $Query & '" method="post" enctype="multipart/form-data">' & _
            '<input type="text" name="chat_id"/>' & _
            '<input type="file" name="document"/>' & _
            '<input type="text" name="parse_mode"/>' & _
            '<input type="text" name="caption"/>'
    If $ReplyMarkup <> Default Then $Form &= ' <input type="text" name="reply_markup"/>'
    If $ReplyToMessage <> '' Then $Query &= '<input type="text" name="reply_to_message_id"/>'
    If $DisableNotification Then $Form &= ' <input type="text" name="disable_notification"/>'
    $Form &= '</form>'
    Local $Response = _WinHttpSimpleFormFill($Form, $hOpen, Default, _
            "name:chat_id", $ChatID, _
            "name:document", $Document, _
            "name:parse_mode", "markdown", _
            "name:caption", $Caption, _
            "name:reply_markup", $ReplyMarkup, _
            "name:reply_to_message_id", $ReplyToMessage, _
            "name:disable_notification", $DisableNotification)
    _WinHttpCloseHandle($hOpen)
    Local $json = Json_Decode($Response)
    If Not (Json_IsObject($json)) Then Return SetError($INVALID_JSON_RESPONSE, 0, False) ; JSON Check
    Return __GetFileID($json, 'document')
EndFunc   ;==>_SendDocument

This is what i've tried.

[Jos]

My guess would be that you need: 

name:parse_mode", "HTML"

.. but if you want me to test it you need to post that requested example script to test with.  

[Colduction]

10 minutes ago, Jos said:

My guess would be that you need: 

name:parse_mode", "HTML"

.. but if you want me to test it you need to post that requested example script to test with.  

We are free to select parse_mode style, there is no limit! but one of my problems is that Emojis are not supported in this function, even with URL Encoded emoji!

[Jos]

Ok....  So?...   Are they at all supported in telegram for that function?

Edited July 5, 2020 by Jos

[Colduction]

2 minutes ago, Jos said:

Are they at all supported in telegram for that function?

Yes! see this link:
https://core.telegram.org/bots/api#senddocument

[Jos]

Ok...I just don't see that test script yet

[Colduction]

9 minutes ago, Jos said:

.I just don't see that test script yet

#include <Telegram.au3>

Global Const $ChatID = '123456789'
Global Const $sToken  = '123456789:AAHezzlggo2NOmS0_o-3oZ4qTtTCs8bLiRg'

_InitBot($sToken)
_SendDocument($ChatID, @DesktopDir & "\1.txt", '%F0%9F%93%84%20*Test*%20%F0%9F%93%84')

 

[EDITED] Telegram UDF.rar

Edited July 5, 2020 by Colduction

[Jos]

parse_mode isn't the issue and not required.
It seems that the enctype="multipart/form-data", used for the SendDocument() form is not supporting URLENCODED characters.

Not sure yet how to solve this at the moment.

Jos

[Colduction]

5 hours ago, Jos said:

enctype="multipart/form-data", used for the SendDocument() form is not supporting URLENCODED characters

Maybe...

But i know that this this is available.

[Jos]

I agree it is available in the API, it has to do with the implementation in the udf using a enctype="multipart/form-data

... Which you seem to question?

 

[Colduction]

3 hours ago, Jos said:

I agree it is available in the API, it has to do with the implementation in the udf using a enctype="multipart/form-data

... Which you seem to question?

 

I solved one part of my question and now i can send message as markdown parse_mode, but in both before\after editing the source i couldn't send Emojis.

[Jos]

As stated, it has to do with the way it was implemented in the UDF. Using CURL like this it works fine:

curl -F document=@"1.txt" https://api.telegram.org/bot123456789:AAHezzlggo2NOmS0_o-3oZ4qTtTCs8bLiRg/sendDocument?chat_id=123456789&caption=%F0%9F%93%84%20*Test*%20%F0%9F%93%84

So somebody needs to translate that CURL statement to the proper winhttp syntax.

Jos

[Colduction]

1 minute ago, Jos said:

curl -F document=@"1.txt" https://api.telegram.org/bot123456789:AAHezzlggo2NOmS0_o-3oZ4qTtTCs8bLiRg/sendDocument?chat_id=123456789&caption=%F0%9F%93%84%20*Test*%20%F0%9F%93%84

i've tried this code without passing markdown text as HTML style, but i didn't get good response, it was same.

as you told, i think i should change:

11 minutes ago, Colduction said:

enctype="multipart/form-data

 

[Jos]

20 minutes ago, Colduction said:

i've tried this code without passing markdown text as HTML style, but i didn't get good response, it was same.

It is working correctly for me as far as I can tell: 

 

.. or am I missing something?

Jos

Edited July 6, 2020 by Jos

[Colduction]

@Jos, I wrote same thing as you:
 

Func _SendDocument($ChatID, $Document, $Caption = '', $ReplyMarkup = Default, $ReplyToMessage = '', $DisableNotification = False)
    Local $Query = $URL & '/sendDocument?parse_mode=markdown&caption=' & $Caption
    Local $hOpen = _WinHttpOpen()
    Local $Form = '<form action="' & $Query & '" method="post" enctype="multipart/form-data">' & _
            '<input type="text" name="chat_id"/>' & _
            '<input type="file" name="document"/>'
    If $ReplyMarkup <> Default Then $Form &= ' <input type="text" name="reply_markup"/>'
    If $ReplyToMessage <> '' Then $Query &= '<input type="text" name="reply_to_message_id"/>'
    If $DisableNotification Then $Form &= ' <input type="text" name="disable_notification"/>'
    $Form &= '</form>'
    Local $Response = _WinHttpSimpleFormFill($Form, $hOpen, Default, _
            "name:chat_id", $ChatID, _
            "name:document", $Document, _
            "name:reply_markup", $ReplyMarkup, _
            "name:reply_to_message_id", $ReplyToMessage, _
            "name:disable_notification", $DisableNotification)
    _WinHttpCloseHandle($hOpen)
    Local $json = Json_Decode($Response)
    If Not (Json_IsObject($json)) Then Return SetError($INVALID_JSON_RESPONSE, 0, False) ; JSON Check
    Return __GetFileID($json, 'document')
EndFunc   ;==>_SendDocument

But as you told, i should think about enctype="multipart/form-data"

[Colduction]

@Jos, I've fixed both Emojis and Markdown style by adding _URLDecode() function, but now i have new problem, i can't send %0D%0A to make new line, WinHTTP replace %20 instead of %0D%0A
 

Func _SendDocument($ChatID, $Document, $Caption = '', $ReplyMarkup = Default, $ReplyToMessage = '', $DisableNotification = False)
    Local $Query = $URL & '/sendDocument?chat_id=' & $ChatID & '&parse_mode=markdown&caption=' & _URLDecode($Caption)
    Local $hOpen = _WinHttpOpen()
    Local $Form = '<form action="' & $Query & '" method="post" enctype="multipart/form-data">' & '<input type="file" name="document"/>'
    If $ReplyMarkup <> Default Then $Form &= ' <input type="text" name="reply_markup"/>'
    If $ReplyToMessage <> '' Then $Query &= '<input type="text" name="reply_to_message_id"/>'
    If $DisableNotification Then $Form &= ' <input type="text" name="disable_notification"/>'
    $Form &= '</form>'
    Local $Response = _WinHttpSimpleFormFill($Form, $hOpen, Default, _
            "name:document", $Document, _
            "name:reply_markup", $ReplyMarkup, _
            "name:reply_to_message_id", $ReplyToMessage, _
            "name:disable_notification", $DisableNotification)
    _WinHttpCloseHandle($hOpen)
    Local $json = Json_Decode($Response)
    If Not (Json_IsObject($json)) Then Return SetError($INVALID_JSON_RESPONSE, 0, False) ; JSON Check
    Return __GetFileID($json, 'document')
EndFunc   ;==>_SendDocument

Func _URLDecode($sData)
    Local $aData = StringSplit(StringReplace($sData, "%20", " ", 0, 1), "%")
    $sData = ""
    For $i = 2 To $aData[0]
        $aData[1] &= Chr(Dec(StringLeft($aData[$i], 2))) & StringTrimLeft($aData[$i], 2)
    Next
    Return BinaryToString(StringToBinary($aData[1], 1), 4)
EndFunc   ;==>_URLDecode

 

Edited July 6, 2020 by Colduction

[Jos]

You can make it all work fine without the _UrlDecode when you apply the following changes:

 Telegram.au3:

Func _SendDocument($ChatID, $Document, $Caption = '', $ReplyMarkup = Default, $ReplyToMessage = '', $DisableNotification = False)
    Local $Query = $URL & '/sendDocument?chat_id=' & $ChatID & '&parse_mode=markdown&caption=' & $Caption
    If $ReplyMarkup <> Default Then $Query &= "&reply_markup=" & $ReplyMarkup
    If $ReplyToMessage <> '' Then $Query &= "&reply_to_message_id=" & $ReplyToMessage
    If $DisableNotification Then $Query &= "&disable_notification=" & $DisableNotification
    Local $hOpen = _WinHttpOpen()
    Local $Form = '<form action="' & $Query & '" method="post" enctype="multipart/form-data"><input type="file" name="document"/>'
    $Form &= '</form>'
    Local $Response = _WinHttpSimpleFormFill($Form, $hOpen, Default, _
            "name:document", $Document)
    _WinHttpCloseHandle($hOpen)
    Local $json = Json_Decode($Response)
    If Not (Json_IsObject($json)) Then Return SetError($INVALID_JSON_RESPONSE, 0, False) ; JSON Check
    Return __GetFileID($json, 'document')
EndFunc   ;==>_SendDocument

winhttp:au3:

Func __WinHttpNormalizeActionURL($sActionPage, ByRef $sAction, ByRef $iScheme, ByRef $sNewURL, ByRef $sEnctype, ByRef $sMethod, $sURL = "")
;~  Local $aCrackURL = _WinHttpCrackUrl($sAction)
    Local $aCrackURL = _WinHttpCrackUrl($sAction, $ICU_DECODE)

This issue is that the latter UDF call to _WinHttpCrackUrl($sAction) will perform a urlencode by default which is changed by adding  the second parameter to make it do the reverse.  Don't make this change a permanent one in the standard winhttp.au3, but for me now all works fine... both the emoji's and %0a for a newline.

Jos