shake a window

[caramen]

Hello all. 

Dear community, I'm making a script to monitor some windows. 

I would like to know if some of you can advise me or point me in the correct direction to shake a window when some statements are verified. 

 

Thanks in advance for your advises. 

[FrancescoDiMuro]

@caramen
Take a look at WinFlash or _WinAPI_FlashWindow* functions

[Seminko]

Take a look at this.

 

[Malkey]

I really liked Seminko's find, and thought "ShakeWindow" function should work on any window.
 

; Modified version of "Shake Window" by Death Pax <death_pax@msn.com> from
; https://www.autoitscript.com/forum/topic/22277-new-scrap-shake-window/
; Press Shift-Alt-s keys together and current window with focus will shake.

HotKeySet("{ESC}", "Terminate")
HotKeySet("+!s", "_ShakeWindow") ; Shift-Alt-s

While Sleep(100)
WEnd


Func _ShakeWindow()
    Local $Window = WinGetTitle("", ""), $ShakeAmount = 5, $Win_pos = WinGetPos($Window)
    For $i = 0 To 100
        WinMove($Window, "", $Win_pos[0], $Win_pos[1] + $ShakeAmount * Mod($i, 2))
        Sleep(40)
    Next
EndFunc   ;==>_ShakeWindow

Func Terminate()
    Exit
EndFunc   ;==>Terminate

 

[badcoder123]

Modify this so it's a quick circle

 

$pi = 4 * ATan(1)
$centerX = @DesktopWidth / 2
$centerY = @DesktopHeight / 2
$RMax = @DesktopHeight / 2
$R = 0

While 1
    For $i = 0 To 2 * $pi Step 0.03125
        WinMove("Untitled - Notepad", "", $centerX + ($R * Cos($i)), $centerY + ($R * Sin($i)))
        $R += 0.5
        If $R > $RMax Then $R = 0
        Sleep(10)
    Next
WEnd

 

[Malkey]

2 hours ago, badcoder123 said:

Modify this so it's a quick circle

Yes Sir.

Use Shift-Alt-s on this example.

; Modified version of "Shake Window" by Death Pax <death_pax@msn.com> from
; https://www.autoitscript.com/forum/topic/22277-new-scrap-shake-window/
; Press Shift-Alt-a keys together and current window with focus will shake up and down.
; Press Shift-Alt-s keys together and current window with focus will shake circular.

HotKeySet("{ESC}", "Terminate")
HotKeySet("+!a", "_ShakeWindow") ; Shift-Alt-a
HotKeySet("+!s", "_ShakeWindow2") ; Shift-Alt-s

While Sleep(100)
WEnd


Func _ShakeWindow()
    Local $Window = WinGetTitle("", ""), $ShakeAmount = 5, $Win_pos = WinGetPos($Window)
    For $i = 0 To 100
        WinMove($Window, "", $Win_pos[0], $Win_pos[1] + $ShakeAmount * Mod($i, 2))
        Sleep(40)
    Next
EndFunc   ;==>_ShakeWindow

Func _ShakeWindow2()
    Local $Window = WinGetTitle("", ""), $R = 50, $Win_pos = WinGetPos($Window), $pi = 4 * ATan(1)
    Local $Win_pos = WinGetPos($Window), $centerX = $Win_pos[0], $centerY = $Win_pos[1]
    For $i = 0 To 20 * $pi Step $pi / 8
        WinMove($Window, "", $centerX + ($R * Cos($i)), $centerY + ($R * Sin($i)))
        Sleep(10)
    Next
    WinMove($Window, "", $centerX, $centerY)
EndFunc   ;==>_ShakeWindow2

Func Terminate()
    Exit
EndFunc   ;==>Terminate