HotKeySet("^{NUMPAD7}) does not release Ctrl

[jackhab]

Hi
I created  a shortcut to send my email address:
 

HotKeySet("^{NUMPAD7}", "SendEmail")
Func SendEmail()
    Send("address@gmail.com")
EndFunc

I have an issue with Ctrl not releasing after pressing CtrlNum7, the text got sent but keyboard behaves as if I'm still holding Ctrl.

I tried to add Opt("SendKeyDelay", 50), and Sleep() before sending the text but it did not help.

So what am I doing wrong?

[Guest]

It works for me, when i increase the Sleep inside _SendEmail()

HotKeySet("^{NUMPAD7}", "_SendEmail") ; NUMLOCK must be on
HotKeySet("{ESC}", "_Exit")
While True
    Sleep(100)
WEnd

Func _SendEmail()
    Sleep(250) ; <=== 
    Send("address@gmail.com")
    ConsoleWrite(@CRLF & "+ >>> Send('address@gmail.com')" & @CRLF)
EndFunc

Func _Exit()
    ConsoleWrite("! Terminated" & @CRLF)
    Exit
EndFunc

[Nine]

Better use this :

#include <Misc.au3>

HotKeySet("^{NUMPAD7}", "_SendEmail") ; NUMLOCK must be on
HotKeySet("{ESC}", "_Exit")
While True
    Sleep(100)
WEnd

Func _SendEmail()
    While _IsPressed ("11")
        Sleep (100)
    WEnd
    Send("address@gmail.com")
    ConsoleWrite(@CRLF & "+ >>> Send('address@gmail.com')" & @CRLF)
EndFunc

Func _Exit()
    ConsoleWrite("! Terminated" & @CRLF)
    Exit
EndFunc

 

[jackhab]

Great! _IsPressed is, indeed, the way to prevent "sticky" Ctrl. Thanks.