_GUICtrlEdit_AppendText freezes gui

[Melba23]

TheAutomator,

I thought that you were happy with the suggested solution posted by AutoBert, so I put this on the back burner - I now see that you are not. But real life has been rather demanding of my time lately - I should have some time to look at it again later this week.

M23

[Nine]

Ok found the problem.  To solve it, follow those steps :

1- copy the UDF GuiEdit.au3 from the AutoIt\Include to your script folder

2- rename it GUIEditEX.au3

3- remove the read only property of the file

4- edit the file and replace in the Func _GUICtrlEdit_AppendText : _SendMessage by _SendMessageA

5- save the file

6- replace in your script the #include <GUIEdit.au3> by #include "GUIEditEX.au3"

7- run your script

8- enjoy

 

Tested both on win7 and win10

Edited February 9, 2020 by Nine

[TheAutomator]

19 hours ago, Melba23 said:

TheAutomator,

I thought that you were happy with the suggested solution posted by AutoBert, so I put this on the back burner - I now see that you are not. But real life has been rather demanding of my time lately - I should have some time to look at it again later this week.

M23

Yes, i replied to fast on him..
Thanks for taking your time to look back at it

Regards,

TheAutomator

[TheAutomator]

Nine,

Nice! Gonna test this when I'm home from work

EDIT -> after testing:

It seems to behave strange now, doesn't append some characters anymore:

Global $clear = False
func WRITE($message)
    if $clear then
        $clear = False
    else
        _guictrledit_appendtext($console, '>>>' & @crlf) ; only types '>', no crlf also...
    endif
    ADD($message)
endfunc

Regards,
TheAutomator

Edited February 10, 2020 by TheAutomator

[Nine]

Replace the func in GUIEditEX.au3 with this code :

Func _GUICtrlEdit_AppendText($hWnd, $sText)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    Local $iLength = _GUICtrlEdit_GetTextLen($hWnd)
    _GUICtrlEdit_SetSel($hWnd, $iLength, $iLength)
    Local $tString = DllStructCreate ("char[" & StringLen ($sText)+1 & "]")
    DllStructSetData ($tString, 1, $sText & chr (0))

    _SendMessageA($hWnd, $EM_REPLACESEL, True, DllStructGetPtr($tString), 0, "wparam", "lparam")
EndFunc   ;==>_GUICtrlEdit_AppendText

 

[Zedna]

I played with this problem too and tried this workaround but the result was the same, so this "fix" doesn't work, just for info here:

Func _GUICtrlEdit_AppendText($hWnd, $sText)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    Local $sOrig = _GUICtrlEdit_GetText($hWnd)
    _GUICtrlEdit_SetText($hWnd, $sOrig & $sText)
EndFunc   ;==>_GUICtrlEdit_AppendText2

 

Edited February 10, 2020 by Zedna

[Nine]

Seems my last patch is working well.  Tested with multiple text lengths including those of OP, both on Win7 and Win10.  No flaw so far,..

[TheAutomator]

17 hours ago, Nine said:

Seems my last patch is working well.  Tested with multiple text lengths including those of OP, both on Win7 and Win10.  No flaw so far,..

For now it seems to work well, thanks for that!
What did you do exactly? i see sendmessageA and dllcalls getting involved? 🤔

[EDIT]

Bad news.. 😕
I was tinkering around with it and suddenly the gui froze again while appending some text...

I don't know exactly what text it was, it was a test using random strings from a file.

Regards,
TheAutomator

Edited February 11, 2020 by TheAutomator

[TheAutomator]

write(FileRead(@ScriptDir & '\a.txt'))
GUICtrlSetData($console, '')
$clear = True
add(FileRead(@ScriptDir & '\a.txt'))
read()
write('[[[done]]]')

ergljnemr negn mqegnmqe ,
regergnoaerngpoaergn
ergojnaeoge on on on o n o  
 
  ergergae
  
ergaergk.

ergraeg5457erg758,,;7,9:87
$^m$tgmù^µrsgm^$
^ergml^qpgregre;gg

ergk,nqerpginjo^qerhg oirheo h oubh eborgu 
erognq^oi o  oinoi no no in oi   o negq
geogpe

gqeporgjpaegjpârgje^ùpargee,
a
b
v
c
x
w
e1
12
123
12364
123456465
47879
8798798798798
.
azzerttyuuiipp12345798

example of the script part i used for testing + text file called 'a.txt'

Edited February 11, 2020 by TheAutomator

[Nine]

Seems there is some kind of a bug in Win10.  It may be related to the previous one, but I didn't test it.  Someone should report it to MicroSoft.

Anyway, I think I have found a workaround.  You must use the patch that I made and change your function to this :

Func ADD($message)
  Local $char
  For $i = 1 To StringLen($message)
    $char = StringMid($message, $i, 1)
    If Asc ($char) = 13 Then $char &= @LF
    If Asc ($char) = 10 Then ContinueLoop
    _GUICtrlEdit_AppendText($console, $char)
    Sleep(50)
  Next
EndFunc   ;==>ADD

The message gets stuck from time to time when @CR is sent alone. 

I will let @Melba23 decide how he would like to manage it.

[TheAutomator]

Alright, thanks for the effort Nine

[Melba23]

TheAutomator,

