how to enclose strings in quotation marks using a regular expression?

[Gianni]

Hello
if I have a string like in the example below,
is there a regular expression that can surround any "string" (and only strings) within quotes?.
The whole input string is a "constructor" to populate an array so even if an element contains more words (a phrase) it should be considered as a single word (Elton John should be considered a single word and as that quoted as "Elton John")
for example
the following string

[[Elton John,Peter,Sally,123],[1 one 1,2,3,4 four 4]]

should be transformed to this other string

[["Elton John","Peter","Sally",123],["1 one 1",2,3,"4 four 4"]]

Thanks for your help

Here a small script to use as "guinea pig"

#include <Array.au3>

Local $aArray = [["Elton John", "Peter", "Sally", 123],["one 1", 2, 3, "4 four 4"]]
MsgBox(0, "Result", _Array2Json($aArray))

Func _Array2Json($aArray)
    If (Not IsArray($aArray)) Or (UBound($aArray, 0) > 2) Then Return SetError(1, 0, '')
    Local $sOpening, $sClosing
    If UBound($aArray, 0) = 1 Then
        $sOpening = '['
        $sClosing = ']'
    Else
        $sOpening = '[['
        $sClosing = ']]'
    EndIf

    $sOutpt = $sOpening & _ArrayToString($aArray, ",", -1, -1, "],[") & $sClosing

    ;  $sOutpt = ???? how to quote strings ????

    Return $sOutpt
EndFunc   ;==>_Array2Json

 

Edited November 24, 2019 by Chimp

[Jos]

Something like this should do it. It is a updated version of _ArrayToString() - see the comments in the UDF:

expandcollapse popup

#include <Array.au3>

Local $aArray = [["Elton John", "Peter", "Sally", 123], ["one 1", 2, 3, "4 four 4"]]
MsgBox(0, "Result", _Array2Json($aArray))

Func _Array2Json($aArray)
    If (Not IsArray($aArray)) Or (UBound($aArray, 0) > 2) Then Return SetError(1, 0, '')
    Local $sOpening, $sClosing
    If UBound($aArray, 0) = 1 Then
        $sOpening = '['
        $sClosing = ']'
    Else
        $sOpening = '[['
        $sClosing = ']]'
    EndIf


    $sOutpt = $sOpening & _ArrayToString_ex($aArray, ",", -1, -1, "],[") & $sClosing

    ;  $sOutpt = ???? how to quote strings ????

    Return $sOutpt
EndFunc   ;==>_Array2Json

Func _ArrayToString_ex(Const ByRef $aArray, $sDelim_Col = "|", $iStart_Row = -1, $iEnd_Row = -1, $sDelim_Row = @CRLF, $iStart_Col = -1, $iEnd_Col = -1)
    If $sDelim_Col = Default Then $sDelim_Col = "|"
    If $sDelim_Row = Default Then $sDelim_Row = @CRLF
    If $iStart_Row = Default Then $iStart_Row = -1
    If $iEnd_Row = Default Then $iEnd_Row = -1
    If $iStart_Col = Default Then $iStart_Col = -1
    If $iEnd_Col = Default Then $iEnd_Col = -1
    If Not IsArray($aArray) Then Return SetError(1, 0, -1)
    Local $iDim_1 = UBound($aArray, $UBOUND_ROWS) - 1
    If $iStart_Row = -1 Then $iStart_Row = 0
    If $iEnd_Row = -1 Then $iEnd_Row = $iDim_1
    If $iStart_Row < -1 Or $iEnd_Row < -1 Then Return SetError(3, 0, -1)
    If $iStart_Row > $iDim_1 Or $iEnd_Row > $iDim_1 Then Return SetError(3, 0, "")
    If $iStart_Row > $iEnd_Row Then Return SetError(4, 0, -1)
    Local $sRet = ""
    Switch UBound($aArray, $UBOUND_DIMENSIONS)
        Case 1
            For $i = $iStart_Row To $iEnd_Row
                ; Added this logic
                If IsString($aArray[$i]) Then
                    $sRet &= '"' & $aArray[$i] & '"' & $sDelim_Col
                Else
                    $sRet &= $aArray[$i] & $sDelim_Col
                EndIf
            Next
            Return StringTrimRight($sRet, StringLen($sDelim_Col))
        Case 2
            Local $iDim_2 = UBound($aArray, $UBOUND_COLUMNS) - 1
            If $iStart_Col = -1 Then $iStart_Col = 0
            If $iEnd_Col = -1 Then $iEnd_Col = $iDim_2
            If $iStart_Col < -1 Or $iEnd_Col < -1 Then Return SetError(5, 0, -1)
            If $iStart_Col > $iDim_2 Or $iEnd_Col > $iDim_2 Then Return SetError(5, 0, -1)
            If $iStart_Col > $iEnd_Col Then Return SetError(6, 0, -1)
            For $i = $iStart_Row To $iEnd_Row
                For $j = $iStart_Col To $iEnd_Col
                    ; Added this logic
                    If IsString($aArray[$i][$j]) Then
                        $sRet &= '"' & $aArray[$i][$j] & '"' & $sDelim_Col
                    Else
                        $sRet &= $aArray[$i][$j] & $sDelim_Col
                    EndIf
                Next
                $sRet = StringTrimRight($sRet, StringLen($sDelim_Col)) & $sDelim_Row
            Next
            Return StringTrimRight($sRet, StringLen($sDelim_Row))
        Case Else
            Return SetError(2, 0, -1)
    EndSwitch
    Return 1

