@FuncName ?

[argumentum]

I use /RM (Rename Variables and Functions to a shorter name) in the AutoIt3Wrapper GUI to Compile, and have to use #Au3Stripper_Off / #Au3Stripper_On.

@NumParams exists, a @FuncName makes sense to me, and would allow me to workaround limitations in renaming functions.

If @FuncName is a possibility given the way AutoIt is coded, I would open a ticket to request it for a future build, otherwise I would be requesting nonsense out of my .... imagination  

Thanks @Jon

[MrCreatoR]

11 years ago was proposed, and... rejected.

[Jos]

This seems to be related to au3stripper.
Please show me a snippet that shows what you are talking about so I can have a look at it.

Jos

[argumentum]

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/rm
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

Func SayHiMsgBox($sMsg)
    MsgBox(0,@ScriptName, $sMsg, 20)
EndFunc

Func RunSayHiMsgBox($sFunc, $sMsg)
    Execute($sFunc & '("' & $sMsg & '")')
EndFunc

RunSayHiMsgBox("SayHiMsgBox", "Yellow there   =)")

it will not run compiled but we both know why and how to get around it.

Now about the ticket #1243:

Changed 11 years ago by Valik
Resolution set to Rejected
Status changed from new to closed
Version 3.3.0.0 deleted
No, the macro causes way too much performance degradation. Also, terrible example. You're requesting the feature to write bad code. Not exactly the best way to get it considered.

My request has a different approach/reason and would be available within the function just like @NumParams is.
I know that there is no performance impact implementing it, if it was possible. Now, is it practical / useful to implement such ? ( I believe it is )

Also know that a "function reference map" can be created by au3stripper and/or the coder. Or the coder can patch the *_stripped.au3 and compile that. So is not like "OMG what am I going to do" but I believe a @FuncName goes well with @NumParams.

Edited May 19, 2020 by argumentum

[Jos]

This does make sense it doesn't work as au3stripper has no way of knowing that SayHiMsgBox() is used via the Execute statement.
The simple way to "fix" this is to add this line:

#Au3Stripper_Ignore_Funcs=SayHiMsgBox

It is also very hard to test for this potential issue and create a warning/error, like I do with a Call() statement.

Jos

[MrCreatoR]

But do you have an example that shows the real need of such macro?

I mean what is the usage in this case?

[jchd]

Since AutoIt functions are now first-class citizen, passing function names as strings is only calling for trouble.

[argumentum]

17 minutes ago, Jos said:

The simple way to "fix" this is...

..yes, I know. The request for the new macro is if, is not a big deal to implement. Otherwise, meh, no big deal. Is not existent at the moment but if it exited may have been used.

@MrCreatoR, there is no immediate need for it nor I have code that must use it, but I would argue that neither @NumParams is a must have, tho may come in handy.

[jchd]

As I said above, the correct code would be:

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/rm
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

Func SayHiMsgBox($sMsg)
    MsgBox(0,@ScriptName, $sMsg, 20)
EndFunc

Func RunSayHiMsgBox($Func, $sMsg)
    Execute(FuncName($Func) & '("' & $sMsg & '")')
EndFunc

RunSayHiMsgBox(SayHiMsgBox, "Yellow there   =)")

Or did I miss something?

[argumentum]

4 minutes ago, jchd said:

Since AutoIt functions are now first-class citizen, passing function names as strings is only calling for trouble.

my understanding of language is limited, both code and human wise. I did not get the "first-class citizen" part. 

As  far as code, say:

Spoiler

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/rm
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; https://www.autoitscript.com/forum/topic/143250-grab-runtime-errors-when-script-is-run-from-a-service/?tab=comments#comment-1009391
If @Compiled Then _AddHookApi("user32.dll", "MessageBoxW", "_Intercept_MessageBoxW", "int", "hwnd;wstr;wstr;uint")
Func _Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)
    If $sTitle = "AutoIt Error" Then
;~      ; For example:
;~      ConsoleWriteError($sTitle & " " & $sText & @CRLF)
;~  Else
        Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
                "hwnd", $hWnd, _
                "wstr", "My " & $sText, _
                "wstr", "My " & $sTitle, _
                "uint", $iType)
        If @error Or Not $aCall[0] Then Return 0
        Return $aCall[0]
    EndIf
EndFunc   ;==>_Intercept_MessageBoxW
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Let's try it (don't forget to compile)
; Usual message box
MsgBox(0, 'Test', 'Some text')
; Cause array error
Global $aArray[3] = [1, 2, 3]
$aArray[4] = 4 ; !!!!


