_DateIsValid() is returning false positives

[RedZone]

Please forgive if there is already a topic regarding this issue, however I could not find one.

It seems that the _DateIsValid function can return 1(Valid) even when the date is not valid. I am using the latest releases of Autoit and SciTE

Example of 3 non-valid dates:
 

#include <Date.au3>
Local $checkDate, $aDateExamples[3]
$aDateExamples[0] = "rrrr/rr/rr 05:23:09"
$aDateExamples[1] = "2007/12/12 rr:rrfrr"
$aDateExamples[2] = "2007/12/08 rrfrrfrr"

For $i = 0 To UBound($aDateExamples) - 1
    $checkDate = _DateIsValid($aDateExamples[$i])
    If $checkDate = 0 Then
        $checkDate = "Not Valid"
    Else
        $checkDate = "Valid"
    EndIf
    ConsoleWrite($aDateExamples[$i] & " returns: " & $checkDate & @CRLF)
Next

 

I am sure I could check the strings first but I do believe that the _Dateisvalid function does that already.

Any help would be greatly appreciated!

[Jos]

This is indeed a flaw in the current UDF as the _DateTimeSplit() udf assumes this date has the "yyyy/mm/dd hh:mm" format and for the hh=rr and mm=rrfrr, the INT() is taken which is 0, so it "thinks" the time is 00:00.

Jos

[Jos]

...I am actually pretty sure somebody could come up with a regex that does this test, which weren't available at the time I wrote these under my alias JdeB.  

Jos

[RedZone]

I'm sure there is a better way to do this but this is my work around for this situation

#include <Date.au3>
Local $aDate, $aTime, $verifyNumbersOnly, $checkDate, $aDateExamples[3]
$aDateExamples[0] = "2007/12/12 05:22:09"
$aDateExamples[1] = "2007/12/12 rr:rrfrr"
$aDateExamples[2] = "2007/12/08 rrfrrfrr"

For $i = 0 To UBound($aDateExamples) - 1
    ; Remove "/" and ":" and " " from the string
    $verifyNumbersOnly = StringRegExpReplace($aDateExamples[$i], "[/: ]", "")
    $checkDate = "Not Checked because it's not Int!"
    If StringIsInt($verifyNumbersOnly) Then ;Only check the date if it's doesn't contain letters
        $checkDate = _DateIsValid($aDateExamples[$i])
        If $checkDate = 0 Then
            $checkDate = "Not Valid"
        Else
            $checkDate = "Valid"
        EndIf
    EndIf
    ConsoleWrite($aDateExamples[$i] & " returns: " & $checkDate & @CRLF)
Next

 

[jchd]

Try this:

#include <Date.au3>

Local $aDate
Local $aDateExamples = ["2007/12/12 05:22:09", "2007/12/12 rr:rrfrr", "2007/12/12 rrfrrfrr", "2007/12/12 35:22:09"]
For $i = 0 To UBound($aDateExamples) - 1
    Local $checkDate = "Valid"
    If Not (StringRegExp($aDateExamples[$i], "^\d\d\d\d[/-]\d\d[/-]\d\d \d\d:\d\d:\d\d$") And _DateIsValid($aDateExamples[$i])) Then
        $checkDate = "Not " & $checkDate
    EndIf
    ConsoleWrite($aDateExamples[$i] & " returns: " & $checkDate & @CRLF)
Next

 

Edited May 16, 2020 by jchd

[Deye]

Or like you did it 

just for a note, note that the dateisvalid   works even without expressing the time units after the space in the date but i'm guessing the digits in the date are mandatory for the function to return true

#include <Date.au3>
Local $aDate, $aTime, $verifyNumbersOnly, $checkDate, $aDateExamples[3]
$aDateExamples[0] = "2007/12/12 05:22:09"
$aDateExamples[1] = "2007/12/12 rr:rrfrr"
$aDateExamples[2] = "2007/12/08 rrfrrfrr"

For $i = 0 To UBound($aDateExamples) - 1
    If Not StringRegExp(StringRegExpReplace($aDateExamples[$i], "[/: ]", ""), "\D") And _DateIsValid($aDateExamples[$i]) Then
        $checkDate = "Valid"
    Else
        $checkDate = "Not Valid"
    EndIf
    ConsoleWrite($aDateExamples[$i] & " returns: " & $checkDate & @CRLF)
Next

 

Edited May 16, 2020 by Deye

[RedZone]

55 minutes ago, Deye said:

Or like you did it 

just for a note, note that the dateisvalid   works even without expressing the time units after the space in the date but i'm guessing the digits in the date are mandatory for the function to return true

#include <Date.au3>
Local $aDate, $aTime, $verifyNumbersOnly, $checkDate, $aDateExamples[3]
$aDateExamples[0] = "2007/12/12 05:22:09"
$aDateExamples[1] = "2007/12/12 rr:rrfrr"
$aDateExamples[2] = "2007/12/08 rrfrrfrr"

For $i = 0 To UBound($aDateExamples) - 1
    If Not StringRegExp(StringRegExpReplace($aDateExamples[$i], "[/: ]", ""), "\D") And _DateIsValid($aDateExamples[$i]) Then
        $checkDate = "Valid"
    Else
        $checkDate = "Not Valid"
    EndIf
    ConsoleWrite($aDateExamples[$i] & " returns: " & $checkDate & @CRLF)
Next

 

Yes they were mandatory for the function to return true