Copying Specific lines of code from a .txt file and pasting them over lines in another .txt file

[Kruxe]

Hello Everyone,

I am very green when it comes to AutoIT, I have recently started using it to automate a job that i perform using MS Excel and that is working great. Recently I have been faced with a challenge I which i need to copy a specific set of lines from one .txt file and past them, overwriting a specific set of lines in a different .txt file. I honestly have no clue how I can copy the specified lines and transfer them. What functions / commands could I use and how could I lay them out I AutoIT? Any and all help will be appreciated. 

Thanks!

Kruxe

[Nine]

Depends how big are those text files.  If they are not too large, you could use _FileReadToArray to get the source and target files, then modify target array from source lines and copy back to target using _FileWriteFromArray.

[Musashi]

52 minutes ago, Kruxe said:

i need to copy a specific set of lines from one .txt file and past them, overwriting a specific set of lines in a different .txt file.

As @Nine already pointed out, there are several possible approaches. It would be helpful, if you could post two sample texts (source, target). Then we would have an idea what you mean by 'specific set of lines'.

[Kruxe]

5 minutes ago, Musashi said:

As @Nine already pointed out, there are several possible approaches. It would be helpful, if you could post two sample texts (source, target). Then we would have an idea what you mean by 'specific set of lines'.

@Nine, @Musashi

Thank you guys for the quick replies! I attached the 2 files that are part of this process. what I am looking to do is open O8000.txt and copy lines 8-46 then Open O1800.txt and past the lines from O8000 and overwrite lines 22-29 in O1800. Thank you so much for the help guys, I really appreciate it!

O8000.txt O1800.txt

[Nine]

Since files are small, I would go with the array approach. Here something to start you up :

#include <File.au3>
#include <String.au3>

Opt ("MustDeclareVars", 1)

Local $aSource, $aTarget, $aExtract
_FileReadToArray ("O8000.txt",$aSource,$FRTA_NOCOUNT)
_ArrayDisplay ($aSource, "source file")
_FileReadToArray ("O1800.txt",$aTarget,$FRTA_NOCOUNT)
_ArrayDisplay ($aTarget, "before delete")
_ArrayDelete ($aTarget, "21-28")
_ArrayDisplay ($aTarget, "after delete")
$aExtract = _ArrayExtract ($aSource, 7, 45)
_ArrayDisplay ($aExtract,"extracted lines")
Local $sRange = StringTrimRight (_StringRepeat ("21;", UBound ($aExtract)),1)
_ArrayInsert ($aTarget, $sRange, $aExtract)
_ArrayDisplay ($aTarget,"new target")
_FileWriteFromArray ("O1800 New.txt", $aTarget)

 

[Musashi]

@Kruxe : a little additional explanatory note :

_FileReadToArray (..., $FRTA_NOCOUNT) means : the arrays are 0-based ==> Line 1 therefore has the index 0 ! So don't get confused by the fact, that the "line numbers" are 1 smaller .

--> _ArrayExtract ($aSource, 7, 45) ==> your lines 8 - 46 in O8000.txt

--> _ArrayDelete ($aTarget, "21-28") ==> your lines 22 - 29 in O1800.txt

Edited November 25, 2019 by Musashi

[jchd]

2 hours ago, Kruxe said:

a specific set of lines

A pretty vague definition!

If I guess correctly you want to replace a tooling sequence by another one.  Does this do the job?

Local $sToBeCopied = StringRegExpReplace(FileRead("O8000.txt"), "(?s)(.*?\RN1.*?\R)(.*?\RM99\R)(.*)", "$2")
Local $sModified = StringRegExpReplace(FileRead("O1800.txt"), "(?s)(.*?\RN1.*?\R)(.*?\RM50\R(?=\h*\R))(.*)", "$1" & $sToBeCopied & "$3")
FileDelete("O1800_new.txt")
FileWrite("O1800_new.txt", $sModified)

 

[Kruxe]

Holy Cow!!! You guys are awesome!!! Thank you so much for all the help i sincerely appreciate it. As someone that is completely new to AutoIT, it feels really good to know that there is such an great community of people willing to help you learn and grow! I will try all of your examples and see what would work best. Again, thanks a ton!!!