Func _AddHookApi($sModuleName, $vFunctionName, $vNewFunction, $sRet = "", $sParams = "")
    Local Static $pImportDirectory, $hInstance
    If Not $pImportDirectory Then
        $hInstance = _GetModuleHandle()
        If @error Then Return SetError(1, 0, 0)
        Local $aCall = DllCall("dbghelp.dll", "ptr", "ImageDirectoryEntryToData", _
                "handle", $hInstance, _
                "boolean", 1, _ ; as an image
                "word", 1, _ ; IMAGE_DIRECTORY_ENTRY_IMPORT
                "dword*", 0)
        If @error Or Not $aCall[0] Then Return SetError(2, 0, 0)
        $pImportDirectory = $aCall[0]
    EndIf
    Local $iIsInt = IsInt($vFunctionName)
    Local $iRestore = Not IsString($vNewFunction)
    Local $tIMAGE_IMPORT_MODULE_DIRECTORY
    Local $pDirectoryOffset = $pImportDirectory
    Local $tModuleName
    Local $iInitialOffset, $iInitialOffset2
    Local $iOffset2
    Local $tBufferOffset2, $iBufferOffset2
    Local $tBuffer, $tFunctionOffset, $pOld, $fMatch
    Local Const $PAGE_READWRITE = 0x04
    While 1
        $tIMAGE_IMPORT_MODULE_DIRECTORY = DllStructCreate("dword RVAOriginalFirstThunk;" & _
                "dword TimeDateStamp;" & _
                "dword ForwarderChain;" & _
                "dword RVAModuleName;" & _
                "dword RVAFirstThunk", _
                $pDirectoryOffset)
        If Not DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk") Then ExitLoop
        $tModuleName = DllStructCreate("char Name[64]", $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAModuleName"))
        If DllStructGetData($tModuleName, "Name") = $sModuleName Then ; function from this module
            $iInitialOffset = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk")
            $iInitialOffset2 = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAOriginalFirstThunk")
            If $iInitialOffset2 = $hInstance Then $iInitialOffset2 = $iInitialOffset
            $iOffset2 = 0
            While 1
                $tBufferOffset2 = DllStructCreate("dword_ptr", $iInitialOffset2 + $iOffset2)
                $iBufferOffset2 = DllStructGetData($tBufferOffset2, 1)
                If Not $iBufferOffset2 Then ExitLoop
                If $iIsInt Then
                    If BitAND($iBufferOffset2, 0xFFFFFF) = $vFunctionName Then $fMatch = True ; wanted function
                Else
                    $tBuffer = DllStructCreate("ushort Ordinal; char Name[64]", $hInstance + $iBufferOffset2)
                    If DllStructGetData($tBuffer, "Name") == $vFunctionName Then $fMatch = True ; wanted function
                EndIf
                If $fMatch Then
                    $tFunctionOffset = DllStructCreate("ptr", $iInitialOffset + $iOffset2)
                    _VirtualProtect(DllStructGetPtr($tFunctionOffset), DllStructGetSize($tFunctionOffset), $PAGE_READWRITE)
                    If @error Then Return SetError(3, 0, 0)
                    $pOld = DllStructGetData($tFunctionOffset, 1)
                    If $iRestore Then
                        DllStructSetData($tFunctionOffset, 1, $vNewFunction)
                    Else
                        DllStructSetData($tFunctionOffset, 1, DllCallbackGetPtr(DllCallbackRegister($vNewFunction, $sRet, $sParams)))
                    EndIf
                    Return $pOld
                EndIf
                $iOffset2 += DllStructGetSize($tBufferOffset2)
            WEnd
            ExitLoop
        EndIf
        $pDirectoryOffset += 20 ; size of $tIMAGE_IMPORT_MODULE_DIRECTORY
    WEnd
    Return SetError(4, 0, 0)
EndFunc   ;==>_AddHookApi

Func _VirtualProtect($pAddress, $iSize, $iProtection)
    Local $aCall = DllCall("kernel32.dll", "bool", "VirtualProtect", "ptr", $pAddress, "dword_ptr", $iSize, "dword", $iProtection, "dword*", 0)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return 1
EndFunc   ;==>_VirtualProtect

Func _GetModuleHandle($vModule = 0)
    Local $sParamType = "ptr"
    If IsString($vModule) Then $sParamType = "wstr"
    Local $aCall = DllCall("kernel32.dll", "ptr", "GetModuleHandleW", $sParamType, $vModule)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return $aCall[0]
EndFunc   ;==>_GetModuleHandle

 

..something that has many other function in the function that is excluded, will exclude a bunch of them too in the /rm case.

Again, I or anyone, can edit AutoIt3Wrapper and do anything. The "passing function names as strings is only calling for trouble" part, I don't know, how should I do different in the case of this function ?

[argumentum]

...I guess I am missing something @jchd, thanks  

[MrCreatoR]

You also could do something like this:

 

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Run_Before=%autoitdir%\AutoIt3.exe "%in%" /AddFuncName
#Au3Stripper_Parameters=/rm
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

If $CmdLine[0] And StringInStr($CmdLineRaw, '/AddFuncName') Then
    $sRead = FileRead(@ScriptFullPath)
    $sRead = StringRegExpReplace($sRead, '(?mi)^((?:Volatile\h+)?\h*Func\h+)(\w+)([^\r\n]+)(?:\r?\n\t+Local Const \$FuncName = "\w+")?', '\1\2\3' & @CRLF & @TAB & 'Local Const $FuncName = "\2"')
    
    $hFile = FileOpen(@ScriptFullPath, 2)
    FileWrite($hFile, $sRead)
    FileClose($hFile)
    
    Exit
EndIf

Func Func1($sVar)
    ;Func1 stuff
EndFunc

Func Func2($sVar1, $sVar2)
    ;Func2 stuff
EndFunc

 

[jchd]

O I see now. That's because DllCallbackRegister() and possibly friends require a function name as a string and not as a function.

That's a defect in these function! If not already done, opening a Trac ticket to this effect would be a good idea while Jon is working on AutoIt.

[argumentum]

 

5 minutes ago, jchd said:

while Jon is working on AutoIt

...I wanted to see if, given that he is looking at the code right now, the idea was sound and easy to just add the macro.

As far as the DllCallbackRegister() ticket, I would not be able to defend the point if I had to, so ..., if you could present it in the ticket system, it would have a better future than if I did.

Edited May 19, 2020 by argumentum

[jchd]

Depends on what others think.  I for one have no use of AutoIt for my daily job ans it's been ages I've not used DllCallbackRegister and I never used Au3Stripper. So my point of view is rather moot.

[argumentum]

The Au3Stripper makes a smaller executable. The fact that you are in this forum now is that you are fond of AutoIt. You have a set of skills that may come in useful right now and if there is no great opposition, a compelling presentation can bring in a world of opportunities. Now if this is not possible due time or real life constrains, then that is that.
I for once, don't have the know how to request a change, as again, could not defend the point.

I guess there is a MVP forum, where ideas can be posted and a pool, would determine, yay or nay  

[jchd]

Posted to the MVP forum.

[argumentum]

your example of the use of FuncName(), gave me a clue. Thanks to that I've found a way to eat my cake and have it too implement it

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/rm
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; https://www.autoitscript.com/forum/topic/143250-grab-runtime-errors-when-script-is-run-from-a-service/?tab=comments#comment-1009391

;Global $f__Intercept_MessageBoxW = FuncName(_Intercept_MessageBoxW) ; <--- pointer by jchd

If @Compiled Then _AddHookApi("user32.dll", "MessageBoxW", FuncName(_Intercept_MessageBoxW), "int", "hwnd;wstr;wstr;uint")
Func _Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)
    If $sTitle = "AutoIt Error" Then
