tiny soduku solver no gui

[aart]

this is small and fast it may be some adjustment to apply it is special written in auto it 

smallsoduko.au3

[jchd]

And your question is?  Remember this is a help forum!

BTW, your code solves only the easiest problems and needs more than "some adjustments" to correctly solve the hardest grids.

[Nine]

@aart Maybe you would like to try this one ?

expandcollapse popup

#include <GDIPlus.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <FontConstants.au3>
#include <WinAPISysWin.au3>
#include <Array.au3>

Const $SIZE = 9, $REGION = Sqrt($SIZE)
Const $LENGTH = $SIZE * $SIZE

Global $aGrid[$SIZE][$SIZE]
Global $aFinalGrid, $SolutionFound = False

ShowGrid($aGrid)

Func ShowGrid(ByRef $aGrid)

  Local $hGUI = GUICreate("Sudoku", 470, 510)
  GUISetBkColor(0xFFFFFF)
  GUISetFont(18, $FW_SEMIBOLD)
  GUISetState(@SW_SHOW)

  ; Draw line
  _GDIPlus_Startup()
  Global $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
  Global $hBitmap = _GDIPlus_BitmapCreateFromGraphics(470, 510, $hGraphic)
  Local $hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap)

  Local $hPen = _GDIPlus_PenCreate(0xFF000000, 3)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 10, 460, 10, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 10, 10, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 460, 10, 460, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 460, 460, 460, $hPen)

  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 160, 10, 160, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 310, 10, 310, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 160, 460, 160, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 310, 460, 310, $hPen)

  _GDIPlus_PenDispose($hPen)
  $hPen = _GDIPlus_PenCreate()

  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 60, 10, 60, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 110, 10, 110, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 210, 10, 210, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 260, 10, 260, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 360, 10, 360, 460, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 410, 10, 410, 460, $hPen)

  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 60, 460, 60, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 110, 460, 110, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 210, 460, 210, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 260, 460, 260, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 360, 460, 360, $hPen)
  _GDIPlus_GraphicsDrawLine($hGfxCtxt, 10, 410, 460, 410, $hPen)

  Local $idInput[$SIZE][$SIZE]

  GUIRegisterMsg($WM_COMMAND, "WM_Command")

  For $line = 0 To $SIZE - 1
    For $col = 0 To $SIZE - 1
      $idInput[$line][$col] = GUICtrlCreateInput("", 23 + ($col * 50), 23 + ($line * 50), 30, 30, $ES_CENTER + $ES_NUMBER, $WS_EX_TRANSPARENT)
    Next
  Next

  Local $idButton = GUICtrlCreateButton ("Solve", 200, 475, 70, 25, $BS_CENTER+$BS_VCENTER)
  GUICtrlSetFont (-1, 10, $FW_NORMAL)
  _GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, 470, 510)

  Local $nMsg

  While True
    $nMsg = GUIGetMsg()
    Switch $nMsg
      Case $GUI_EVENT_CLOSE
        ExitLoop
      Case $idButton
        For $line = 0 To $SIZE - 1
          For $col = 0 To $SIZE - 1
            $aGrid[$line][$col] = GUICtrlRead($idInput[$line][$col])
          Next
        Next
        ;_ArrayDisplay($aGrid)
        Solution($aGrid, 1)
        ;_ArrayDisplay($aFinalGrid)
        For $line = 0 To $SIZE - 1
          For $col = 0 To $SIZE - 1
            If Not GUICtrlRead($idInput[$line][$col]) Then
              GUICtrlSetData ($idInput[$line][$col], $aFinalGrid[$line][$col])
              GUICtrlSetColor ($idInput[$line][$col], 0xFF0000)
            EndIf
          Next
        Next
    EndSwitch
  WEnd

  _GDIPlus_GraphicsDispose($hGfxCtxt)
  _GDIPlus_BitmapDispose($hBitmap)
  _GDIPlus_PenDispose($hPen)
  _GDIPlus_GraphicsDispose($hGraphic)
  _GDIPlus_Shutdown()
  GUIDelete()

EndFunc   ;==>ShowGrid

Func WM_Command($hWnd, $iMsg, $wParam, $lParam)
  _GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, 470, 510)
EndFunc   ;==>WM_Command

Func Solution($aTemp, $iLoc)

  If $SolutionFound Then Return
  If $iLoc > $LENGTH Then
    $SolutionFound = True
    $aFinalGrid = $aTemp
    Return
  EndIf

  Local $iLine = Int(($iLoc - 1) / $SIZE)
  Local $iCol = Mod($iLoc - 1, $SIZE)

  If $aTemp[$iLine][$iCol] Then
    Solution($aTemp, $iLoc + 1)
  Else
    For $i = 1 To $SIZE
      If Possible($aTemp, $iLine, $iCol, $i) Then
        $aTemp[$iLine][$iCol] = $i
        Solution($aTemp, $iLoc + 1)
      EndIf
    Next
  EndIf

EndFunc   ;==>Solution

Func Possible(ByRef $aGrid, $iLine, $iCol, $iValue)
  For $i = 0 To $SIZE - 1
    If $aGrid[$iLine][$i] = $iValue Then Return False
    If $aGrid[$i][$iCol] = $iValue Then Return False
  Next
  Local $iRegLine = Int($iLine / $REGION) * $REGION
  Local $iRegCol = Int($iCol / $REGION) * $REGION
  For $line = $iRegLine To $iRegLine + $REGION - 1
    For $col = $iRegCol To $iRegCol + $REGION - 1
      If $aGrid[$line][$col] = $iValue Then Return False
    Next
  Next
  Return True
EndFunc   ;==>Possible

It is working on all levels of difficulties of SudoKu 

[jchd]

Seems it needs manual input of the puzzle value.

Also try this all-SQL implementation: Sudokus.au3

It will need a copy of the sqlite3.dll library.

[aart]

hi nine

 

what you build is a brutal force quite nice and fast

that is a problem

there may be more possibilities it would be possible to detect by further investigation

if you take the gui out of it then it stay's very smal

sotest.au3

Edited November 14, 2019 by aart

[Nine]

Recursion in that case is very efficient.  To keep it small and fast 

[jdelaney]

I scripted mine to screen scrape a sudoku site and automatically solve it:

edit: this is the first iteration of that script that will constantly solve sudoku puzzles, nvermind.

Edited November 15, 2019 by jdelaney

[aart]

my coal is what i think is that i think is like some calling it "havy" or "insane"

the issiu there is some time's more out come from same puzzle by more Possible's so you can hide some ways from the "real out com"

you may be can make some way to "endcrypt" it from brutal force by missing numbers what can be twisted

so turn the sodukutabel and read it backwards and some "insane" or "havy" have a differend outcome

 

[Nine]

I really do not understand what you are talking about.  Maybe use a translator to express your concerns.  Anyway, who do you think won: Deep Blue or Kasparov ?   This goes against Artificial Intelligence that tries to mimic human thinking.   Do not do invest in that if you can avoid it.  Human are good on some aspects but they are really bad at crunching millions of numbers.

[jchd]

@aart I also have hard time understanding what you wrote.

If you mean that you want to find multiple solutions to a given sudoku puzzle, this is quite possible as well.  A even simpler variant of the SQL implementation I posted can do that.  Please note that sudokus should have only one unique solution.

Also please remark that the SQL implementation doesn't rely on brute force!

[aart]

sorry my bad writting