As promised I have been playing around with this problem again over the past few days and have not changed my original conclusion (see my earlier post) that the problem seems to arise after clearing the edit using GUICtrlSetData and then trying to use _GUICtrlEdit_AppendText to add text which includes @CR characters. if you do this the script freezes at some indeterminate (as far as I can see) instance of a @CR within the new text being appended - although the freeze is repeatable at the same point for a given text.  This appears only to be a problem when using Win 10 - so like Nine I suspect that a subtle change within the editbox implementation has caused this, but I have no idea just what.

I have played about with various ways of emptying the editbox before appending the new text - such as not mixing native and UDF functions (often a recipe for disaster) and using _GUICtrlEdit_SetSel and _GUICtrlEdit_ReplaceSel to clear the edit - but the only reliable way to avoid the problem seems to be to delete and recreate the entire control - which might appear a bit of an overkill but does at least seem to resolve the problem:

expandcollapse popup

#include <guiconstantsex.au3>
#include <buttonconstants.au3>
#include <windowsconstants.au3>
#include <guiedit.au3>

Opt("TrayIconDebug", 1)

HotKeySet('{esc}', 'quit')

Const $form = GUICreate('TypingError', 600, 400) ;, Default, Default, BitOR($gui_ss_default_gui, $ws_maximizebox, $ws_sizebox, $ws_thickframe, $ws_tabstop))
$console = GUICtrlCreateEdit('loading...', 10, 10, 581, 341, BitOR($es_autovscroll, $es_readonly, $es_wantreturn, $ws_vscroll)) ;, 0)
Const $user = GUICtrlCreateInput('', 10, 360, 521, 30) ; , Default, 0)
Const $send = GUICtrlCreateButton('send', 540, 360, 51, 31, BitOR($es_uppercase, $bs_defpushbutton, $ws_disabled))

GUISetState(@SW_SHOW)

Global $clear = False

write(FileRead(@ScriptDir & '\a.txt'))
$clear = True
write(FileRead(@ScriptDir & '\a.txt'))
read()
write('[[[done]]]')

Func WRITE($message)
    If $clear Then
        ; Delete existing edit control and recreate a new empty one <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        GUICtrlDelete($console)
        $console = GUICtrlCreateEdit('', 10, 10, 581, 341, BitOR($es_autovscroll, $es_readonly, $es_wantreturn, $ws_vscroll))
        $clear = False
    Else
        _GUICtrlEdit_AppendText($console, @CRLF)
    EndIf
    ADD($message)
EndFunc   ;==>WRITE

Func ADD($message)
    For $i = 1 To StringLen($message)
        Sleep(50)
        _GUICtrlEdit_AppendText($console, StringMid($message, $i, 1))
    Next
EndFunc   ;==>ADD

Func READ()
    GUICtrlSetState($send, $gui_enable)
    While 1
        Switch GUIGetMsg()
            Case $gui_event_close
                Exit
            Case $send
                GUICtrlSetState($send, $gui_disable)
                Local $answer = GUICtrlRead($user)
                GUICtrlSetData($user, '')
                Return $answer
        EndSwitch
    WEnd
EndFunc   ;==>READ

Func QUIT()
    WRITE("goodbye...")
    Exit
EndFunc   ;==>QUIT

Sorry that I cannot yet pin the problem down any closer - and that we need to use such an inelegant workaround. I will keep poking away at the problem and see if anything new comes up.

M23

Edit: Just to add that amending the _AppendText function did not work for me at all.

Edited February 14, 2020 by Melba23

[Melba23]

TheAutomator,

The Devs have looked into the problem and, as Nine and I reported, it appears that Win 10 edit controls do not like having single @CR characters passed to them - so we can put this problem down to MS and not AutoIt.

To enable you to use the _GUICtrlEdit_AppendText function we suggest using something like this:

Func ADD($message)
    For $i = 1 To StringLen($message)
        Sleep(50)
        ; Look for @CR and @LF
        If StringMid($message, $i, 1) = @CR Or StringMid($message, $i, 1) = @LF Then
            ; If @CR then check it is followed by @LF and send @CRLF in one call and pass over the trailing @LF         
            If StringMid($message, $i, 2) = @CRLF Then $i += 1
            _GUICtrlEdit_AppendText($console, @CRLF)
        Else
            _GUICtrlEdit_AppendText($console, StringMid($message, $i, 1))
        EndIf
    Next
EndFunc   ;==>ADD

That works for us on all the examples you posted.

We will now consider whether we need to adjust the Help file to reflect this new behaviour of the edit control under Win 10.

M23

[mLipok]

@Melba23 would this following example will fit the same feature:

Func ADD($message)
    _GUICtrlEdit_AppendText($console, StringRegExpReplace($message, '\R', @CRLF) & @CRLF)
EndFunc   ;==>ADD

?

[Nine]

@mLipok No. OP wants to send single char at a time, like those typewriters way back. The problem is not to send a message containing @CR alone.  The problem is to send this single char @CR with a delay before sending his buddy @LF.

[mLipok]

Thanks for clarifing.

[TheAutomator]

Nine, Melba23,

Thanks a lot for your help!
I will use this workaround, hopefully w10 will get rid of this bug in a future update..

Regards

TheAutomator