How to make script faster with FileGetVersion on remote computers

[antmar904]

Hi,

I need to get the file version of a certain file on a large number of remote computers.  My scrip is too slow most likely because of the ping.  How can I make this much faster?  TIA!

Is there a way to add some type of multi thread processing to this?

 

expandcollapse popup

#include <Array.au3>
#include <AutoITConstants.au3>
#include <Timers.au3>
#include <File.au3>
#RequireAdmin

OnAutoItExitRegister("WriteLog")

Local $ComputerList = @ScriptDir & "\TrendCheckADComputerNames.txt", $LogFile = @ScriptDir & "\" & @MON & "" & @MDAY & "" & @YEAR & "_" & @HOUR & "_" & @MIN & "_TrendAudit.csv", $sPC = FileReadToArray($ComputerList)


If Not FileExists($ComputerList) Then
    MsgBox(48, "Error", "Missing the computer list file : " & @CRLF & $ComputerList & @CRLF & @CRLF & "Please make sure it exist then run the script again.")
    Exit
EndIf

;_ArrayDisplay($sPC, "Computer List") ;Debug

;Create Array
Global $Array_Base[2]
Global $Array = $Array_Base

_ArrayAdd($Array, "ComputerName" & "," & "Trend Version")

For $i = 0 To UBound($sPC) - 1
    If Ping($sPC[$i]) Then
        Local $sVersion = FileGetVersion('\\' & $sPC[$i] & '\C$\Program Files\Trend Micro\OfficeScan Client\Ntrtscan.exe', "FileVersion")
        Local $sVersion2 = FileGetVersion('\\' & $sPC[$i] & '\C$\Program Files (x86)\Trend Micro\OfficeScan Client\Ntrtscan.exe', "FileVersion")
        _ArrayAdd($Array, $sPC[$i] & "," & $sVersion & $sVersion2)
    Else
        _ArrayAdd($Array, $sPC[$i] & "," & "Offline")
    EndIf
Next

WriteLog()

Func WriteLog()
_FileWriteFromArray($LogFile, $Array)
Exit
EndFunc

 

Edited September 24, 2019 by antmar904

[seadoggie01]

You could have a setup where you have one (parent) script launch a bunch of (child) scripts through the command line... basically use the inside of your loop as the child script, pass the params through, and have it write the results to a specific file... an ini file under a Section named as the PC?

[BrewManNH]

It would go faster without the Ping, just check for @error to be set after the FileGetVersion command and see if it failed or not.

[antmar904]

25 minutes ago, BrewManNH said:

It would go faster without the Ping, just check for @error to be set after the FileGetVersion command and see if it failed or not.

How would I do that when checking two different file path locations?

[BrewManNH]

6 minutes ago, antmar904 said:

How would I do that when checking two different file path locations?

Check for an error after each one, if both error out then the computer is offline or the files just aren't there. Considering the fact you're not doing any checks in your original script to see if FileGetVersion actually returns a valid version number, at least this way you'll know enough not to write bogus information into your array as you're doing now.

The way you have it written now, as long as the computer responds to a ping, then you're adding something to your array, regardless of whether the file is there or not.

[antmar904]

25 minutes ago, BrewManNH said:

Check for an error after each one, if both error out then the computer is offline or the files just aren't there. Considering the fact you're not doing any checks in your original script to see if FileGetVersion actually returns a valid version number, at least this way you'll know enough not to write bogus information into your array as you're doing now.

The way you have it written now, as long as the computer responds to a ping, then you're adding something to your array, regardless of whether the file is there or not.

Not working:

For $i = 0 To UBound($sPC) - 1
    Local $sVersion = FileGetVersion('\\' & $sPC[$i] & '\C$\Program Files\Trend Micro\OfficeScan Client\Ntrtscan.exe', "FileVersion")
    If @error Then
        Local $sVersion2 = FileGetVersion('\\' & $sPC[$i] & '\C$\Program Files (x86)\Trend Micro\OfficeScan Client\Ntrtscan.exe', "FileVersion")
    ElseIf @error Then
        _ArrayAdd($Array, $sPC[$i] & "," & "Offline or No Trend")
    Else
    _ArrayAdd($Array, $sPC[$i] & "," & $sVersion & $sVersion2)

 

[seadoggie01]

2 minutes ago, antmar904 said:

Not working:

Well... that's not helpful. Maybe a bit of description? How exactly isn't it working?

[antmar904]

1 minute ago, seadoggie01 said:

Well... that's not helpful. Maybe a bit of description? How exactly isn't it working?

nothing is getting written to the log file

[seadoggie01]

5 minutes ago, antmar904 said:

nothing is getting written to the log file

Well, from the snippet you posted above, that makes sense, there's not even a 'Next'. If you mean you replaced the loop with that, it doesn't make sense, at least the header of the array should be written to the log file. You might want to throw some FileExists checks in there so you can make sure that the computers are still connected.

[BrewManNH]

Maybe something like this would work? Not tested, and may need to be adjusted to fit your needs.

For $i = 0 To UBound($sPC) - 1
     Local $sVersion2 = "0.0.0", $sVersion = FileGetVersion('\\' & $sPC[$i] & '\C$\Program Files\Trend Micro\OfficeScan Client\Ntrtscan.exe', "FileVersion") ; check programfiles for the file version
     If @error Then ; first one not found
          $sVersion2 = FileGetVersion('\\' & $sPC[$i] & '\C$\Program Files (x86)\Trend Micro\OfficeScan Client\Ntrtscan.exe', "FileVersion") ; Check programfiles (x86) for the file
          If @error Then ; still not found
               _ArrayAdd($Array, $sPC[$i] & "," & "Offline or No Trend") ; add to the array that it doesn't exist in either location
               ContinueLoop
         EndIf
     EndIf
     _ArrayAdd($Array, $sPC[$i] & "," & $sVersion & " : " & $sVersion2) ; add the version information for the found version
 
Next

 

NOTE: I have edited the original script. The original script wouldn't have written the correct version number into the array if it had been found in the first test, and would have errored due to the variable $sVersion 2 being declared inside the second If conditional check. This declares that variable before the first test, and shouldn't have the problem.

Edited September 26, 2019 by BrewManNH
Edited the script