REG Ex problem SOLVED

[xcaliber13]

Could someone point to the correct logic/process to do this.   I have a text file and within that file I have blocks of text I would like to format.  

Beginning block of text

88305 data data

Line 2  data

Line 3 data data data

Line 4 data data

Line 5 data

86244 data data

Line 2  data

Line 3 data data data

Line 4 data data

Line 5 data

End of block of text. 

Results after formatting

Beginning block of text

88305 data data Line 2  data Line 3 data data data Line 4 data data Line 5 data

86244 data data Line 2  data Line 3 data data data Line 4 data data Line 5 data

End of block of text. 

 

So within each block of text the data can vary.   Some would only have a resulting finished format of one line and others have 2 or more.  The 5 digit code(88305 and this varies) is always at the beginning of a line.  

Not looking for anyone to write the code just get me pointed to the correct logic to do this task.   Anything would help just really kind of brain cramping on this one.  Thank you

 

[water]

Pseudocode (untested):

Open InputFile
Open OutputFile
While
    Read line from InputFile into ReadBuffer
    If error Then ; End-of-file reached
        If WriteBuffer <> "" Then Write WriteBuffer to OutputFile ; Write last block to output file
        ExitLoop
    EndIf
    If ReadBuffer starts with "Line " Then 
        concat ReadBuffer to WriteBuffer
    Else  ; Start new block
        If WriteBuffer <> "" Then Write WriteBuffer to Output file ; Write previous block to output file
        WriteBuffer = ReadBuffer
    EndIf
WEnd
Close InputFile
Close OutputFile

 

[Melba23]

xcaliber13,

My suggestion (I added a second section just to prove the concept):

expandcollapse popup

#include <Array.au3> ; Just for display

$sStart = "Beginning block of text "
$sEnd = "End of block of text"

; Simulate reading file into an array
Global $aText[] = ["Beginning block of text ", _
                    "88305 data data ", _
                    "Line 2  data ", _
                    "Line 3 data data data ", _
                    "Line 4 data data ", _
                    "Line 5 data ", _
                    "86244 data data ", _
                    "Line 2  data ", _
                    "Line 3 data data data ", _
                    "Line 4 data data ", _
                    "Line 5 data ", _
                    "End of block of text", _
                    "Beginning block of text ", _
                    "89345 data data ", _
                    "Line 2  data ", _
                    "Line 3 data data data ", _
                    "Line 4 data data ", _
                    "Line 5 data ", _
                    "87654 data data ", _
                    "Line 2  data ", _
                    "Line 3 data data data ", _
                    "Line 4 data data ", _
                    "Line 5 data ", _
                    "End of block of text"]

; Just for display
 _ArrayDisplay($aText, "", Default, 8)

$sData = ""

For $i = 0 To UBound($aText) - 1

    $sLine = $aText[$i]

    If $sLine = $sStart Or $sLine = $sEnd Then
        $sData &= @CRLF & $sLine
    Else
        If StringLeft($sLine, 4) <> "Line" Then
            $sData &= @CRLF & $sLine
        Else
            $sData &= $sLine
        EndIf
    EndIf

Next

ConsoleWrite($sData & @CRLF)

M23

[xcaliber13]

I really am trying to learn regex.   I have been using www.myregextester.com to test different regex patterns.   But I am having an issue when trying to use a successful pattern that I tested at  myregextester.com  in AutoIt.   I have a text file that I read to an array,  then search the array for the pattern but it does not find the correct string.  I am trying to find every  line that begins with 5 numbers .  Here is the code I have been trying to make work.   My  _ArrayFindAll is not returning the correct lines from the text file.  Is my regex pattern wrong?  Or should I be doing this a different way?  Thank you for any help.

Global $avArray
_FileReadToArray('c:\Temp\temp.txt', $avArray, $FRTA_NOCOUNT)
;_ArrayDisplay($avArray)

