A better pattern (SRER)

[Deye]

@trying to replace the "C:\EEC\"  if its to be the $sSearch instance

with the others it mostly works .. 

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC\' & @CRLF & _
        'C:\MSfree\' & @CRLF

$sSearch = "C:\MSfree"
;~ $sSearch = "C:\EEC"

$sOutput = StringRegExpReplace($Paths, "(\Q" & $sSearch & "\E\R)|(\Q" & $sSearch & "\E\\\R)", "")

MsgBox("", "", $sOutput)

Thanks

Deye

[iamtheky]

Fun SRER problem aside, if you want a literal replacement what edge cases are preventing you from just using stringreplace?

something like:

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC\' & @CRLF & _
        'C:\MSfree\' & @CRLF

;~ $sSearch = "C:\MSfree\"
$sSearch = "C:\EEC\"

$sOutput = stringstripws(StringReplace($Paths, $sSearch , "") , 4)

MsgBox("", "", $sOutput)

 

Edited December 29, 2019 by iamtheky

[Deye]

 if $Paths has  a line that contains "C:\MSfree\someother file" Then _stingreplace will leave me with a line of "\someother file"  .etc

also i may have the search instance with\out "\" to the end

maybe  something that braces a pattern at first can do the job: ?

$sPattern = "(" & StringReplace(StringRegExpReplace($sSearch, "[][$^.{}()+\\\-:]", "\\$0"), "*", ".*?") & "\\\R)" ;& "$"

Still didn't  get it to work as yet ..

Edited December 29, 2019 by Deye

[Deye]

not sure how will this work with other unknown cases of file names but this does it for now :  can turn messy later ..

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC\' & @CRLF & _
        'C:\MSfree\' & @CRLF

$sSearch = "C:\EEC\"
$sPattern = "(?:" & StringReplace(StringRegExpReplace($sSearch, "[][$^.{}()+\\\-:]", "\\$0"), "*", ".*?") ;& "$"
$sOutput = StringRegExpReplace($Paths, $sPattern  & "\R)|" & $sPattern & "\\\R)", "")

MsgBox("", "", $sOutput)

 

Edited December 29, 2019 by Deye

[iamtheky]

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC\someotherfolder\' & @CRLF & _
        'C:\MSfree\' & @CRLF


$sSearch = "C:\EEC\"
;~ $sSearch = "C:\MSfree\"


