How to run a Powershell command and return this result

[Chris66]

I need to add a system information back from a Powershell script.

This is the PowerShell command I need to run:
(Get-CimInstance -Class Win32_OperatingSystem).InstallDate

It will bring back the information then the OS has been installed.
This is an example for the result:
Wednesday, July 31, 2019 6:59:56 AM

My idea was to use this command line in AutoIt:
$sInstallDate = RunWait('powershell.exe -command (Get-CimInstance -Class Win32_OperatingSystem).InstallDate')

The variable $sInstallDate is the target for the result.
I've add the parameter "-noexit" to see what happens. But I can see that only the PowerShell command windows will get opened. It did not show the command.

Any idea how to solve this issue?

 
 

Thanks,
Chris66

[water]

You get this information much faster when using WMI.
Example:

ConsoleWrite("InstallDate (MM/DD/YYYY HH:MM:SS): " & _GetOSInstallDate() & @CRLF)
Exit

Func _GetOSInstallDate()
    Local $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    Local $colItems = "", $strComputer = "."

    Local $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\")
    Local $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_OperatingSystem", "WQL", _
            $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

    If IsObj($colItems) Then
        For $objItem In $colItems
            Return WMIDateStringToDate($objItem.InstallDate)
        Next
    Else
        Return "No WMI Objects Found for class: Win32_OperatingSystem"
    EndIf
EndFunc   ;==>_GetOSInstallDate

Func WMIDateStringToDate($dtmDate)
    Return (StringMid($dtmDate, 5, 2) & "/" & _
            StringMid($dtmDate, 7, 2) & "/" & StringLeft($dtmDate, 4) _
             & " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate, 13, 2))
EndFunc   ;==>WMIDateStringToDate

 

[Chris66]

Hi water,

thanks for this complete solution to my request. It's working fine.
I've not realized that this information is also available via WMI before.
 

Regards,
Christoph

[water]