Get color of a Solid Brush

[Bilgus]

Shamelessly ripped from Raymond @ TheNewOldThing

get the color of a SOLID brush

#include <WinAPIGdi.au3> ;CreateSolidBrush
#include <WinAPIHObj.au3>

Local $hBrush = _WinAPI_CreateSolidBrush(0xFFDEDEFF)

ConsoleWrite("Brush Color = 0x" & Hex(_GetBrushColor($hBrush)) & @CRLF)

_WinAPI_DeleteObject($hBrush)


Func _GetBrushColor($hBrush)
    ;https://devblogs.microsoft.com/oldnewthing/20190802-00/?p=102747
    Local $iErr
    Local Const $BS_SOLID = 0x00000000
    Local Const $tagLogBrush = "uint lbStyle; dword lbColor; ulong_ptr lbHatch"
    Local $tLogBrush = DllStructCreate($tagLogBrush)
    Local $iSzLogBrush = DllStructGetSize($tLogBrush)
    If _WinAPI_GetObject($hBrush, $iSzLogBrush, DllStructGetPtr($tLogBrush)) <> $iSzLogBrush Then
        $iErr = 0x1
    ElseIf DllStructGetData($tLogBrush, "lbStyle") <> $BS_SOLID Then
        $iErr = 0x2
    Else
        Return DllStructGetData($tLogBrush, "lbColor")
    EndIf
    Return SetError($iErr, 0, 0xFFFFFFFF) ;CLR_NONE
EndFunc

 

[Bilgus]

Func GUIStaticCtrlGetBkColor($hWnd)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)
    Local $hWnd_Main = _WinAPI_GetParent ($hWnd)
    Local $hDC = _WinAPI_GetDC($hWnd)
    Local $hBrush = _SendMessage($hWnd_Main, $WM_CTLCOLORSTATIC, $hdc, $hWnd)
    Local $iColor = _GetBrushColor($hBrush)
    _WinAPI_ReleaseDC($hWnd, $hDC)
    Return $iColor
EndFunc

Here is @guinness'  GUICtrlGetBkColor converted to use GetBrushColor()

Edited February 9, 2022 by Bilgus

[Professor_Bernd]

I think there is a typo in the code of the last post:

Local $hBrush = _SendMessage($hWndMain, $WM_CTLCOLORSTATIC, $hdc, $hWnd)

Local $hBrush = _SendMessage($hWnd_Main, $WM_CTLCOLORSTATIC, $hdc, $hWnd)

Thanks for sharing the code!