$sOutput = StringRegExpReplace($Paths , stringreplace($sSearch , "\" , "\\") & ".*\R" , "")

MsgBox("", "", $sOutput)

maybe just ensuring the backslashes are double-upped within the regex?

Edited December 29, 2019 by iamtheky

[Deye]

 basically if "C:\EEC (1)" doesn't  exist in a longer version like  "C:\EEC (1)\someother file" then it needs to be removed

I will need to pay attention on to how the If StringRegExp($Paths, $sPattern & "\\)+[\w\d_]") should  work -  to detect if there are longer lines of the search instance

if there aren't any only then should the instance get removed

 

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC (1)\' & @CRLF & _
        'C:\EEC (1)\someother file' & @CRLF & _
        'C:\MSfree\' & @CRLF
$sSearch = "C:\EEC (1)"

$sPattern = "(?:" & StringReplace(StringRegExpReplace($sSearch, "[][$^.{}()+\\\-:]", "\\$0"), "*", ".*?")

If StringRegExp($Paths, $sPattern & "\\)+[\w\d_]") Then
Else
    $sOutput = StringRegExpReplace($Paths, $sPattern & "\R)|" & $sPattern & "\\\R)", "")
    MsgBox("", "", $sOutput)
EndIf

 

[iamtheky]

more fun than i had gathered...

i'd probably use stringreplace to test the number of times it appears, then act off the value in extended

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC (1)\' & @CRLF & _
        'C:\EEC (1)\someother file' & @CRLF & _
        'C:\MSfree\' & @CRLF

$sSearch = "C:\EEC (1)\"
stringreplace($Paths , $sSearch , $sSearch)

$sOutput = @Extended = 1 ? StringStripWS(stringreplace($Paths , $sSearch , "") , 4) : @Extended & " matches for: " & $sSearch

MsgBox("", "", $sOutput)

 

Edited December 29, 2019 by iamtheky

[Deye]

Thanks iamtheky

I will give it a little more time to see what else crept s up with later on tests

[Malkey]

8 hours ago, Deye said:

 basically if "C:\EEC (1)" doesn't  exist in a longer version like  "C:\EEC (1)\someother file" then it needs to be removed ..

....

Here are two methods to literalize metacharacters in the $sSearch variable. Either using "\Q...\E", or, escaping all metacharacters.

expandcollapse popup

#include <Array.au3>

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC (1)\someother file' & @CRLF & _
        'C:\MSfree\' & @CRLF & _
        'C:\EEC (1)\'
Local $sSearch = "C:\EEC (1)"

; --------------------- Method 1 ----------------------------------
; Check if "\E" is in $sSearch.  If "\E" is present, replace "\E" with "\E\\E\Q",  because of the "\Q" & $sSearch & "\E" in RE pattern.
Local $sSearchA = (StringInStr($sSearch, "\E") ? StringReplace($sSearch, "\E", "\E\\E\Q") : $sSearch)
;ConsoleWrite("\Q" & $sSearchA & "\E" & @CRLF)
Local $a = StringRegExp($Paths, "(\Q" & $sSearchA & "\E.*)", 3)
_ArraySort($a)
;_ArrayDisplay($a)
If UBound($a) > 1 Then
    For $i = 1 To UBound($a) - 1 ; Keep $a1[0]
        $sSearchB = (StringInStr($a[$i], "\E") ? StringReplace($a[$i], "\E", "\E\\E\Q") : $a[$i])
        ;ConsoleWrite("\Q" & $sSearchB & "\E" & @CRLF)
        Local $sOutput = StringRegExpReplace($Paths, "(\Q" & $sSearchB & "\E\R?)", "")
    Next
Else
    Local $sOutput = StringRegExpReplace($Paths, "(\Q" & $sSearchA & "\E.*\R?)", "")
EndIf
MsgBox(0, "\Q...\E", $sOutput)

; Or

; --------------------- Method 2 ----------------------------------
; Beware "(1)" = (n) - Tests whether the capturing group with absolute number n matched.
$sSearch = StringRegExpReplace($sSearch, "([\\()\.^$|\[\]{}*+?#])", "\\$1")
;ConsoleWrite($sSearch & @CRLF)

Local $a1 = StringRegExp($Paths, "(" & $sSearch & ".*)", 3)
_ArraySort($a1)
;_ArrayDisplay($a1)
If UBound($a1) > 1 Then
    For $i = 1 To UBound($a1) - 1 ; Keep $a1[0]
        $sSearchC = StringRegExpReplace($a1[$i], "([\\()\.^$|\[\]{}*+?#])", "\\$1")
        ;ConsoleWrite($sSearchC & @CRLF)
        Local $sOutput = StringRegExpReplace($Paths, "(" & $sSearchC & "\R?)", "")
    Next
Else
    Local $sOutput = StringRegExpReplace($Paths, "(" & $sSearch & ".*\R?)", "")
EndIf
MsgBox(0, "\\,(,)", $sOutput)

#cs ; Both methods return:-
C:\Users\
C:\MSfree\
C:\EEC (1)\
#ce

 

Edited December 30, 2019 by Malkey

[Nine]

That seems to be working fine :

#include <Constants.au3>

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC (1)\someother file' & @CRLF & _
        'C:\MSfree\' & @CRLF & _
        'C:\EEC (1)\' & @CRLF & _
        'C:\EEC (1)\EEC' & @CRLF & _
        'C:\Temp\'
Local $sSearch = "C:\EEC (1)\"
$sSearch = StringReplace($sSearch, "\E", "\E\\E\Q")

MsgBox ($MB_SYSTEMMODAL,"",StringRegExpReplace ($Paths, '(?m)^(\Q' & $sSearch & '\E.*)$\R', ''))

 

[Deye]

Yes, Thanks Malkey that solves the issue to My satisfactory 

[Deye]

Still no relief :

#include <Constants.au3>

Local $Paths = 'H:\Users\' & @CRLF & _
        'H:\EEC (1)\someother file' & @CRLF & _
        'H:\MSfree\' & @CRLF & _
        'H:\QQEC (1)\' & @CRLF & _
        'H:\EEC (1)\EEC' & @CRLF & _
        'H:\Temp\'
Local $sSearch = "H:\"
$sSearch = '\Q' & StringReplace($sSearch, "\E", "\E\\E\Q") & "\E"

MsgBox($MB_SYSTEMMODAL, "", StringRegExpReplace($Paths, $sSearch & ".*\R", ''))
MsgBox($MB_SYSTEMMODAL, "", StringRegExpReplace($Paths, $sSearch & ".*\R", ''))

must i remove them one by one as with Malkey's example ?

Edit:  NM, was getting ahead of my self

Its:

$sSearch = '\Q' & StringReplace($sSearch, "\E", "\E\\E\Q") & "\E"
$Paths = StringRegExpReplace($Paths, $sSearch & ".*\R", '')
MsgBox($MB_SYSTEMMODAL, "", $Paths)
$Paths = StringRegExpReplace($Paths, $sSearch & ".*", '')
MsgBox($MB_SYSTEMMODAL, "", $Paths)

 

Edited January 23, 2020 by Deye

[jguinch]

More simple :

Local $Paths = 'C:\Users\' & @CRLF & _
        'C:\EEC\' & @CRLF & _
        'C:\MSfree\' & @CRLF

$sSearch = "c:\EEC\"

$sOutput = StringRegExpReplace($Paths, "(?i)\Q" & StringLower($sSearch) & "\E\R", "")
MsgBox(0, "", $sOutput)

 

[Deye]

that is true