;~      ; For example:
;~      ConsoleWriteError($sTitle & " " & $sText & @CRLF)
;~  Else
        Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
                "hwnd", $hWnd, _
                "wstr", "My " & $sText, _
                "wstr", "My " & $sTitle, _
                "uint", $iType)
        If @error Or Not $aCall[0] Then Return 0
        Return $aCall[0]
    EndIf
EndFunc   ;==>_Intercept_MessageBoxW
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Let's try it (don't forget to compile)
; Usual message box
MsgBox(0, 'Test', 'Some text')
; Cause array error
Global $aArray[3] = [1, 2, 3]
$aArray[4] = 4 ; !!!!



Func _AddHookApi($sModuleName, $vFunctionName, $vNewFunction, $sRet = "", $sParams = "")
    ; $vNewFunction = String($vNewFunction) <-- not needed
    Local Static $pImportDirectory, $hInstance
    If Not $pImportDirectory Then
        $hInstance = _GetModuleHandle()
        If @error Then Return SetError(1, 0, 0)
        Local $aCall = DllCall("dbghelp.dll", "ptr", "ImageDirectoryEntryToData", _
                "handle", $hInstance, _
                "boolean", 1, _ ; as an image
                "word", 1, _ ; IMAGE_DIRECTORY_ENTRY_IMPORT
                "dword*", 0)
        If @error Or Not $aCall[0] Then Return SetError(2, 0, 0)
        $pImportDirectory = $aCall[0]
    EndIf
    Local $iIsInt = IsInt($vFunctionName)
    Local $iRestore = Not IsString($vNewFunction)
    Local $tIMAGE_IMPORT_MODULE_DIRECTORY
    Local $pDirectoryOffset = $pImportDirectory
    Local $tModuleName
    Local $iInitialOffset, $iInitialOffset2
    Local $iOffset2
    Local $tBufferOffset2, $iBufferOffset2
    Local $tBuffer, $tFunctionOffset, $pOld, $fMatch
    Local Const $PAGE_READWRITE = 0x04
    While 1
        $tIMAGE_IMPORT_MODULE_DIRECTORY = DllStructCreate("dword RVAOriginalFirstThunk;" & _
                "dword TimeDateStamp;" & _
                "dword ForwarderChain;" & _
                "dword RVAModuleName;" & _
                "dword RVAFirstThunk", _
                $pDirectoryOffset)
        If Not DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk") Then ExitLoop
        $tModuleName = DllStructCreate("char Name[64]", $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAModuleName"))
        If DllStructGetData($tModuleName, "Name") = $sModuleName Then ; function from this module
            $iInitialOffset = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk")
            $iInitialOffset2 = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAOriginalFirstThunk")
            If $iInitialOffset2 = $hInstance Then $iInitialOffset2 = $iInitialOffset
            $iOffset2 = 0
            While 1
                $tBufferOffset2 = DllStructCreate("dword_ptr", $iInitialOffset2 + $iOffset2)
                $iBufferOffset2 = DllStructGetData($tBufferOffset2, 1)
                If Not $iBufferOffset2 Then ExitLoop
                If $iIsInt Then
                    If BitAND($iBufferOffset2, 0xFFFFFF) = $vFunctionName Then $fMatch = True ; wanted function
                Else
                    $tBuffer = DllStructCreate("ushort Ordinal; char Name[64]", $hInstance + $iBufferOffset2)
                    If DllStructGetData($tBuffer, "Name") == $vFunctionName Then $fMatch = True ; wanted function
                EndIf
                If $fMatch Then
                    $tFunctionOffset = DllStructCreate("ptr", $iInitialOffset + $iOffset2)
                    _VirtualProtect(DllStructGetPtr($tFunctionOffset), DllStructGetSize($tFunctionOffset), $PAGE_READWRITE)
                    If @error Then Return SetError(3, 0, 0)
                    $pOld = DllStructGetData($tFunctionOffset, 1)
                    If $iRestore Then
                        DllStructSetData($tFunctionOffset, 1, $vNewFunction)
                    Else
                        DllStructSetData($tFunctionOffset, 1, DllCallbackGetPtr(DllCallbackRegister($vNewFunction, $sRet, $sParams)))
                    EndIf
                    Return $pOld
                EndIf
                $iOffset2 += DllStructGetSize($tBufferOffset2)
            WEnd
            ExitLoop
        EndIf
        $pDirectoryOffset += 20 ; size of $tIMAGE_IMPORT_MODULE_DIRECTORY
    WEnd
    Return SetError(4, 0, 0)
EndFunc   ;==>_AddHookApi

Func _VirtualProtect($pAddress, $iSize, $iProtection)
    Local $aCall = DllCall("kernel32.dll", "bool", "VirtualProtect", "ptr", $pAddress, "dword_ptr", $iSize, "dword", $iProtection, "dword*", 0)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return 1
EndFunc   ;==>_VirtualProtect

Func _GetModuleHandle($vModule = 0)
    Local $sParamType = "ptr"
    If IsString($vModule) Then $sParamType = "wstr"
    Local $aCall = DllCall("kernel32.dll", "ptr", "GetModuleHandleW", $sParamType, $vModule)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return $aCall[0]
EndFunc   ;==>_GetModuleHandle

..and now compiles just fine. 

Edited May 19, 2020 by argumentum
better code

[mLipok]

Recent change in Au3Stripper /rsln   .... releated to @ScriptLineNumber is enought replacement for @FuncName.
@FuncName will be uselles when you use Au3Stripper with /RM but @ScriptLineNumber will still fit the needs.

 

[argumentum]

"thinking does not hurt, ........ .......... but it takes time", lol, I like that.
Sharing may hurt but it brings about knowledge and solutions. It never occur to me to use FuncName() the way I did without sharing ( for my benefit ) and that knowing would not let me ask for the requested macro, but it also brought about DllCallbackRegister() incongruencies in reference to the language's(AutoIt) growth ( for the benefit of all ), so, ...sharing is good, annoying at times, but good overall.
I never meant to use the @FuncName for debugging as @ScriptLineNumber is all that is needed along with the error type ( in my view ), but I guess it could be used for that too, but then again, what line in the function. So, no, not for debugging.

So to wrap it up: 
Static was not in previous versions but it came to exist and is handy to have.
@FuncName would be complementary/related to @NumParams, if it existed. That's all.