[Solved] How do I detect click on an input control?

[CYCho]

The following code does not work.

#include <GUIConstantsEx.au3>

GUICreate(" My GUI input control", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1)
Local $idInput = GUICtrlCreateInput("", 10, 5, 300, 20)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $idInput
            MsgBox(0, "", "Input control was clicked")
    EndSwitch
WEnd

Having not found a handy way to make it work, I created a label control beneath the input control and it simulates detection of click on input control.

#include <GUIConstantsEx.au3>

GUICreate(" My GUI input control", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1)
Local $idLabel = GUICtrlCreateLabel("", 10, 5, 300, 20)
Local $idInput = GUICtrlCreateInput("", 10, 5, 300, 20)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $idLabel
            MsgBox(0, "", "Input control was clicked")
    EndSwitch
WEnd

Is this a viable way? Or is there a better way to make this happen?

Edited June 22, 2020 by CYCho

[Nine]

Message hook will let you do it :

#include <WinAPI.au3>
#include <GUIConstants.au3>

GUICreate(" My GUI input control", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1)
Local $idInput = GUICtrlCreateInput("", 10, 5, 300, 20)
$wProcHandle = DllCallbackRegister("_WindowProc", "ptr", "hwnd;uint;wparam;lparam")
$wProcOld = _WinAPI_SetWindowLong(GUICtrlGetHandle($idInput), $GWL_WNDPROC, DllCallbackGetPtr($wProcHandle))

GUISetState(@SW_SHOW)

While 1
  Switch GUIGetMsg()
    Case $GUI_EVENT_CLOSE
      ExitLoop
  EndSwitch
WEnd

DllCallbackFree($wProcHandle)

Func _WindowProc($hWnd, $Msg, $wParam, $lParam)
  If $hWnd = GUICtrlGetHandle($idInput) And $Msg = $WM_LBUTTONDOWN Then
    ConsoleWrite("-> Left mouse simple click" & @LF)
  EndIf
  Return _WinAPI_CallWindowProc($wProcOld, $hWnd, $Msg, $wParam, $lParam)
EndFunc   ;==>_WindowProc

 

[careca]

#include <GUIConstantsEx.au3>

Local $GUI = GUICreate(" My GUI input control", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1)
Local $idInput = GUICtrlCreateInput("", 10, 5, 300, 20)
Local $CurInfo

GUISetState(@SW_SHOW)

While 1
    $CurInfo = GUIGetCursorInfo($GUI)
    If $CurInfo[4] = $idInput And $CurInfo[2] = 1 Then
        MsgBox(64 + 262144, '', '')
    EndIf
    ;=============================================================================
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
    Sleep(100)
WEnd

Or like this

[CYCho]

@Nine and @careca, Thank you for your kind attention and knowledgeable suggestions.