$GUI_WS_EX_PARENTDRAG and GUICtrlSetOnEvent

[baconaise]

Greetings,

I have a GUI on which are GUICtrlCreateLabels appended with $GUI_WS_EX_PARENTDRAG because I want to be able to use them to click-and-drag my GUI. They used to be buttons, but buttons do not allow for $GUI_WS_EX_PARENTDRAG, so now they are labels masquerading as buttons. These labels, who in their soul are buttons, are invigorated with GUICtrlSetOnEvent, so they do a thing when they are clicked.

My trouble is that when I drag my GUI with one of the GUICtrlCreateLabels, it also activates the GUICtrlSetOnEvent. I want the GUICtrlSetOnEvent to only activate if my click does not drag the GUI.

I tried having the function called by GUICtrlSetOnEvent look at where the GUI is, but it only checks that after I let go of the click, so it doesn't fix it.

Any ideas?

Thanks!

[Melba23]

baconaise,

How about providing a small runnable example script showing the problem so we can see exactly what you are doing - otherwise we risk not reproducing your case correctly.

M23

[baconaise]

#include <GUIConstants.au3>
#include <MsgBoxConstants.au3>
Opt("GUIOnEventMode", 1)

Create_GUI()

While 1
   Sleep(10)
WEnd

Func Create_GUI()
   Global $GUI_Main = GUICreate("Main GUI", 200, 100)
   Global $GUI_Main_Button = GUICtrlCreateLabel("Button", 0, 0, 200, 100, BitOR($SS_CENTERIMAGE, $SS_CENTER, $SS_RIGHTJUST), $GUI_WS_EX_PARENTDRAG)
   GUICtrlSetOnEvent($GUI_Main_Button, "Button_Function")
   GUISetOnEvent($GUI_EVENT_CLOSE, "Exiting_Function")
   GUISetState(@SW_SHOW, $GUI_Main)
EndFunc

Func Button_Function()
   MsgBox($MB_OK,"You did the thing", "I only want the thing done if I didn't use the label/button to drag the GUI")
EndFunc

Func Exiting_Function()
   Exit
EndFunc

 

[BrewManNH]

You should probably be using a Message Handler rather than an OnEvent message. 

[baconaise]

I see your point. What you see is an excerpt of a ~25,000 line script, and other portions rely pretty heavily on the OnEvent functionality. I'd really prefer to find a way to get this to work without trying to rework so much.

[mikell]

Not easy but this might work
BTW declaring global variables inside a func is not nice 

#include <GUIConstants.au3>
#include <MsgBoxConstants.au3>
Opt("GUIOnEventMode", 1)

Create_GUI()

While 1
   Sleep(10)
WEnd

Func Create_GUI()
   Global $GUI_Main = GUICreate("Main GUI", 200, 100)
   Global $GUI_Main_Button = GUICtrlCreateLabel("Button", 0, 0, 200, 100, BitOR($SS_CENTERIMAGE, $SS_CENTER, $SS_RIGHTJUST))    ;, $GUI_WS_EX_PARENTDRAG)
   GUICtrlSetOnEvent($GUI_Main_Button, "Drag")
   GUISetOnEvent($GUI_EVENT_CLOSE, "Exiting_Function")
   GUISetState(@SW_SHOW, $GUI_Main)
EndFunc

Func Drag()
   $pos = WinGetPos($GUI_Main)
   DllCall("user32.dll", "int", "ReleaseCapture")
   DllCall("user32.dll", "int", "SendMessage", "hWnd", $GUI_Main, "int", 0xA1, "int", 2, "int", 0) ;WM_NCLBUTTONDOWN
   Sleep(10)
   $pos2 = WinGetPos($GUI_Main)
   If $pos[0] = $pos2[0] and $pos[1] = $pos2[1] Then Button_Function()
EndFunc

Func Button_Function()
   MsgBox($MB_OK,"You did the thing", "I only want the thing done if I didn't use the label/button to drag the GUI")
EndFunc

Func Exiting_Function()
   Exit
EndFunc

 

[baconaise]

mikell, you are a gentleman and a scholar. Thank you.

[mikell]

Thanks
An other flavour

expandcollapse popup

#include <GUIConstants.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <SendMessage.au3>
Opt("GUIOnEventMode", 1)

Global Const $SC_DRAGMOVE = 0xF012

Create_GUI()

While 1
   Sleep(10)
WEnd

Func Create_GUI()
   Global $GUI_Main = GUICreate("Main GUI", 200, 100)
   Global $GUI_Main_Button = GUICtrlCreateLabel("Button", 0, 0, 200, 100, BitOR($SS_CENTERIMAGE, $SS_CENTER, $SS_RIGHTJUST))    
   GUICtrlSetOnEvent($GUI_Main_Button, "Drag")
   GUISetOnEvent($GUI_EVENT_CLOSE, "Exiting_Function")
   GUISetState(@SW_SHOW, $GUI_Main)
EndFunc

Func Drag()
   $pos = WinGetPos($GUI_Main)
  _SendMessage($GUI_Main, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
   Sleep(10)
   $pos2 = WinGetPos($GUI_Main)
   If $pos[0] = $pos2[0] and $pos[1] = $pos2[1] Then Button_Function()
EndFunc

Func Button_Function()
   MsgBox($MB_OK,"You did the thing", "I only want the thing done if I didn't use the label/button to drag the GUI")
EndFunc

Func Exiting_Function()
   Exit
EndFunc