How to Add separators between characters

[Zero0]

How can I add delimiters between the characters I set, without any loop?

For example I want it to look like this => ABCD-EF12-3456

$SerialStringExample1 = "ABCDEF123456"
$delimiters1 = StringRegExpReplace($SerialStringExample1, '\w{4}', '-')
MsgBox(0,0, $delimiters1)

$SerialStringExample2 = "ABCDEF123456"
$delimiters2 = StringLeft($SerialStringExample2, 4)
MsgBox(0,0, $delimiters2)

 

[Melba23]

Zero0,

Welcome to the AutoIt forum.

A simple way is to use a RegEx like this:

#include <MsgBoxConstants.au3>
$sSerialStringExample1 = "ABCDEF123456"
$sDelimiters1 = StringRegExpReplace($sSerialStringExample1, "(.{4})(.{4})(.{4})", "$1-$2-$3")
MsgBox($MB_SYSTEMMODAL, "Delimited", $sDelimiters1)

No doubt a RegEx guru will be along shortly to explain why that is not the best way , but it works for me!

M23

[mikell]

$SerialStringExample1 = "ABCDEF123456"
$delimiters1 = StringRegExpReplace($SerialStringExample1, '\w{4}\K(?!$)', '-')
MsgBox(0,0, $delimiters1)

[Melba23]

See, I just knew it would happen!

M23

[mikell]

Well I must admit that your regex is more reliable, because it may return an error if let's say the string is 11 chars long only...

Edited May 15, 2020 by mikell

[Zero0]

7 minutes ago, mikell said:

$SerialStringExample1 = "ABCDEF123456"
$delimiters1 = StringRegExpReplace($SerialStringExample1, '\w{4}\K(?!$)', '-')
MsgBox(0,0, $delimiters1)

@mikell Great sample code, Thank you.
Are there any other examples without the loop? Except StringRegExpReplace.

[mikell]

Oh yes... you can use some kind of pseudo-loop

#include <MsgBoxConstants.au3>
$sSerialStringExample1 = "ABCDEF12345"
$sDelimiters1 = StringLeft($sSerialStringExample1, 4) & "-" & StringMid($sSerialStringExample1, 5, 4) & "-" & StringRight($sSerialStringExample1, 4)
MsgBox($MB_SYSTEMMODAL, "Delimited", $sDelimiters1)

 

[SirAlonne]

Global $Regex, $String = "ABCDEF123456"
Global $Pattern = "^(\w{4})(\w{4})(\w{4})$"         ; ^ <-- beginning of the string ... end of string --> $

For $x = 1 To 2 Step 1
    If $x = 2 Then
        $String &= "5_"
    EndIf
    If StringRegExp($String, $Pattern) Then
        $Regex = StringRegExpReplace($String, $Pattern, "$1" & "-" & "$2" & "-" & "$3")
        MsgBox(0, "Result if string is in the defined format", "String =" & $String & _
        @CRLF & "Result =" & $Regex)
    Else
        MsgBox(0, "Result if not", $String & " does not match.")
    EndIf
Next

 

[mikell]

No need to run it twice to get a valid error checking

$String = "ABCDEF123456"
$new = StringRegExpReplace($String, "^(\w{4})(\w{4})(\w{4})$", "$1-$2-$3")
MsgBox(0, @extended ? "ok" : "error", @extended ? $new : "error" )

 

[FrancescoDiMuro]

Let's wrap it into a function:

#include <StringConstants.au3>

ConsoleWrite(_StringDelimiter("ABCDEFGH123456", 2) & @CRLF)


Func _StringDelimiter($strString, $intNumber)
    Return Mod(StringLen($strString), $intNumber) = 0 ? StringRegExpReplace($strString, '\w{' & $intNumber & '}\K(?!$)', '-') : ''
EndFunc

[SirAlonne]

My point was the definition of the beginning ^ and end $ of the string, without that error cheking is not working.
Anyhow @mikell, nice use of conditional operators there! I did not know that it works inside a message box.

[Gianni]

22 hours ago, Zero0 said:

Are there any other examples without the loop? Except StringRegExpReplace.

... through recursion

MsgBox(0, '', _stringsInsertDelims('ABCDEF123456', 4))

; inserts delimiters after each group of nr. characters and returns the resulting string
Func _stringsInsertDelims($sString, $iGroupsLen = 1, $sDelim = '-')
    If Number($iGroupsLen) < 1 Then Return SetError(1, 0, $sString)
    Local $sSnippt = StringLeft($sString, $iGroupsLen)
    Local $sReminder = StringTrimLeft($sString, $iGroupsLen)
    If $sReminder <> '' Then $sSnippt &= $sDelim & _stringsInsertDelims($sReminder, $iGroupsLen, $sDelim)
    Return $sSnippt
EndFunc   ;==>_stringsInsertDelims

 

Edited May 16, 2020 by Chimp
added 3th parameter in recursion call