Embed AVI in Exe and use it

[Zombie02]

Hello Guys i am new to Autoit. I am currently writing a GUI which is displaying a avi. My question now is how can i use a avi i added with Autoit3wrapper

Thanks is advance

Zombie

[BrewManNH]

Look at the _GUICtrlAVI_* functions and see if they'll work for you.

[Zombie02]

2 hours ago, BrewManNH said:

Look at the _GUICtrlAVI_* functions and see if they'll work for you.

Unfortunately no the function should work Like the guictrlsetimage function

[BrewManNH]

2 hours ago, Zombie02 said:

Unfortunately no the function should work Like the guictrlsetimage function

Not sure what you're trying to say here. What function should work that way? If you're trying to embed a movie into a GUI, you can't just set it to a control, you have to create the control differently than say a picture or an icon.

[Zedna]

It's simple like this:

#AutoIt3Wrapper_Res_File_Add=test_avi.avi, avi, 150

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hAVI

    ; Create GUI
    $hGUI = GUICreate("(Internal) AVI OpenEx", 300, 100)
    $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
    GUISetState(@SW_SHOW)

    ; Play the sample AutoIt AVI
;~  _GUICtrlAVI_OpenEx($hAVI, @SystemDir & "\Shell32.dll", 150)
    _GUICtrlAVI_OpenEx($hAVI, @ScriptFullPath, 150)

    ; Play the sample AutoIt AVI
    _GUICtrlAVI_Play($hAVI)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Close AVI clip
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>Example

Note: It's modified example from helpfile for _GUICtrlAVI_OpenEx()

"C:\Program Files\Examples\Helpfile\_GUICtrlAVI_OpenEx.au3" 

 

EDIT:

Don't forget that to test it you have to run COMPILED exe file (not run au3 directly from Scite) and

you have to compile script using FULL Scite4AutoIt3 because of used #AutoIt3Wrapper_Res_File_Add directive

 

EDIT2: Here is simplified example without explicit call of _GUICtrlAVI_OpenEx()

#AutoIt3Wrapper_Res_File_Add=test_avi.avi, avi, 150

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

$hGUI = GUICreate("(Internal) AVI Open", 300, 100)
$hAVI = _GUICtrlAVI_Create($hGUI, @ScriptFullPath, 150, 10, 10)
GUISetState(@SW_SHOW)

_GUICtrlAVI_Play($hAVI)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_GUICtrlAVI_Close($hAVI)

Edited July 2, 2019 by Zedna
edit2

[Zombie02]

6 hours ago, Zedna said:

It's simple like this:

#AutoIt3Wrapper_Res_File_Add=test_avi.avi, avi, 150

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hAVI

    ; Create GUI
    $hGUI = GUICreate("(Internal) AVI OpenEx", 300, 100)
    $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
    GUISetState(@SW_SHOW)

    ; Play the sample AutoIt AVI
;~  _GUICtrlAVI_OpenEx($hAVI, @SystemDir & "\Shell32.dll", 150)
    _GUICtrlAVI_OpenEx($hAVI, @ScriptFullPath, 150)

    ; Play the sample AutoIt AVI
    _GUICtrlAVI_Play($hAVI)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Close AVI clip
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>Example

Note: It's modified example from helpfile for _GUICtrlAVI_OpenEx()

"C:\Program Files\Examples\Helpfile\_GUICtrlAVI_OpenEx.au3" 

 

EDIT:

Don't forget that to test it you have to run COMPILED exe file (not run au3 directly from Scite) and

you have to compile script using FULL Scite4AutoIt3 because of used #AutoIt3Wrapper_Res_File_Add directive

 

EDIT2: Here is simplified example without explicit call of _GUICtrlAVI_OpenEx()

#AutoIt3Wrapper_Res_File_Add=test_avi.avi, avi, 150

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

$hGUI = GUICreate("(Internal) AVI Open", 300, 100)
$hAVI = _GUICtrlAVI_Create($hGUI, @ScriptFullPath, 150, 10, 10)
GUISetState(@SW_SHOW)

_GUICtrlAVI_Play($hAVI)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_GUICtrlAVI_Close($hAVI)

 

test_avi.avi 20.31 kB · 1 download

Yes this was exactly what i was looking for.

Thank you for your help