$search = StringRegExp($avArray, '(?ms)^\d{5}', 3)
Local $iIndex =_ArrayFindAll($avArray, $search, 0, 0, 0, 3)
_ArrayDisplay($iIndex)
for $i = 0 to UBound($iIndex)-1 step 1
    $avArray[$iIndex[$i]] = "CPT CODE"&$avArray[$iIndex[$i]]

Next
_ArrayDisplay($avArray)

 

[Xenobiologist]

Don't know? Maybe something like this?

 

#include <File.au3>
#include <Array.au3>
#include <FileConstants.au3>
Global $avArray
_FileReadToArray('temp.txt', $avArray, $FRTA_NOCOUNT)
For $i = UBound($avArray) - 1 To 0 Step -1
    ConsoleWrite($i & " " & $avArray[$i] & @crlf)
    If Not StringRegExp($avArray[$i], '(?s)^\d{5}', $STR_REGEXPMATCH) Then
;~      _ArrayDelete($avArray, $i) ; optional
    Else
        $avArray[$i] = "CPT CODE" & $avArray[$i]
    EndIf
Next
_ArrayDisplay($avArray)

 

[FrancescoDiMuro]

@xcaliber13
There are many ways to do this:

#include <Array.au3>
#include <StringConstants.au3>

Global $strString = "88305 data data" & @CRLF & _
                    "Line 2  data" & @CRLF & _
                    "Line 3 data data data" & @CRLF & _
                    "Line 4 data data" & @CRLF & _
                    "Line 5 data" & @CRLF & _
                    "86244 data data" & @CRLF & _
                    "Line 2  data" & @CRLF & _
                    "Line 3 data data data 56789" & @CRLF & _
                    "Line 4 data data" & @CRLF & _
                    "Line 5 data" & @CRLF & _
                    "End of block of text. ", _
      $arrResult[0], _
      $strResult = ""
      
MsgBox(0, 'Before:', $strString)

_ArrayAdd($arrResult, StringRegExpReplace($strString, '(?m)(?!\A)^(\d{5})', '|$1'))

For $i = 0 To UBound($arrResult) - 1 Step 1
    $strResult &= StringStripWS(StringReplace($arrResult[$i], @CRLF, " "), BitOR($STR_STRIPLEADING, $STR_STRIPTRAILING, $STR_STRIPSPACES)) & @CRLF & ($i < UBound($arrResult) - 1 ? "---------------" & @CRLF : "")
Next

MsgBox(0, 'After:', $strResult)

Bet @mikell and @jchd will join the party soon.
By the way, both @water and @Melba23 provided you a solution without receiving by you any kind of reply; that's not so much respectful in their comparisons

Edited August 14, 2019 by FrancescoDiMuro

[mikell]

2 hours ago, xcaliber13 said:

I am trying to find every  line that begins with 5 numbers

I don't understand the reason why you overcomplicate. While StringRegExp does the job by itself, you shouldn't need anything more

Global $strString = "88305 data data" & @CRLF & _
                    "Line 2  data" & @CRLF & _
                    "Line 3 data data data" & @CRLF & _
                    "Line 4 data data" & @CRLF & _
                    "Line 5 data" & @CRLF & _
                    "86244 data data" & @CRLF & _
                    "Line 2  data" & @CRLF & _
                    "Line 3 data data data 56789" & @CRLF & _
                    "Line 4 data data" & @CRLF & _
                    "Line 5 data" & @CRLF & _
                    "End of block of text. "
      
$res = StringRegExp($strString, '(?m)^\d{5}.*$', 3)
_ArrayDisplay($res)

BTW StringRegExp acts on strings, not arrays. This is not good :

_FileReadToArray('c:\Temp\temp.txt', $avArray, $FRTA_NOCOUNT)
;_ArrayDisplay($avArray)

$search = StringRegExp($avArray, '(?ms)^\d{5}', 3)

 

[xcaliber13]

Thank you for all your help.   I got the script working the way I needed it to.  

Again Thank you All