EndFunc   ;==>_ArrayToString_ex

Jos

Edited November 24, 2019 by Jos

[Gianni]

Thanks @Jos,
it works, you have "exploited" the internal scan of the _ArrayToString () function to search for array elements that contain strings, nice, thank you .

It would also be interesting to have a solution that uses regexp instead of looping all the elements of the array ((even if _ArrayToString does it already)
Thanks

[mikell]

Strictly following the requirements from your example above, this should work ...

$s = "[[Elton John,Peter,Sally,123],[1 one 1,2,3,4 four 4]]"

$res = StringRegExpReplace($s, '\b\d+(?!\h*\w)\b(*SKIP)(*F)|([\w\h]+)', '"$1"')

Msgbox(0,"", $res)

 

[Gianni]

.... it would seem that this solution also works.  (I had no doubts of course ).
very beautiful!

Thanks a lot @mikell

[mikell]

A little (late...) pseudo-explanation
Sometimes it's easier to define first what you don't want to match, then skip/fail it and apply what is needed to the rest 

[jchd]

OTOH if you want to match JSON definitions of its internal structure you can do so explicitely:

Local $sIn = "{[[Elton John, Bonnie & Clyde, Sally, 123],[one 1, 2, 3, 4 four 4]], abc, [7,{a,b,[c,d,3]}]}"
_String2Json($sIn)
MsgBox(0, "Result", $sIn)

Func _String2Json(ByRef $s)
    $s = StringRegExpReplace($s, _
        '(?x)' & _
        '(?(DEFINE) (?<table>   \{ \h* (?: (?&element) (?: \h* , \h* (?&element) )* \h* \} ) ) )' & _
        '(?(DEFINE) (?<array>   \[ \h* (?: (?&element) (?: \h* , \h* (?&element) )* \h* \] ) ) )' & _
        '(?(DEFINE) (?<element> (?&table) | (?&array) | (?&number) | (?&string) ) )' & _
        '(?(DEFINE) (?<number>  [-+]? \d+ (?: \.\d+ )? (?: [Ee] [-+]? \d+ )? ) )' & _
        '(?(DEFINE) (?<string>  \b \w* [^\[\],]*[[:alpha:]_]+ [\w\h]* ) )' & _
        '( (?&string) )', _
        '"$6"')
EndFunc   ;==>_Array2Json

Of course, once that invalid input string is reformatted to correctly enclose strings inside double quotes, things are easier to handle.

Edited November 25, 2019 by jchd

[seadoggie01]

I haven't used *SKIP or *FAIL before. Thank you for an example with these! TIL

[jchd]

Yeah, backtracking control verbs are powerful but require real care if you don't want to get bitten.

[mikell]

22 minutes ago, jchd said:

OTOH if you want to match JSON definitions of its internal structure you can do so explicitely

It's obviously much more robust and clean 

... reason why I very carefully mentioned the initial requirements

[jchd]

I wrote that quite quickly and I suppose there are holes left around.

For instance, the definition of number isn't fully correct as that would match inside strings!  That's because recursion inside the nested names don't need to be matched: if you request only numbers, for instance, nothing forces this part to be an element, itself part of an array or table.

Also, multi-dimensional tables (arrays) need to have the same number of entries for dimensions > 1, which is hard to check that way.

Nonetheless the use of named subroutines, as in (?(DEFINE) (?<object> ...) ... (... (?&object) ... ) can be very handy at times.

[mikell]

4 minutes ago, jchd said:

I suppose there are holes left around.

There are... For instance, one [:alpha:] is needed to validate a string so "4_4" fails
Named subroutines are very useful indeed. I rarely use them because it involves a complicated pattern... and because of my laziness

 

[jchd]

Fixed, but there must be more (left as exercise to the reader, as they say).

Not enough time to dig further: I still have a significant number of electronic boards to repair and ship tomorrow.  I also need to make progress to finish a hardware/software prototype of a high-precision driver board delivering controlled bursts of extremelly short pulses with ultra-low (sub ns) jitter to medium-power laser diodes.  Late Sunday work.

[mikell]

This description looks like klingon for me
...
My previous try could be done more accurate anyway

Local $s = "{[[Elton John, Bonnie & Clyde, Sally, 123],[one 1, 2&, 3, 4_#4]], abc, [7,{a,b,[c,d,3]}]}"

$res = StringRegExpReplace($s, '\h*\d*\h*(?=[,\{\[\]])(*SKIP)(*F)|\h*([^\{\}\[\],]+)\h*', '"$1"')

Msgbox(0,"", $res)

[jchd]

Klingon too 🙂

Geez, I just realize that +- signs got lost in translation, just like scientific notation!