re: TimerDiff, TimerInit

[Burgaud]

 Does TimerDiff() has a maximum range of values such that

local $timer = TimerInit()
.
. many days later, even a hibernate in between
.
local $duration = TimerDiff($timer)

will still work, able to count the number of ms in between?

Dan

 

[jchd]

Let's see.

Local $t = TimerInit()
ConsoleWrite(VarGetType($t) & @TAB & $t & @LF)

So it's a double. 64-bit floating-point can represent every incrementing positive integer up to the value 9007000000000000 (at least) since it's in this magnitude vincinity that an ULP comes close to 1.*

That many milliseconds represents about:
9007000000000 seconds
150116666666 minutes
2501944444 hours
104247685 days
285414 years

Hence I don't recommend holding your breath until the value misses a single millisecond (else you have a f*ck*ng efficient hibernation technology).

* EDIT: actually the max positive integral value you can store before ULP gets > 1 is 9007199254740991 (= 2⁵³ - 1), which gives you some more years to wait.

Edited June 9, 2020 by jchd

[argumentum]

..this got me thinking.  ( can you hear the silence in my head ? )
..nope, no thoughts, ... in the help file is say "The return value from TimerInit() should be treated as an opaque handle..." , hmmm, so I wrote an awesome code:

Global $t = IniRead(StringTrimRight(@ScriptFullPath, 4) & ".ini", "s", "s", TimerInit())
IniWrite(StringTrimRight(@ScriptFullPath, 4) & ".ini", "s", "s", $t) ; ..i know,i know. this is a test.
ConsoleWrite( TimerDiff( $t ) & @CRLF)
If Not StringInStr($CmdLineRaw, "/ErrorStdOut") Then MsgBox(0, @ScriptName, "TimerDiff:" & @LF & TimerDiff( $t ), 10)

and it works. So ...., is an epoch of sorts, in a measure of sorts. Can you say more about this @jchd ?.

[ 2014 answer from @Mat ] "It's never actually documented what the return type is. It could change in the next release to something completely different, so ...".
[ 2008 answer from @weaponx] "Time in milliseconds since last boot." ( and the test code shows to be right ).

..so I guess I have my answers

PS: so is a QueryPerformanceCounter thing and for what I read it can get complicated.
I've got more answers than is practical to look at, for the practical use of the function.

Edited June 9, 2020 by argumentum
got it

[Burgaud]

@argumentum

You confused me ... 🤔

[argumentum]

...you've got a perfect answer from @jchd.

I had ideas of my own. To use it as a timestamp. But is the time since boot, so I can not use it as a timestamp.
( the rest of the links are just me thinking out loud )

[Burgaud]

Ok... now I understand what TimerInit() is...  a time since BOOT!

a hibernate should not undo it.

thnx!

[jchd]

Yeah I knew it was a kinda wrapper around some performancecounter, and I seemed to remind it was an AutoIt int64. So i rechecked and no: double.

Advantage: doubles are signed so the result doesn't turn nonsensical when you compute backwards timediffs. Maybe it's the only reason to use doubles.

[Exit]

Just a small script to show the difference after a hibernate.

Local $iTimer = TimerInit()
MsgBox(64 + 262144, Default, "Now do a hibernate and wait some minutes." & @LF & @LF & "After resume, press ok.", 0)
Local $iMilliseconds = Round(TimerDiff($iTimer))
Local $iMsec = _Mod($iMilliseconds, 1000)
Local $iSec = _Mod(@extended, 60)
Local $iMin = _Mod(@extended, 60)
Local $iHour = _Mod(@extended, 24)
Local $iDay = @extended
Local $sText = "The difference between Timerinit() and Timerdiff() was" & @LF & @LF
If $iDay Then $sText &= $iDay & " days" & @CRLF
If $iHour + $iDay Then $sText &= $iHour & " hours" & @CRLF
If $iMin + $iHour + $iDay Then $sText &= $iMin & " minutes" & @CRLF
If $iSec + $iMin + $iHour + $iDay Then $sText &= $iSec & " seconds" & @CRLF
If $iMsec Then $sText &= $iMsec & " milliseconds" & @CRLF
ConsoleWrite($sText & @CRLF)
MsgBox(64 + 262144, Default, $sText, 0)

Func _Mod($dividend, $divisor = 10)
    Return $divisor ? SetError(0, Int($dividend / $divisor), $dividend - Int($dividend / $divisor) * $divisor) : SetError(1, -1, -1)
EndFunc   ;==>_Mod

You may use it also without a hibernate.