Problem with comparing values

[jchd]

Count on a myriad of users to find that this will break down the type system and slow down FP unbearably 😄  A  can of worms!

Seriously noone is obliged to use FP, so if you intent an exact computation, use an exact decimal format. If otherwise you can be satisfied by a (close) approximation, use FP as much as you can and deal with it's slight inacuracies.

[argumentum]

...a while back I found myself with the same question and got the same answer you gave, so I now know that use only integers but most of the ppl coding scripts have no clue of the "magic" in the hardware it all runs on. 😅

And thank for your answers, as they are properly backed up. Quite educational.

[mLipok]

11 hours ago, TheXman said:

When comparing floating point values for equality, it is best to make sure that they are both rounded to the same decimal place.  $bTesting1 was not rounded.

So not only the components of the mathematical equation should be rounded but also the result.

Solution is:

_Example()

Func _Example()
    Local $sKwota_Naliczona = _String_AsRounded_Number('6.05')
    Local $sKwota_Pobrana_Wczesniej = 0.00
    Local $sKwota_Pobieram = _String_AsRounded_Number('4.19')
    Local $sKwota_Do_Pobrania = _String_AsRounded_Number('1.86')
;~  Local $bTesting_1 = $sKwota_Naliczona - $sKwota_Pobrana_Wczesniej - $sKwota_Pobieram
    Local $bTesting_1 = _String_AsRounded_Number($sKwota_Naliczona - $sKwota_Pobrana_Wczesniej - $sKwota_Pobieram)
    Local $bTesting__A = ($bTesting_1 = $sKwota_Do_Pobrania)
    Local $bTesting__B = ($bTesting_1 == $sKwota_Do_Pobrania)
    ConsoleWrite( _
            'Test pobrania kosztu - ' & $bTesting__A & ' / ' & $bTesting__B & _
            ' ( testowano: ' & $sKwota_Naliczona & ' - ' & $sKwota_Pobrana_Wczesniej & ' - ' & $sKwota_Pobieram & ' = ' & $sKwota_Do_Pobrania & ' )' _
             & @CRLF)
EndFunc   ;==>_Example

Func _String_AsRounded_Number($sData)
    Return Round(Number(StringReplace($sData, ",", ".")), 2)
EndFunc   ;==>_String_AsRounded_Number

 

[jchd]

Your _String_AsRounded_Number() function serves no real purpose. To wit:

Local $v = _String_AsRounded_Number('6.05')
ConsoleWrite(VarGetType($v) & @TAB & '0x' & Hex($v) & @LF)
ConsoleWrite(VarGetType(6.05) & @TAB & '0x' & Hex(6.05) & @LF)

Func _String_AsRounded_Number($sData)
    Return Round(Number(StringReplace($sData, ",", ".")), 2)
EndFunc   ;==>_String_AsRounded_Number

You see it returns exactly the same double as if you use the literal 6.05 value.

The equality operator = compares the variables as they are, that is double FP values in this case, which differ by one ULP as I previously showed.

OTOH the == operator first converts both doubles to string (and that's where the decimal rouding occurs). That's why the strings are equal because of the double to string conversion. Here's another example, where AutoIt (like almost all languages) is kind enough to round values to what you are likely to expect:

ConsoleWrite('0x' & Hex(6.0499999999999988) & @TAB & 6.0499999999999988 & @LF)
ConsoleWrite('0x' & Hex(6.05) & @TAB & 6.05 & @LF)
ConsoleWrite('0x' & Hex(6.0500000000000009) & @TAB & 6.0500000000000009 & @LF)

The 3 values are clearly different but their conversion to string all show "6.05".
You also can check that the 3 double values compare correctly even if their rounded string representation are exactly the same:

ConsoleWrite((6.0499999999999988 < 6.05) & @TAB & (6.05 < 6.0500000000000009) & @LF)

 

[jchd]

Final example to show how increasing values of a double around the value 6.05 translate once converted to string by the default AutoIt conversion:

Local $t = DllStructCreate("double")
Local $u = DllStructCreate("int64", DllStructGetPtr($t))
DllStructSetData($t, 1, 6.05)

Local $x = DllStructGetData($u, 1)

For $i = -20 To 20
    DllStructSetData($u, 1, $x + $i)
    ConsoleWrite('0x' & Hex(DllStructGetData($t, 1)) & @TAB & DllStructGetData($t, 1) & @LF)
Next

 

[mLipok]

33 minutes ago, jchd said:

that is double FP values in this case, which differ by one ULP as I previously showed.

OTOH the == operator

what mean
FP
ULP
OTOH

please expand these shortcuts.

 

[jchd]

FP = Floating point

ULP = Unit in the Last Place = least significant bit of a FP value in it's binary representation

OTOH = On The Other Hand