HTTP POST Request, Dell Warranty API

[chaoticyeshua]

Hello,

I was approved for a v5 Dell TechDirect API key and am having some issues that I was hoping to receive some input on. My code is designed to retrieve warranty information through Dell's API for computers in our inventory as a part of our imaging process. Our existing code for their v4 API is working perfectly, but they recently made some changes to their process. Now, we are given an API key and a client secret, and we must use those to generate a token which expires every hour. I'm having what I consider to be an odd issue which makes the script, as we have historically used it, extremely problematic.

First, the code itself (note that there's obviously more code than this, but this is enough to demonstrate the issue):

;First we need to get the token
   ;Create HTTP Object
   Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")

   $oHttp.Option(9) = 0x800
   ;Open a POST request at the api. The 'False' is because we are opening the request synchronously
   $oHTTP.Open("POST", "https://apigtwb2c.us.dell.com/auth/oauth/v2/token", False)

   ;We need to set the content-type because our credentials are being sent in like a form
   $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")

   ;In case the client_id or the client secret changes, here is where you would change them
   Local $client_id = "myapikey"
   Local $client_secret = "myclientsecret"

   ;Lastly we need to send the request, the string parameter is the credentials we are sending in.
   $oHTTP.Send('grant_type=client_credentials&client_id=' & $client_id & '&client_secret=' & $client_secret)

When the code was first written, it worked fine on the computer it was initially run on. Once the code was being tested by someone else on their computer, they received the following error:

"No credentials were available in the client certificate"

Upon reading into the issue, it seems that winhttp objects use the first cert in the "CURRENT_USER\My" store for some purpose unknown to us. The error itself seemed to be resolved by adding the line $oHttp.SetClientCertificate("CURRENT_USER\My\mycert") and pointing to a specific cert in the store (in our case, replace the "mycert" signature with the user's email address). However, we typically run this script as a local user account, rather than under a user's domain account, as a part of our computer imaging process. We are unable to make this script work under a local user account, and we aren't sure why pointing to a cert is even required. It doesn't seem to me that it should be.

Is there anyone out there with more knowledge that can point us in the right direction to make this work under a local user account?

Edit: FYI, I have already reached out to Dell and they just said they can't help me.

Edited September 13, 2019 by chaoticyeshua

[mLipok]

Try to use HTTP.au3

Or post what com error handler say to you.

[AriK4]

Hello chaoticyeshua,

Were you able to figure this out?  I'm also trying to make the transition to the new API and even contacted Dell for some sample code, but they weren't able to provide anything.

Thanks, Ari.

[JoeBar]

You can see my post if it can help.

https://www.autoitscript.com/forum/topic/84133-winhttp-functions/page/46/?tab=comments#comment-1440463

Edited November 14, 2019 by JoeBar

[5g6tdcv4]

Not pretty, but you can create a functional warranty lookup from it.

 

expandcollapse popup

#include <HTTP.au3>
$url = "https://apigtwb2c.us.dell.com/auth/oauth/v2/token"
$postdata = "client_id=" & "YOURID" & "&" & "client_secret=" & "YOURSECRET" & "&" & "grant_type=client_credentials"
$test = _HTTP_Post1($url, $postdata)
ConsoleWrite($test)   ;this consolewrite will show you your new token if its older than an hour

$token ="3997b2f1-1781-426d-bc1f-bd7e0bd9011f"    ;will need to be updated with latest token
$ans = _http_get1("https://apigtwb2c.us.dell.com/PROD/sbil/eapi/v5/asset-entitlements?servicetags=YOUR SERIAL")
MsgBox(0,"",$ans)

Func _HTTP_Post1($url, $postdata = '')
    Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    $oHTTP.Open("POST", $url, False)
    If @error Then Return SetError(1, 0, 0)

    $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
    $oHTTP.Send($postdata)
    If @error Then Return SetError(2, 0, 0)

    Local $sReceived = $oHTTP.ResponseText
    Local $iStatus = $oHTTP.Status
    If $iStatus = 200 Then Return $sReceived

    Return SetError(3, $iStatus, $sReceived)
EndFunc   ;==>_HTTP_Post

Func _HTTP_Get1($url)
    Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    Local $res = $oHTTP.Open("GET", $url, False)
    If @error Then Return SetError(1, 0, 0)
    #forceref $res
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.SetRequestHeader("Authorization", "Bearer " &$token)

    $oHTTP.Send()
    If @error Then Return SetError(2, 0, 0)

    Local $sReceived = $oHTTP.ResponseText
    Local $iStatus = $oHTTP.Status
    If $iStatus = 200 Then Return $sReceived

    Return SetError(3, $iStatus, $sReceived)
EndFunc   ;==>_HTTP_Get

 

Edited November 18, 2021 by Jos
added codebox... please use <> next time.

[Valnurat]

Hi.

I'm trying to run the code, but I get an error: can't open include file <HTTP.au3>.

Where can I find the HTTP.au3?

[Musashi]

37 minutes ago, Valnurat said:

Where can I find the HTTP.au3?

Try : 

https://github.com/jesobreira/HTTP.au3/blob/master/README.md

and :

 

 

 

Edited January 26 by Musashi

[Valnurat]

Thank you.

I have downloaded it and I have added my own client-ID and the client-secret, but I get some errors.

We intercepted a COM Error !
Number is: 80020009
Windescription is: Exception occurred.
0We intercepted a COM Error !
Number is: 80020009
Windescription is: Exception occurred.

[Musashi]

14 minutes ago, Valnurat said:

I have downloaded it and I have added my own client-ID and the client-secret, but I get some errors.

You could have a look at the WinHttp.au3 from @trancexx . However, the commands would then have to be adapted accordingly.

https://github.com/dragana-r/autoit-winhttp/blob/master/WinHttp.au3

 

[Valnurat]

Is that because the http.au3 is not working?

[Jos]

Include this info in the error message you get and show the result on error:

Global $__g_oHTTP_ErrorHandler = ObjEvent("AutoIt.Error", __HTTP_OnError) ; Install a custom error handler

; Custom error handler will set @error variable to 1 if a COM error is intercepted
; and will print out the error informations by the Console
Func __HTTP_OnError(ByRef $oMyError)
    Local $HexNumber = Hex($oMyError.number, 8)
    ConsoleWrite("We intercepted a COM Error !" & @LF & _
            "Number is: " & $HexNumber & @LF & _
            "Windescription is: " & $oMyError.windescription _
            "err.description is: " & $oMyError.description _
            )
    Return SetError(5, $HexNumber, 0)
EndFunc   ;==>__HTTP_OnError

 

Edited January 27 by Jos

[Valnurat]

Ok, but the number is just 0, I guess or then I don't understand how I should use the function.

Sorry. 😳

[Jos]

Update the http.au3 code!

[Valnurat]

Did that, but still the same error.

[Jos]

sigh.... of course you still get the same error, but there should be more information now! 

[Valnurat]

Sorry, but how should I add the function?

😳

[Valnurat]

If I just add it like this:

expandcollapse popup

#include <HTTP.au3>
Global $__g_oHTTP_ErrorHandler = ObjEvent("AutoIt.Error", __HTTP_OnError) ; Install a custom error handler

$url = "https://apigtwb2c.us.dell.com/auth/oauth/v2/token"
$postdata = "client_id=" & "API-ID" & "&" & "client_secret=" & "API-SECRET" & "&" & "grant_type=client_credentials"
$test = _HTTP_Post1($url, $postdata)
ConsoleWrite($test)   ;this consolewrite will show you your new token if its older than an hour

$token ="3997b2f1-1781-426d-bc1f-bd7e0bd9011f"    ;will need to be updated with latest token
$ans = _http_get1("https://apigtwb2c.us.dell.com/PROD/sbil/eapi/v5/asset-entitlements?servicetags=845vls3")
MsgBox(0,"",$ans)

; Custom error handler will set @error variable to 1 if a COM error is intercepted
; and will print out the error informations by the Console
Func __HTTP_OnError(ByRef $oMyError)
    Local $HexNumber = Hex($oMyError.number, 8)
    ConsoleWrite("We intercepted a COM Error !" & @LF & _
            "Number is: " & $HexNumber & @LF & _
            "Windescription is: " & $oMyError.windescription _
            "err.description is: " & $oMyError.description _
            )
    Return SetError(5, $HexNumber, 0)
EndFunc   ;==>__HTTP_OnError

Func _HTTP_Post1($url, $postdata = '')
    Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    $oHTTP.Open("POST", $url, False)
    If @error Then Return SetError(1, 0, 0)

    $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
    $oHTTP.Send($postdata)
    If @error Then Return SetError(2, 0, 0)

    Local $sReceived = $oHTTP.ResponseText
    Local $iStatus = $oHTTP.Status
    If $iStatus = 200 Then Return $sReceived

    Return SetError(3, $iStatus, $sReceived)
EndFunc   ;==>_HTTP_Post

Func _HTTP_Get1($url)
    Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    Local $res = $oHTTP.Open("GET", $url, False)
    If @error Then Return SetError(1, 0, 0)
    #forceref $res
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.SetRequestHeader("Authorization", "Bearer " &$token)

    $oHTTP.Send()
    If @error Then Return SetError(2, 0, 0)

    Local $sReceived = $oHTTP.ResponseText
    Local $iStatus = $oHTTP.Status
    If $iStatus = 200 Then Return $sReceived

    Return SetError(3, $iStatus, $sReceived)
EndFunc   ;==>_HTTP_Get

I'll get the below error:
 

"C:\Users\DKent\Autoit\DellAPI\DellAPI.au3"(15,37) : error: __HTTP_OnError() already defined.
Func __HTTP_OnError(ByRef $oMyError)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
"C:\Users\DKent\Autoit\DellAPI\DellAPI.au3"(20,35) : error: syntax error
            "err.description is: "
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Users\DKent\Autoit\DellAPI\DellAPI.au3 - 2 error(s), 0 warning(s)

 

[Jos]

Yes of course you get that.
So we are 13 years further and you don't know any basics at all and simply copy paste code in the hope this work and then dump it here so we can solve these simple things for you? 

Get rid of the #include when you hardcode the funcs in your own script and the second error is a simple basic mistake you really should be able to figure out.
This code is error free according au3check....  

expandcollapse popup

Global $__g_oHTTP_ErrorHandler = ObjEvent("AutoIt.Error", __HTTP_OnError) ; Install a custom error handler

$url = "https://apigtwb2c.us.dell.com/auth/oauth/v2/token"
$postdata = "client_id=" & "API-ID" & "&" & "client_secret=" & "API-SECRET" & "&" & "grant_type=client_credentials"
$test = _HTTP_Post1($url, $postdata)
ConsoleWrite($test)   ;this consolewrite will show you your new token if its older than an hour

$token ="3997b2f1-1781-426d-bc1f-bd7e0bd9011f"    ;will need to be updated with latest token
$ans = _http_get1("https://apigtwb2c.us.dell.com/PROD/sbil/eapi/v5/asset-entitlements?servicetags=845vls3")
MsgBox(0,"",$ans)

; Custom error handler will set @error variable to 1 if a COM error is intercepted
; and will print out the error informations by the Console
Func __HTTP_OnError(ByRef $oMyError)
    Local $HexNumber = Hex($oMyError.number, 8)
    ConsoleWrite("We intercepted a COM Error !" & @LF & _
            "Number is: " & $HexNumber & @LF & _
            "Windescription is: " & $oMyError.windescription & _
            "err.description is: " & $oMyError.description _
            )
    Return SetError(5, $HexNumber, 0)
EndFunc   ;==>__HTTP_OnError

Func _HTTP_Post1($url, $postdata = '')
    Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    $oHTTP.Open("POST", $url, False)
    If @error Then Return SetError(1, 0, 0)

    $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
    $oHTTP.Send($postdata)
    If @error Then Return SetError(2, 0, 0)

    Local $sReceived = $oHTTP.ResponseText
    Local $iStatus = $oHTTP.Status
    If $iStatus = 200 Then Return $sReceived

    Return SetError(3, $iStatus, $sReceived)
EndFunc   ;==>_HTTP_Post

Func _HTTP_Get1($url)
    Local $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    Local $res = $oHTTP.Open("GET", $url, False)
    If @error Then Return SetError(1, 0, 0)
    #forceref $res
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.SetRequestHeader("Authorization", "Bearer " &$token)

    $oHTTP.Send()
    If @error Then Return SetError(2, 0, 0)

    Local $sReceived = $oHTTP.ResponseText
    Local $iStatus = $oHTTP.Status
    If $iStatus = 200 Then Return $sReceived

    Return SetError(3, $iStatus, $sReceived)
EndFunc   ;==>_HTTP_Get

 

Edited January 27 by Jos

[Valnurat]

Thank you again I can now see more detalis than before.

 

"There were no credentials available for the client certificate" and that's funny, but maybe my credetials is wrong, but they shouldn't be.

Edited January 29 by Valnurat

[Valnurat]

And sorry for what I missed. 

It was in the http.au3 you meant I needed to update and not in my code.

Sorry for that.