GUICtrlCreateInput type HH:MM:SS - (Moved)

[Fadi]

hi,

I'm trying to create an input but force the input to be in the form HH:MM:SS and validate that the input is in this format.

Any idea? Thank you in advance 

[Fadi]

Example

$Input1 = GUICtrlCreateInput("", 19, 40, 213, 21)

[JLogan3o13]

Moved to the appropriate forum, as the Developer General Discussion forum very clearly states:

Quote

General development and scripting discussions. If it's super geeky and you don't know where to put it - it's probably here.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Moderation Team

[water]

Search the forum for "input validation" and you will find a lot of UDFs to assist you. Example:

 

[Nine]

Or simply :

If StringRegExp ($sTime, "^\d{2}:\d{2}:\d{2}$") Then
    $aTime = StringSplit ($sTime, ":", $STR_NOCOUNT)
    If $aTime[0] < 24 And $aTime[1] < 60 And $aTime[2] < 60 Then ... ; it is ok now
EndIf

 

[Fadi]

Thank you

[mikell]

But don't forget to check that the result is not something like  85:86:87 ...

Edit
For the fun 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 200, 70)
$Label = GUICtrlCreateLabel("Enter  HH:MM:SS  (24 h format)", 22, 8, 160, 17)
$input = GUICtrlCreateInput("", 50, 30, 100, 24)
GUICtrlSetLimit(-1, 8)
GUICtrlSetFont(-1, 12)
GUISetState()

GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

While 1
  Sleep(10)
WEnd


Func _WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
 Local $id = BitAND($wParam, 0x0000FFFF)
 Local $code = BitShift($wParam, 16)
   If $id = $input AND $code = $EN_UPDATE Then
       Local $content = GUICtrlRead($input)
       $n = StringLen($content)
       If ($n = 1 or $n = 2 or $n = 4 or $n = 5 or $n = 7 or $n = 8) _ 
            and not StringIsDigit(StringRight($content, 1)) Then _ 
            GUICtrlSetData($input, StringTrimRight($content, 1))
       If ($n = 3 or $n = 6) and not (StringRight($content, 1) == ":") Then _ 
            GUICtrlSetData($input, StringTrimRight($content, 1))
       If $n = 2 and Number($content) > 23 Then GUICtrlSetData($input, "")
       If ($n = 5 or $n = 8) and Number(StringRight($content, 2)) > 59 Then _ 
            GUICtrlSetData($input, StringTrimRight($content, 2))
       EndIf
    Return $GUI_RUNDEFMSG
EndFunc


Func _Exit()
    Exit
EndFunc

 

Edited August 1, 2019 by mikell

[BrewManNH]

I'd use 3 (or 4) input controls, an updown control on each, and set the limit for the controls. Use the parameter $ES_NUMBER  so that only numbers can be used. Easy and done.