How to detect if au3 was launched from Visual Studio Code?

[aVen9er]

I would like my script to do something different depending on whether my * .au3 file was launched from Visual Studio Code (by pressing F5) or by double-clicking in Windows Explorer.

How to detect if *.au3 file was launched from Visual Studio Code?

[Danyfirex]

I think you can check parent process of your process. Something like

 

_WinAPI_GetProcessName(_WinAPI_GetParentProcess())

 

PD: sorry for don't using sintaxis highlight I'm by phone. I'll update later.

Saludos

[Nine]

I think you would need to use 2 get parent process.  With Scite at least it is working...

MsgBox ($MB_SYSTEMMODAL,"",_WinAPI_GetProcessName(_WinAPI_GetParentProcess(_WinAPI_GetParentProcess())))

 

[aVen9er]

This is it!

Thank you for a such a quick reply!

[argumentum]

#include <Debug.au3>
#include <WinAPIProc.au3>
_DebugArrayDisplay(WhereAreMyParents(), "WhereAreMyParents")
Func WhereAreMyParents($iPID = @AutoItPID)
    Local $s, $a[11][3] = [[0, "", ""]]
    $a[1][0] = $iPID
    $a[1][1] = _WinAPI_GetProcessName($iPID)
    $a[1][2] = _WinAPI_GetProcessCommandLine($iPID)
    For $n = 2 To 10
        $iPID = _WinAPI_GetParentProcess($iPID)
        If $iPID = 0 Then ExitLoop
        $a[0][0] = $n
        $a[$n][0] = $iPID
        $a[$n][1] = _WinAPI_GetProcessName($iPID)
        $a[$n][2] = _WinAPI_GetProcessCommandLine($iPID)
    Next
    ReDim $a[$a[0][0] + 1][3]
    Return $a
EndFunc   ;==>WhereAreMyParents

..I know I'm late but I type with 2 fingers and I was quite invested so, there !   

[TheDcoder]

@argumentum Kudos for the effort!

@aVen9er You might also want to consider an alternative method of detection, maybe you can pass custom command line parameters, or maybe even use the @Compiled macro. All of my suggestions of course are generic, it is not possible to suggest the best method without knowing the use case

[Nine]

1 hour ago, argumentum said:

but I type with 2 fingers

Sorry to hear you have lost 8 fingers...