[xcaliber13]

Thank you  Water and Melba23   you got me on the right track to be able to finish the script.    

 

[FrancescoDiMuro]

1 hour ago, mikell said:

While StringRegExp does the job by itself

Little hairy cat (), if you would have paid more attention to the OP request, you would have noticed that he was asking to merge the lines where the five digits number were encountered, and the ones following that too, until a new five digits number was encountered, so, the script you posted is not currently doing what the OP requested 

Edited August 14, 2019 by FrancescoDiMuro

[mikell]

Merge ? where on the earth did you see such a mention ? 
"I am trying to find every  line that begins with 5 numbers"  is clear, and their code ends with "_ArrayDisplay($avArray)" so the expected result is an array (probably)
Oh yes, to keep as close as possible to the initial post/question I should have written

$avArray = StringRegExp($file, 'db\.(?|server.name|database.name|instance.name|port)=(\N*)', 3)
for $i = 0 to UBound($avArray)-1
    $avArray[$i] = "CPT CODE"&$avArray[$i]
Next
_ArrayDisplay($avArray)

[FrancescoDiMuro]

10 minutes ago, mikell said:

db\.(?|server.name|database.name|instance.name|port)=(\N*)

Wrong post kitty cat! 
By the way, the OP stated that in this thread

Edited August 14, 2019 by FrancescoDiMuro

[mikell]

I don't care of other threads. I answered to a question asked in post #1 of the current thread. If this answer doesn't fit so the question was wrong, period.

[FrancescoDiMuro]

@mikell
Pay more attention.
This answer was referred to this thread, and not to this one, so, low your fur and just read carefully

[JLogan3o13]

@xcaliber13 you have been around long enough to know better than this multi-post spamming because you want an answer now. Please stick to one thread per topic in the future, as you can see what kind of confusion you caused.

 

3 minutes ago, FrancescoDiMuro said:

This answer was referred to this thread, and not to this one, so, low your fur and just read carefully

Not sure if you think you're being humorous (you're not), but you can't expect someone to come in and answer based off there being multiple threads, each with half the information you would need. So, I would suggest, rather than you telling an MVP to back up and take a moment, that you take your own advice.

[FrancescoDiMuro]

Just now, JLogan3o13 said:

but you can't expect someone to come in and answer based off there being multiple threads

No, that's why I pointed him to let him know there were another post in which the user were explaining much better what he was asking, providing an example too.
The fact is that he is (if you follow the "this" stream) referring to another thread which were not linked in any way to these ones.
And then, MVP or not, just a little "Hey, read carefully before answering"

[JLogan3o13]

Your statements to him, perhaps through translation, come across as condescending. As we have discussed in the past, your willingness to help is great - we could do without some of the side commentary.

[Malkey]

Try this example.

#cs
Could someone point to the correct logic/process to do this.   I have a text file and within that file I have blocks of text I would like to format.
Beginning block of text
88305 data data
Line 2  data
Line 3 data data data
Line 4 data data
Line 5 data
86244 data data
Line 7  data
Line 8 data data data
Line 9 data data
Line 10 data
86660 data data
Line 12  data
Line 13 data data data
Line 14 data data
Line 15 data
End of block of text
Text after first block.

Beginning block of text
88333 data data
Line 20  data
Line 21 data data data
Line 22 data data
Line 23 data
End of block of text
Text after second block.
#ce

Local $sText = StringRegExpReplace(FileRead(@ScriptFullPath), "(?is)^.*?#cs\s+|\s+#ce.*$", "") ; Get test text from comment block in this script.
Local $sStart = "Beginning block of text"
Local $sEnd = "End of block of text"

ConsoleWrite(Execute("'" & StringRegExpReplace($sText, "(?si)(.*?" & $sStart & ")(.+?)(\R" & $sEnd & ".*?)", "$1' & StringRegExpReplace('$2', '\\R(?!\\d{5})', ' ') & '$3") & "'") & @CRLF)